Fix struct update type warning in Mint.WebSocket.Extension

The struct update syntax is deprecated in favor of pattern matching
on the struct earlier in scope and then using map update syntax. This
change rewrites the helper `Mint.WebSocket.Extension.accept_extensions/3`
to follow this pattern. Also I've unrolled the `with` into cases to
avoid weird return values if `client_extensions` is updated to something
that isn't `[Extension.t()]` (probably by erroneously using
`Mint.HTTP.put_private/3` on the conn).

Author: the-mikedavis

lib/mint/web_socket/extension.ex

@@ -203,34 +203,45 @@ defmodule Mint.WebSocket.Extension do
   end
 
   @doc false
+  @spec accept_extensions([t()], Mint.Types.headers()) ::
+          {:ok, [t()]} | {:error, Mint.WebSocket.error()}
   def accept_extensions(client_extensions, response_headers) do
     server_extensions = parse_accepted_extensions(response_headers)
     client_extension_mapping = Enum.into(client_extensions, %{}, &{&1.name, &1})
 
     accept_extensions(server_extensions, [], client_extension_mapping)
   end
 
+  @spec accept_extensions([t()], [t()], %{String.t() => t()}) ::
+          {:ok, [t()]} | {:error, Mint.WebSocket.error()}
   defp accept_extensions(server_extension, acc, client_extension_mapping)
 
   defp accept_extensions([], acc, _), do: {:ok, :lists.reverse(acc)}
 
-  defp accept_extensions([server_extension | server_extensions], acc, client_extension_mapping) do
-    with {:ok, client_extension} <-
-           Map.fetch(client_extension_mapping, server_extension.name),
-         extension = %__MODULE__{client_extension | params: server_extension.params},
-         all_extensions = acc ++ [extension | server_extensions],
-         {:ok, extension} <- client_extension.module.init(extension, all_extensions) do
-      accept_extensions(
-        server_extensions,
-        acc ++ [extension],
-        client_extension_mapping
-      )
-    else
-      :error ->
-        {:error, %WebSocketError{reason: {:extension_not_negotiated, server_extension}}}
+  defp accept_extensions(
+         [%__MODULE__{name: name, params: params} = server_extension | server_extensions],
+         acc,
+         client_extension_mapping
+       ) do
+    case client_extension_mapping do
+      %{^name => %__MODULE__{} = client_extension} ->
+        extension = %{client_extension | params: params}
+        all_extensions = acc ++ [extension | server_extensions]
+
+        case client_extension.module.init(extension, all_extensions) do
+          {:ok, extension} ->
+            accept_extensions(
+              server_extensions,
+              acc ++ [extension],
+              client_extension_mapping
+            )
+
+          error ->
+            error
+        end
 
-      init_error ->
-        init_error
+      _not_found ->
+        {:error, %WebSocketError{reason: {:extension_not_negotiated, server_extension}}}
     end
   end
 
@@ -251,6 +262,7 @@ defmodule Mint.WebSocket.Extension do
   # is exactly equivalent to
   #
   #       Sec-WebSocket-Extensions: foo, bar; baz=2
+  @spec parse_accepted_extensions(Mint.Types.headers()) :: [t()]
   defp parse_accepted_extensions(response_headers) do
     response_headers
     |> Enum.flat_map(fn