Mix.install accepts atoms as paths (#12204)

Author: sabiwara

_build/dev/lib/git_app/.mix/compile.lock

@@ -615,6 +615,17 @@ defmodule Mix do
       Hexpm.Repo.query!("SELECT COUNT(1) from packages")
       #=> ...
 
+  The example above can be simplified by passing the application
+  name as an atom for `:config_path` and `:lockfile`:
+
+      Mix.install(
+        [
+          {:hexpm, path: "/tmp/hexpm", env: :dev},
+        ],
+        config_path: :hexpm,
+        lockfile: :hexpm
+      )
+
   ## Limitations
 
   There is one limitation to `Mix.install/2`, which is actually an Elixir
@@ -682,7 +693,7 @@ defmodule Mix do
       end)
 
     config = Keyword.get(opts, :config, [])
-    config_path = opts[:config_path] && Path.expand(opts[:config_path])
+    config_path = expand_path(opts[:config_path], deps, :config_path, "config/config.exs")
     system_env = Keyword.get(opts, :system_env, [])
     consolidate_protocols? = Keyword.get(opts, :consolidate_protocols, true)
 
@@ -729,7 +740,7 @@ defmodule Mix do
         :ok = Mix.Local.append_archives()
         :ok = Mix.ProjectStack.push(@mix_install_project, config, "nofile")
         build_dir = Path.join(install_dir, "_build")
-        external_lockfile = opts[:lockfile] && Path.expand(opts[:lockfile])
+        external_lockfile = expand_path(opts[:lockfile], deps, :lockfile, "mix.lock")
 
         try do
           first_build? = not File.dir?(build_dir)
@@ -800,6 +811,24 @@ defmodule Mix do
     end
   end
 
+  defp expand_path(_path = nil, _deps, _key, _), do: nil
+  defp expand_path(path, _deps, _key, _) when is_binary(path), do: Path.expand(path)
+
+  defp expand_path(app_name, deps, key, relative_path) when is_atom(app_name) do
+    app_dir =
+      case List.keyfind(deps, app_name, 0) do
+        {_, _, opts} when is_list(opts) -> opts[:path]
+        {_, opts} when is_list(opts) -> opts[:path]
+        _ -> Mix.raise("unknown dependency #{inspect(app_name)} given to #{inspect(key)}")
+      end
+
+    unless app_dir do
+      Mix.raise("#{inspect(app_name)} given to #{inspect(key)} must be a path dependency")
+    end
+
+    Path.join(app_dir, relative_path)
+  end
+
   defp install_dir(cache_id) do
     install_root =
       System.get_env("MIX_INSTALL_DIR") ||

lib/mix/lib/mix.ex

@@ -153,6 +153,27 @@ defmodule MixTest do
       Application.delete_env(:unknown_app, :foo, persistent: true)
     end
 
+    test ":config_path with application name", %{tmp_dir: tmp_dir} do
+      config_path = Path.join(tmp_dir, "install_test/config/config.exs")
+      config_path |> Path.dirname() |> File.mkdir_p!()
+
+      File.write!(config_path, """
+      import Config
+      config :myapp, :foo, 1
+      """)
+
+      Mix.install(
+        [
+          {:install_test, path: Path.join(tmp_dir, "install_test")}
+        ],
+        config_path: :install_test
+      )
+
+      assert Application.fetch_env!(:myapp, :foo) == 1
+    after
+      Application.delete_env(:myapp, :foo)
+    end
+
     test ":config_path", %{tmp_dir: tmp_dir} do
       config_path = Path.join(tmp_dir, "config.exs")
 
@@ -271,6 +292,30 @@ defmodule MixTest do
       purge([GitRepo, GitRepo.MixProject])
     end
 
+    test ":lockfile with application name", %{tmp_dir: tmp_dir} do
+      lockfile = Path.join(tmp_dir, "install_test/mix.lock")
+      lockfile |> Path.dirname() |> File.mkdir_p!()
+      Mix.Project.push(GitApp)
+      [_latest_rev, rev | _] = get_git_repo_revs("git_repo")
+      Mix.Dep.Lock.write(%{git_repo: {:git, fixture_path("git_repo"), rev, []}}, file: lockfile)
+      Mix.ProjectStack.pop()
+
+      Mix.install(
+        [
+          {:install_test, path: Path.join(tmp_dir, "install_test")},
+          {:git_repo, git: fixture_path("git_repo")}
+        ],
+        lockfile: :install_test,
+        verbose: true
+      )
+
+      assert_received {:mix_shell, :info, ["* Getting git_repo " <> _]}
+      assert_received {:mix_shell, :info, ["Mix.install/2 using " <> install_dir]}
+      assert File.read!(Path.join(install_dir, "mix.lock")) =~ rev
+    after
+      purge([GitRepo, GitRepo.MixProject])
+    end
+
     test ":lockfile that does not exist" do
       assert_raise File.Error, ~r/bad": no such file or directory/, fn ->
         Mix.install([], lockfile: "bad")