consolidate warn configuration into test_warn_ignore_patterns

Author: SteffenDE

lib/mix/lib/mix/tasks/test.ex

@@ -234,15 +234,17 @@ defmodule Mix.Tasks.Test do
     * `:test_load_pattern` - a regular expression to load test files.
       Defaults to `~r/.*_test\\.exs$/`
 
-    * `:test_warn_pattern` - a regular expression to match potentially
-      misnamed test files and display a warning.
-      Defaults to `~r/^(?!.*_helper\.exs$)(?:.*_test\.ex|.*\.exs)$/`,
-      matching any file that ends in `_test.ex` or `.exs`, ignoring files
-      ending in `_helper.exs`. Warnings can be disabled by setting this to
-      `nil` or `false`.
-
-    * `:test_warn_ignore_files` - a list of files to ignore when displaying
-      warnings about potentially misnamed test files. Defaults to `[]`.
+    * `:test_warn_ignore_patterns` - a list of files, regexes or one-arity functions
+      that restrict which files trigger a warning for a potentially misnamed test file.
+      By default, any file that does not match the `test_load_pattern` and does not
+      end in `_helper.exs` potentially triggers a warning. Defaults to:
+      ```elixir
+      [
+        ~r/.*_helper\\.exs$/,
+        fn file -> Enum.any?(elixirc_paths(Mix.env()), &String.starts_with?(file, &1)) end
+      ]
+      ```
+      This ensures that any helper or test support files are not triggering a warning.
 
   ## Coloring
 
@@ -607,20 +609,8 @@ defmodule Mix.Tasks.Test do
     # Prepare and extract all files to require and run
     test_paths = project[:test_paths] || default_test_paths()
     test_pattern = project[:test_pattern] || "*.{ex,exs}"
-    test_load_pattern = project[:test_load_pattern] || ~r/.*_test\.exs$/
-
-    test_warn_pattern =
-      Keyword.get(project, :test_warn_pattern, ~r/^(?!.*_helper\.exs$)(?:.*_test\.ex|.*\.exs)$/)
-
-    test_warn_ignore_files = project[:test_warn_ignore_files] || []
-
-    # Warn about deprecated configurations
-    if project[:test_pattern] do
-      Mix.shell().info(
-        "warning: the `:test_pattern` configuration is deprecated and will be ignored. Use `:test_load_pattern` instead."
-      )
-    end
 
+    # Warn about deprecated warn configuration
     if project[:warn_test_pattern] do
       Mix.shell().info(
         "warning: the `:warn_test_pattern` configuration is deprecated and will be ignored. Use `:test_warn_pattern` instead."
@@ -633,23 +623,15 @@ defmodule Mix.Tasks.Test do
     # get a list of all files in the test folders, which we filter by the test_load_pattern
     potential_test_files = Mix.Utils.extract_files(test_files, test_pattern)
 
-    unfiltered_test_files =
-      Enum.filter(potential_test_files, &Regex.match?(test_load_pattern, &1))
+    {unfiltered_test_files, _ignored_files, warn_files} =
+      classify_test_files(potential_test_files, project)
 
     matched_test_files =
       unfiltered_test_files
       |> filter_to_allowed_files(allowed_files)
       |> filter_by_partition(shell, partitions)
 
-    # do not warn if test_warn_pattern is nil or false
-    test_warn_pattern &&
-      maybe_warn_misnamed_test_files(
-        potential_test_files,
-        unfiltered_test_files,
-        test_warn_ignore_files,
-        test_load_pattern,
-        test_warn_pattern
-      )
+    warn_files != [] && warn_misnamed_test_files(warn_files, project)
 
     try do
       Enum.each(test_paths, &require_test_helper(shell, &1))
@@ -720,32 +702,65 @@ defmodule Mix.Tasks.Test do
     end
   end
 
-  defp maybe_warn_misnamed_test_files(
-         potential_test_files,
-         unfiltered_test_files,
-         test_warn_ignore_files,
-         test_load_pattern,
-         test_warn_pattern
-       )
-       when is_struct(test_warn_pattern, Regex) do
-    missing_files = (potential_test_files -- unfiltered_test_files) -- test_warn_ignore_files
+  defp classify_test_files(potential_test_files, project) do
+    test_load_pattern = project[:test_load_pattern] || ~r/.*_test\.exs$/
+    elixirc_paths = project[:elixirc_paths] || []
 
-    ignored = Enum.filter(missing_files, &Regex.match?(test_warn_pattern, &1))
+    # ignore any _helper.exs files and files that are compiled (test support files)
+    test_warn_ignore_patterns =
+      project[:test_warn_ignore_patterns] ||
+        [
+          ~r/.*_helper\.exs$/,
+          fn file -> Enum.any?(elixirc_paths, &String.starts_with?(file, &1)) end
+        ]
 
-    if ignored != [] do
-      Mix.shell().info("""
-      warning: the following files do not match the test load pattern #{inspect(test_load_pattern)} and won't be loaded:
+    {to_load, to_ignore, to_warn} =
+      for file <- potential_test_files, reduce: {[], [], []} do
+        {to_load, to_ignore, to_warn} ->
+          cond do
+            Regex.match?(test_load_pattern, file) ->
+              {[file | to_load], to_ignore, to_warn}
 
-      #{Enum.join(ignored, "\n")}
+            ignore_file?(file, test_warn_ignore_patterns) ->
+              {to_load, [file | to_ignore], to_warn}
 
-      This might indicate a typo in a test file name (for example, using "foo_tests.exs" instead of "foo_test.exs").
+            true ->
+              {to_load, to_ignore, [file | to_warn]}
+          end
+      end
 
-      You can adjust which files trigger this warning by configuring the `:test_warn_pattern` option in your
-      Mix project's configuration. To disable the warning entirely, set that option to false.
+    # get the files back in the original order
+    {Enum.reverse(to_load), Enum.reverse(to_ignore), Enum.reverse(to_warn)}
+  end
 
-      For more information, run `mix help test`.
-      """)
-    end
+  defp ignore_file?(file, test_warn_ignore_patterns) do
+    Enum.any?(test_warn_ignore_patterns, fn pattern ->
+      case pattern do
+        regex when is_struct(regex, Regex) ->
+          Regex.match?(regex, file)
+
+        binary when is_binary(binary) ->
+          file == binary
+
+        fun when is_function(fun, 1) ->
+          fun.(file)
+      end
+    end)
+  end
+
+  defp warn_misnamed_test_files(ignored, project) do
+    Mix.shell().info("""
+    warning: the following files do not match the test load pattern #{inspect(project[:test_load_pattern])} and won't be loaded:
+
+    #{Enum.join(ignored, "\n")}
+
+    This might indicate a typo in a test file name (for example, using "foo_tests.exs" instead of "foo_test.exs").
+
+    You can adjust which files trigger this warning by configuring the `:test_warn_pattern` option in your
+    Mix project's configuration. To disable the warning entirely, set that option to false.
+
+    For more information, run `mix help test`.
+    """)
   end
 
   @option_keys [

lib/mix/test/fixtures/test_warn/mix.exs

@@ -6,7 +6,11 @@ defmodule TestWarn.MixProject do
       app: :test_warn,
       version: "0.0.1",
       test_load_pattern: ~r/.*_tests\.exs/,
-      test_warn_pattern: ~r/^(?!.*_helper\.exs$)(?:.*_tests\.ex|.*\.exs)$/
+      test_warn_ignore_patterns: [
+        "test/test_helper.exs",
+        ~r/ignored_regex/,
+        fn file -> file == "test/ignored_file.exs" end
+      ]
     ]
   end
 end