Option for mix app.tree and mix deps.tree to be output as DOT file (#4764)

Josh Price · josevalim · commit e23683098af7 · 2016-06-08T13:55:27.000+02:00
diff --git a/lib/mix/lib/mix/tasks/app.tree.ex b/lib/mix/lib/mix/tasks/app.tree.ex
@@ -17,8 +17,17 @@ defmodule Mix.Tasks.App.Tree do
     * `--exclude` - exclude applications which you do not want to see printed.
       `kernel`, `stdlib` and `compiler` are always excluded from the tree.
 
-    * `--pretty` - use Unicode codepoints for formatting the tree.
-      Defaults to `true` except on Windows.
+    * `--format` - Can be set to one of either:
+
+      * `pretty` - use Unicode codepoints for formatting the tree.
+        This is the default except on Windows.
+
+      * `plain` - do not use Unicode codepoints for formatting the tree.
+        This is the default on Windows.
+
+      * `dot` - produces a DOT graph description of the application tree
+        in `app_tree.dot` in the current directory.
+        Warning: this will override any previously generated file.
 
   """
 
@@ -29,7 +38,7 @@ defmodule Mix.Tasks.App.Tree do
     Mix.Task.run "compile"
 
     {app, opts} =
-      case OptionParser.parse!(args, strict: [exclude: :keep, pretty: :boolean]) do
+      case OptionParser.parse!(args, strict: [exclude: :keep, format: :string]) do
         {opts, []} ->
           app = Mix.Project.config[:app] || Mix.raise("no application given and none found in mix.exs file")
           {app, opts}
@@ -40,10 +49,20 @@ defmodule Mix.Tasks.App.Tree do
     excluded = Keyword.get_values(opts, :exclude) |> Enum.map(&String.to_atom/1)
     excluded = @default_excluded ++ excluded
 
-    Mix.Utils.print_tree([{:normal, app}], fn {type, app} ->
-      load(app)
-      {"#{app}#{type(type)}", children_for(app, excluded)}
-    end, opts)
+    app_tree_callback =
+      fn {type, app} ->
+        load(app)
+        {"#{app}#{type(type)}", children_for(app, excluded)}
+      end
+
+    if opts[:format] == "dot" do
+      app_tree = Mix.Utils.build_dot_graph("application tree", [{:normal, app}], app_tree_callback, opts)
+      filename = "app_tree.dot"
+      File.write!(filename, app_tree <> "\n")
+      Mix.shell.info("Generated `#{filename}` in current directory")
+    else
+      Mix.Utils.print_tree([{:normal, app}], app_tree_callback, opts)
+    end
   end
 
   defp load(app) do
diff --git a/lib/mix/lib/mix/tasks/deps.tree.ex b/lib/mix/lib/mix/tasks/deps.tree.ex
@@ -17,11 +17,20 @@ defmodule Mix.Tasks.Deps.Tree do
 
     * `--exclude` - exclude dependencies which you do not want to see printed.
 
-    * `--pretty` - use Unicode codepoints for formatting the tree.
-      Defaults to `true` except on Windows.
+    * `--format` - Can be set to one of either:
+
+      * `pretty` - use Unicode codepoints for formatting the tree.
+        This is the default except on Windows.
+
+      * `plain` - do not use Unicode codepoints for formatting the tree.
+        This is the default on Windows.
+
+      * `dot` - produces a DOT graph description of the dependency tree
+        in `deps_tree.dot` in the current directory.
+        Warning: this will override any previously generated file.
 
   """
-  @switches [only: :string, exclude: :keep, pretty: :boolean]
+  @switches [only: :string, exclude: :keep, format: :string]
 
   @spec run(OptionParser.argv) :: :ok
   def run(args) do
@@ -42,29 +51,48 @@ defmodule Mix.Tasks.Deps.Tree do
           find_dep(deps, app) || Mix.raise("could not find dependency #{app}")
       end
 
-    Mix.Utils.print_tree([root], fn
-      %Mix.Dep{app: app} = dep ->
-        deps =
-          # Do not show dependencies if they were
-          # already show at the top level
-          if not dep.top_level && find_dep(top_level, app) do
-            []
-          else
-            find_dep(deps, app).deps
-          end
-        {format_dep(dep), exclude(deps, excluded)}
-      app ->
-        {Atom.to_string(app), exclude(top_level, excluded)}
-    end, opts)
+    deps_tree_callback =
+      fn
+        %Mix.Dep{app: app} = dep ->
+          deps =
+            # Do not show dependencies if they were
+            # already shown at the top level
+            if not dep.top_level && find_dep(top_level, app) do
+              []
+            else
+              find_dep(deps, app).deps
+            end
+          {format_dep(dep, opts), exclude(deps, excluded)}
+        app ->
+          {Atom.to_string(app), exclude(top_level, excluded)}
+      end
+
+    if opts[:format] == "dot" do
+      deps_tree = Mix.Utils.build_dot_graph("dependency tree", [root], deps_tree_callback, opts)
+      filename = "deps_tree.dot"
+      File.write!(filename, deps_tree <> "\n")
+      Mix.shell.info("Generated `#{filename}` in current directory")
+    else
+      Mix.Utils.print_tree([root], deps_tree_callback, opts)
+    end
   end
 
   defp exclude(deps, excluded) do
     Enum.reject deps, & &1.app in excluded
   end
 
-  defp format_dep(%{app: app, scm: scm, requirement: requirement, opts: opts}) do
-    override = if opts[:override], do: "#{IO.ANSI.bright} *override*#{IO.ANSI.normal}", else: ""
-    "#{app}#{requirement(requirement)} (#{scm.format(opts)})#{override}"
+  defp format_dep(%{app: app, scm: scm, requirement: requirement, opts: deps_opts}, opts) do
+    override =
+      if deps_opts[:override] do
+        "#{IO.ANSI.bright} *override*#{IO.ANSI.normal}"
+      else
+        ""
+      end
+    if opts[:format] == "dot" do
+      {app, "#{requirement(requirement)}#{override}"}
+    else
+      "#{app}#{requirement(requirement)} (#{scm.format(deps_opts)})#{override}"
+    end
   end
 
   defp requirement(nil), do: ""
diff --git a/lib/mix/lib/mix/utils.ex b/lib/mix/lib/mix/utils.ex
@@ -151,7 +151,12 @@ defmodule Mix.Utils do
   """
   @spec print_tree([term], (term -> {String.t, [term]}), Keyword.t) :: :ok
   def print_tree(nodes, callback, opts \\ []) do
-    pretty = Keyword.get(opts, :pretty, elem(:os.type, 0) != :win32)
+    pretty =
+      case Keyword.get(opts, :format) do
+        "pretty" -> true
+        "plain" -> false
+        _ -> elem(:os.type, 0) != :win32
+      end
     print_tree(nodes, [], pretty, callback)
   end
 
@@ -178,6 +183,44 @@ defmodule Mix.Utils do
   defp prefix(true, _, []),  do: "└── "
   defp prefix(true, _, _),   do: "├── "
 
+  @doc """
+  Outputs the given tree according to the callback as a DOT graph.
+
+  The callback will be invoked for each node and it
+  must either return `{printed, children}` tuple or
+  `false` if the given node must not be printed.
+  """
+  @spec build_dot_graph(String.t, [term], (term -> {String.t, [term]}), Keyword.t) :: :ok
+  def build_dot_graph(title, nodes, callback, _opts \\ []) do
+    {parent_name, _} = callback.(hd(nodes))
+    "digraph \"#{title}\" {\n" <>
+    do_build_dot_graph(parent_name, nodes, callback) <>
+    "}"
+  end
+
+  defp do_build_dot_graph(_parent, [], _callback), do: ""
+  defp do_build_dot_graph(parent, [node | nodes], callback) do
+    {name, children} = callback.(node)
+
+    parent_name = case parent do
+      {parent_name, _} -> parent_name
+      parent_name -> parent_name
+    end
+
+    if parent != name do
+      case name do
+        {node_name, edge_info} ->
+          ~s(  "#{parent_name}" -> "#{node_name}" [label=\"#{edge_info}\"]\n)
+        node_name ->
+          ~s(  "#{parent_name}" -> "#{node_name}"\n)
+      end
+    else
+      ""
+    end <>
+    do_build_dot_graph(name, children, callback) <>
+    do_build_dot_graph(parent, nodes, callback)
+  end
+
   @doc false
   # TODO: Deprecate by 1.4
   def underscore(value) do
diff --git a/lib/mix/test/mix/tasks/app.tree_test.exs b/lib/mix/test/mix/tasks/app.tree_test.exs
@@ -19,7 +19,7 @@ defmodule Mix.Tasks.App.TreeTest do
 
     in_tmp context.test, fn ->
       load_apps()
-      Mix.Tasks.App.Tree.run(["--pretty"])
+      Mix.Tasks.App.Tree.run(["--format", "pretty"])
 
       assert_received {:mix_shell, :info, ["test"]}
       assert_received {:mix_shell, :info, ["└── app_deps_sample"]}
@@ -33,7 +33,7 @@ defmodule Mix.Tasks.App.TreeTest do
   test "show the application tree for umbrella apps" do
     in_fixture "umbrella_dep/deps/umbrella", fn ->
       Mix.Project.in_project(:umbrella, ".", fn _ ->
-        Mix.Task.run "app.tree", ["--pretty"]
+        Mix.Task.run "app.tree", ["--format", "pretty"]
         assert_received {:mix_shell, :info, ["foo"]}
         assert_received {:mix_shell, :info, ["└── elixir"]}
         assert_received {:mix_shell, :info, ["bar"]}
@@ -48,11 +48,11 @@ defmodule Mix.Tasks.App.TreeTest do
 
     in_tmp context.test, fn ->
       assert_raise Mix.Error, "could not find application app_deps_sample", fn ->
-        Mix.Tasks.App.Tree.run(["--pretty", "app_deps_sample"])
+        Mix.Tasks.App.Tree.run(["--format", "pretty", "app_deps_sample"])
       end
 
       load_apps()
-      Mix.Tasks.App.Tree.run(["--pretty", "app_deps_sample"])
+      Mix.Tasks.App.Tree.run(["--format", "pretty", "app_deps_sample"])
 
       assert_received {:mix_shell, :info, ["app_deps_sample"]}
       assert_received {:mix_shell, :info, ["├── app_deps2_sample"]}
@@ -67,7 +67,7 @@ defmodule Mix.Tasks.App.TreeTest do
 
     in_tmp context.test, fn ->
       load_apps()
-      Mix.Tasks.App.Tree.run(["--pretty", "--exclude", "app_deps4_sample", "--exclude", "app_deps3_sample"])
+      Mix.Tasks.App.Tree.run(["--format", "pretty", "--exclude", "app_deps4_sample", "--exclude", "app_deps3_sample"])
 
       assert_received {:mix_shell, :info, ["test"]}
       assert_received {:mix_shell, :info, ["└── app_deps_sample"]}
@@ -77,6 +77,28 @@ defmodule Mix.Tasks.App.TreeTest do
     end
   end
 
+  @tag apps: [:test, :app_deps_sample, :app_deps2_sample, :app_deps3_sample, :app_deps4_sample]
+  test "shows the application tree in dot form", context do
+    Mix.Project.push AppDepsSample
+
+    in_tmp context.test, fn ->
+      load_apps()
+      Mix.Tasks.App.Tree.run(["--format", "dot"])
+
+      assert File.read!("app_tree.dot") == """
+        digraph "application tree" {
+          "test" -> "elixir"
+          "test" -> "logger"
+          "logger" -> "elixir"
+          "test" -> "app_deps_sample"
+          "app_deps_sample" -> "app_deps2_sample"
+          "app_deps2_sample" -> "app_deps4_sample (included)"
+          "app_deps_sample" -> "app_deps3_sample"
+        }
+        """
+    end
+  end
+
   def load_apps() do
     :ok = :application.load({:application, :app_deps4_sample, [vsn: '1.0.0', env: []]})
     :ok = :application.load({:application, :app_deps3_sample, [vsn: '1.0.0', env: []]})
diff --git a/lib/mix/test/mix/tasks/deps.tree_test.exs b/lib/mix/test/mix/tasks/deps.tree_test.exs
@@ -33,14 +33,14 @@ defmodule Mix.Tasks.Deps.TreeTest do
     Mix.Project.push ConvergedDepsApp
 
     in_tmp context.test, fn ->
-      Mix.Tasks.Deps.Tree.run(["--pretty"])
+      Mix.Tasks.Deps.Tree.run(["--format", "pretty"])
       assert_received {:mix_shell, :info, ["sample"]}
       assert_received {:mix_shell, :info, ["├── git_repo >= 0.1.0 (" <> _]}
       assert_received {:mix_shell, :info, ["└── deps_on_git_repo 0.2.0 (" <> _]}
       refute_received {:mix_shell, :info, ["    └── git_repo (" <> _]}
 
       Mix.Tasks.Deps.Get.run([])
-      Mix.Tasks.Deps.Tree.run(["--pretty"])
+      Mix.Tasks.Deps.Tree.run(["--format", "pretty"])
       assert_received {:mix_shell, :info, ["sample"]}
       assert_received {:mix_shell, :info, ["├── git_repo >= 0.1.0 (" <> _]}
       assert_received {:mix_shell, :info, ["└── deps_on_git_repo 0.2.0 (" <> _]}
@@ -53,7 +53,7 @@ defmodule Mix.Tasks.Deps.TreeTest do
   test "show the dependency tree for umbrella apps" do
     in_fixture "umbrella_dep/deps/umbrella", fn ->
       Mix.Project.in_project(:umbrella, ".", fn _ ->
-        Mix.Task.run "deps.tree", ["--pretty"]
+        Mix.Task.run "deps.tree", ["--format", "pretty"]
         assert_received {:mix_shell, :info, ["foo"]}
         assert_received {:mix_shell, :info, ["bar"]}
         assert_received {:mix_shell, :info, ["└── foo (../foo)"]}
@@ -66,10 +66,10 @@ defmodule Mix.Tasks.Deps.TreeTest do
 
     in_tmp context.test, fn ->
       assert_raise Mix.Error, "could not find dependency unknown", fn ->
-        Mix.Tasks.Deps.Tree.run(["--pretty", "unknown"])
+        Mix.Tasks.Deps.Tree.run(["--format", "pretty", "unknown"])
       end
 
-      Mix.Tasks.Deps.Tree.run(["--pretty", "deps_on_git_repo"])
+      Mix.Tasks.Deps.Tree.run(["--format", "pretty", "deps_on_git_repo"])
       assert_received {:mix_shell, :info, ["deps_on_git_repo 0.2.0 (" <> _]}
       refute_received {:mix_shell, :info, ["└── git_repo (" <> _]}
     end
@@ -79,7 +79,7 @@ defmodule Mix.Tasks.Deps.TreeTest do
     Mix.Project.push OverriddenDepsApp
 
     in_tmp context.test, fn ->
-      Mix.Tasks.Deps.Tree.run(["--pretty"])
+      Mix.Tasks.Deps.Tree.run(["--format", "pretty"])
       assert_received {:mix_shell, :info, ["sample"]}
       assert_received {:mix_shell, :info, ["├── git_repo (" <> msg]}
       assert_received {:mix_shell, :info, ["└── deps_on_git_repo ~r/0.2.0/ (" <> _]}
@@ -91,7 +91,7 @@ defmodule Mix.Tasks.Deps.TreeTest do
     Mix.Project.push OverriddenDepsApp
 
     in_tmp context.test, fn ->
-      Mix.Tasks.Deps.Tree.run(["--pretty", "--exclude", "deps_on_git_repo"])
+      Mix.Tasks.Deps.Tree.run(["--format", "pretty", "--exclude", "deps_on_git_repo"])
       assert_received {:mix_shell, :info, ["sample"]}
       assert_received {:mix_shell, :info, ["└── git_repo (" <> _]}
       refute_received {:mix_shell, :info, ["└── deps_on_git_repo ~r/0.2.0/ (" <> _]}
@@ -102,10 +102,38 @@ defmodule Mix.Tasks.Deps.TreeTest do
     Mix.Project.push OverriddenDepsApp
 
     in_tmp context.test, fn ->
-      Mix.Tasks.Deps.Tree.run(["--pretty", "--only", "prod"])
+      Mix.Tasks.Deps.Tree.run(["--format", "pretty", "--only", "prod"])
       assert_received {:mix_shell, :info, ["sample"]}
       assert_received {:mix_shell, :info, ["└── git_repo (" <> _]}
       refute_received {:mix_shell, :info, ["└── deps_on_git_repo ~r/0.2.0/ (" <> _]}
     end
   end
+
+  test "shows the dependency tree in DOT graph format", context do
+    Mix.Project.push ConvergedDepsApp
+
+    in_tmp context.test, fn ->
+      Mix.Tasks.Deps.Tree.run(["--format", "dot"])
+
+      assert File.read!("deps_tree.dot") == """
+        digraph "dependency tree" {
+          "sample" -> "git_repo" [label=" >= 0.1.0"]
+          "sample" -> "deps_on_git_repo" [label=" 0.2.0"]
+        }
+        """
+
+      Mix.Tasks.Deps.Get.run([])
+      Mix.Tasks.Deps.Tree.run(["--format", "dot"])
+
+      assert File.read!("deps_tree.dot") == """
+        digraph "dependency tree" {
+          "sample" -> "git_repo" [label=" >= 0.1.0"]
+          "sample" -> "deps_on_git_repo" [label=" 0.2.0"]
+          "deps_on_git_repo" -> "git_repo" [label=""]
+        }
+        """
+    end
+  after
+    purge [DepsOnGitRepo.Mixfile, GitRepo.Mixfile]
+  end
 end
