Add and use Macro.escape(ast, generated: true)

Author: sabiwara

lib/elixir/lib/kernel.ex

@@ -3858,17 +3858,14 @@ defmodule Kernel do
 
   defp do_at_escape(name, value) do
     try do
-      :elixir_quote.escape(value, :none, false)
+      # mark module attrs as shallow-generated since the ast for their representation
+      # might contain opaque terms
+      Macro.escape(value, generated: true)
     rescue
       ex in [ArgumentError] ->
         raise ArgumentError,
               "cannot inject attribute @#{name} into function/macro because " <>
                 Exception.message(ex)
-    else
-      # mark module attrs as shallow-generated since the ast for their representation
-      # might contain opaque terms
-      {caller, meta, args} when is_list(meta) -> {caller, [generated: true] ++ meta, args}
-      ast -> ast
     end
   end
 

lib/elixir/lib/macro.ex

@@ -808,6 +808,10 @@ defmodule Macro do
       nodes. Note this option changes the semantics of escaped code and
       it should only be used when escaping ASTs. Defaults to `false`.
 
+    * `:generated` - (since v1.19.0) Whether the AST should be considered as generated
+      by the compiler or not. This means the compiler and tools like Dialyzer may not
+      emit certain warnings.
+
       As an example for `:prune_metadata`, `ExUnit` stores the AST of every
       assertion, so when an assertion fails we can show code snippets to users.
       Without this option, each time the test module is compiled, we would get a
@@ -908,7 +912,17 @@ defmodule Macro do
   def escape(expr, opts \\ []) do
     unquote = Keyword.get(opts, :unquote, false)
     kind = if Keyword.get(opts, :prune_metadata, false), do: :prune_metadata, else: :none
-    :elixir_quote.escape(expr, kind, unquote)
+    generated = Keyword.get(opts, :generated, false)
+
+    case :elixir_quote.escape(expr, kind, unquote) do
+      # mark module attrs as shallow-generated since the ast for their representation
+      # might contain opaque terms
+      {caller, meta, args} when generated and is_list(meta) ->
+        {caller, [generated: true] ++ meta, args}
+
+      ast ->
+        ast
+    end
   end
 
   # TODO: Deprecate me on Elixir v1.22

lib/elixir/test/elixir/macro_test.exs

@@ -84,6 +84,11 @@ defmodule MacroTest do
       assert Macro.escape(contents, unquote: true) == {:x, [], MacroTest}
     end
 
+    test "with generated" do
+      assert Macro.escape(%{a: {}}, generated: true) ==
+               {:%{}, [generated: true], [a: {:{}, [], []}]}
+    end
+
     defp eval_escaped(contents) do
       {eval, []} = Code.eval_quoted(Macro.escape(contents, unquote: true))
       eval