fix: update content-length header after decompression

Or keep the original for HEAD requests.
HEAD requests can be used to check the size of remote content
to decide ahead of time whether it is worth fetching. Of course
there’ll be some differences between the compressed and ucompressed
size later, but depending on usecase only the transfer size might be relevant.

Furthermore, content-length is mandatory in HTTP1.0 and in HTTP1.1
mandatory except for chunked transfers. Thus deleting the header after
decompression might be unexpected for later processing steps.
Instead, update the header with the decompressed size.

TODO:
 - Question: keep empty body clause in decompression
 - Question: can body be non-binary (for update content-length function)

Author: TheOneric

lib/tesla/middleware/compression.ex

@@ -67,6 +67,11 @@ defmodule Tesla.Middleware.Compression do
   def decompress({:ok, env}), do: {:ok, decompress(env)}
   def decompress({:error, reason}), do: {:error, reason}
 
+  # HEAD requests may be used to obtain information on the transfer size and properties
+  # and their empty bodies are not actually valid for the possibly indicated encodings
+  # thus we want to preserve them unchanged.
+  def decompress(%Tesla.Env{method: :head} = env), do: env
+
   def decompress(env) do
     codecs = compression_algorithms(Tesla.get_header(env, "content-encoding"))
     {decompressed_body, unknown_codecs} = decompress_body(codecs, env.body)
@@ -123,7 +128,27 @@ defmodule Tesla.Middleware.Compression do
   defp put_decompressed_body(env, body) do
     env
     |> Tesla.put_body(body)
-    |> Tesla.delete_header("content-length")
+    |> update_content_length(body)
+  end
+
+  # The value of the content-length header wil be inaccurate after decompression.
+  # But setting it is mandatory or strongly encouraged in HTTP/1.0 and HTTP/1.1.
+  # Except, when transfer-encoding is used defining content-length is invalid.
+  # Thus we can neither just drop it nor indiscriminately add it, but will update it if it already exist.
+  # Furthermore, content-length is technically allowed to be specified mutliple times if all values match,
+  # to ensure consistency we must therefore make sure to drop any duplicate definitions while updating.
+  defp update_content_length(env, body) when is_binary(body) do
+    if Tesla.get_header(env, "content-length") != nil do
+      env
+      |> Tesla.delete_header("content-length")
+      |> Tesla.put_header("content-length", "#{byte_size(body)}")
+    else
+      env
+    end
+  end
+
+  defp update_content_length(env, _) do
+    env
   end
 end
 

test/tesla/middleware/compression_test.exs

@@ -68,6 +68,24 @@ defmodule Tesla.Middleware.CompressionTest do
 
           "/response-empty" ->
             {200, [{"content-type", "text/plain"}, {"content-encoding", "gzip"}], ""}
+
+          "/response-with-content-length" ->
+            body = :zlib.gzip("decompressed gzip")
+
+            {200,
+             [
+               {"content-type", "text/plain"},
+               {"content-encoding", "gzip"},
+               {"content-length", "#{byte_size(body)}"}
+             ], body}
+
+          "/response-empty-with-content-length" ->
+            {200,
+             [
+               {"content-type", "text/plain"},
+               {"content-encoding", "gzip"},
+               {"content-length", "4194304"}
+             ], ""}
         end
 
       {:ok, %{env | status: status, headers: headers, body: body}}
@@ -103,6 +121,28 @@ defmodule Tesla.Middleware.CompressionTest do
     assert env.headers == [{"content-type", "text/plain"}]
   end
 
+  test "updates existing content-length header" do
+    expected_body = "decompressed gzip"
+    assert {:ok, env} = CompressionResponseClient.get("/response-with-content-length")
+    assert env.body == expected_body
+
+    assert env.headers == [
+             {"content-type", "text/plain"},
+             {"content-length", "#{byte_size(expected_body)}"}
+           ]
+  end
+
+  test "preserves compression headers for HEAD requests" do
+    assert {:ok, env} = CompressionResponseClient.head("/response-empty-with-content-length")
+    assert env.body == ""
+
+    assert env.headers == [
+             {"content-type", "text/plain"},
+             {"content-encoding", "gzip"},
+             {"content-length", "4194304"}
+           ]
+  end
+
   defmodule CompressRequestDecompressResponseClient do
     use Tesla