dap-mouse: support triggering manually

Refactor the value rendering of `dap-mouse' into a new function:
`dap-ui-render-value'.

The new `dap-tooltip-at-point' function creates a dap-mouse posframe under the
cursor, and can be used without `dap-tooltip-mode'. Extend `dap--resp-handler'
to take an error callback. which is leveraged in `dap-tooltip-at-point' to make
the error handling more explicit.

Add functions to evaluate expressions in a new `treemacs' buffer:
`dap-ui-eval-in-buffer', `dap-ui-eval-variable-in-buffer', based on the new
`dap-ui-render-value' function.

Author: nbfalcon

dap-mode.el

@@ -315,17 +315,18 @@ The hook will be called with the session file and the new set of breakpoint loca
   "Get currently active `dap--debug-session'."
   (lsp-workspace-get-metadata "default-session"))
 
-(defun dap--resp-handler (&optional success-callback)
+(defun dap--resp-handler (&optional success-callback error-callback)
   "Generate a response handler, for use in `dap--send-message'.
 
 If the request is successful, call SUCCESS-CALLBACK with the
 entire resulting messsage.
 
-The handler will call `error' on failure."
+The handler will call ERROR-CALLBACK with the message or `error'
+on failure."
   (-lambda ((result &as &hash "success" "message"))
     (if success
         (when success-callback (funcall success-callback result))
-      (error message))))
+      (if error-callback (funcall error-callback message) (error message)))))
 
 (defun dap--session-init-resp-handler (debug-session &optional success-callback)
   "Returned handler will mark the DEBUG-SESSION as failed if call return error.

dap-mouse.el

@@ -114,7 +114,8 @@ ACTIVATEP non-nil means activate mouse motion events."
       (kill-local-variable 'track-mouse))))
 
 (defun dap-tooltip-mouse-motion (event)
-  "Command handler for mouse movement events in `dap-mode-map'."
+  "Command handler for mouse movement events in `dap-mode-map'.
+EVENT is the last mouse movement event."
   (interactive "e")
   (tooltip-hide)
   (when (car (mouse-pixel-position))
@@ -168,22 +169,17 @@ If there is an active selection - return it."
           (setq dap-mouse--hide-timer nil)
           (remove-hook 'post-command-hook #'dap-tooltip-post-tooltip)))))))
 
-(defun dap-tooltip-tips (event)
-  "Show tip for identifier or selection under the mouse.
-The mouse must either point at an identifier or inside a selected
-region for the tip window to be shown.  In the case of a C program
-controlled by GDB, show the associated #define directives when program is
-not executing.
-
-This function must return nil if it doesn't handle EVENT."
-  (setq dap-tooltip--request (1+ dap-tooltip--request))
-
+(defun dap-tooltip-at-point (&optional pos)
+  "Show information about the variable under point.
+The result is displayed in a `treemacs' `posframe'. POS,
+defaulting to `point', specifies where the cursor is and
+consequently where to show the `posframe'."
+  (interactive)
+  (cl-incf dap-tooltip--request)
   (let ((debug-session (dap--cur-session))
-        (mouse-point (posn-point (event-end event)))
+        (mouse-point (or pos (point)))
         (request-id dap-tooltip--request))
-    (when (and (eventp event)
-               (dap--session-running debug-session)
-               dap-tooltip-mode
+    (when (and (dap--session-running debug-session)
                mouse-point)
       (-when-let* ((active-frame-id (-some->> debug-session
                                       dap--debug-session-active-frame
@@ -197,38 +193,40 @@ This function must return nil if it doesn't handle EVENT."
                             (list :expression expression
                                   :frameId active-frame-id
                                   :context "hover"))
-         (-lambda ((&hash "success" "body"
-                          (&hash? "result"
-                                  "variablesReference" variables-reference)))
-           (when (and success
-                      ;; REVIEW: hover failure will yield weird errors involving
-                      ;; process filters, so I resorted to this hack; we should
-                      ;; perhaps do proper error handling?
-                      (= request-id dap-tooltip--request))
-             (add-text-properties
-              start end '(mouse-face dap-mouse-eval-thing-face))
-             ;; REVIEW: I inherited this code; why kill the buffer first,
-             ;; then show it, and then initialize it?
-             (when (get-buffer dap-mouse-buffer)
-               (kill-buffer dap-mouse-buffer))
-             (unless (and (zerop variables-reference) (string-empty-p result))
-               (apply #'posframe-show dap-mouse-buffer
-                      :position start
-                      :accept-focus t
-                      dap-mouse-posframe-properties)
-               (with-current-buffer (get-buffer-create dap-mouse-buffer)
-                 (lsp-treemacs-render
-                  `((:key ,expression
-                     :label ,result
-                     :icon dap-field
-                     ,@(unless (zerop variables-reference)
-                         (list :children
-                               (-partial #'dap-ui-render-variables
-                                         debug-session
-                                         variables-reference)))))
-                  "" nil (buffer-name))))
-             (add-hook 'post-command-hook 'dap-tooltip-post-tooltip)))
-         debug-session))))
+         (dap--resp-handler
+          (-lambda ((&hash "body" (&hash? "result"
+                                          "variablesReference" variables-reference)))
+            (when (= request-id dap-tooltip--request)
+              (add-text-properties
+               start end '(mouse-face dap-mouse-eval-thing-face))
+              ;; Show a dead buffer so that the `posframe' size is consistent.
+              (when (get-buffer dap-mouse-buffer)
+                (kill-buffer dap-mouse-buffer))
+              (unless (and (zerop variables-reference) (string-empty-p result))
+                (apply #'posframe-show dap-mouse-buffer
+                       :position start
+                       :accept-focus t
+                       dap-mouse-posframe-properties)
+                (with-current-buffer (get-buffer-create dap-mouse-buffer)
+                  (dap-ui-render-value debug-session expression
+                                       result variables-reference)))
+              (add-hook 'post-command-hook 'dap-tooltip-post-tooltip)))
+          ;; TODO: hover failure will yield weird errors involving process
+          ;; filters, so I resorted to this hack; we should proably do proper
+          ;; error handling, with a whitelist of allowable errors.
+          #'ignore)
+         debug-session)))))
+
+(defun dap-tooltip-tips (event)
+  "Show tip for identifier or selection under the mouse.
+The mouse must either point at an identifier or inside a selected
+region for the tip window to be shown. In the case of a C program
+controlled by GDB, show the associated #define directives when
+program is not executing.
+
+This function must return nil if it doesn't handle EVENT."
+  (when (and (eventp event) dap-tooltip-mode)
+    (dap-tooltip-at-point (posn-point (event-end event))))
   "")
 
 (provide 'dap-mouse)

dap-ui.el

@@ -785,8 +785,8 @@ DEBUG-SESSION is the debug session triggering the event."
 
 (defun dap-ui-render-variables (debug-session variables-reference _node)
   "Render hierarchical variables for treemacs.
-Usable as the :children argument, when DEBUG-SESSION and
-VARIABLES-REFERENCE are applyied partially.
+Usable as the `treemacs' :children argument, when DEBUG-SESSION
+and VARIABLES-REFERENCE are applied partially.
 
 DEBUG-SESSION specifies the debug session which will be used to
 issue requests.
@@ -817,6 +817,54 @@ adapter for acquiring nested variables and must not be 0."
                    (list :children
                          (-partial #'dap-ui-render-variables debug-session
                                    variables-reference)))))))))
+
+(defun dap-ui-render-value
+    (debug-session expression value variables-reference)
+  "Render a hover result to the current buffer.
+VALUE is the evaluate result, DEBUG-SESSION the debug session as
+usual and EXPRESSION the expression that was originally
+evaluated. VARIABLES-REFERENCE is returned by the evaluate
+request."
+  (lsp-treemacs-render
+   `((:key ,expression
+      :label ,value
+      :icon dap-field
+      ,@(unless (zerop variables-reference)
+          (list :children
+                (-partial #'dap-ui-render-variables
+                          debug-session
+                          variables-reference)))))
+   "" nil (buffer-name)))
+
+(defun dap-ui-eval-in-buffer (expression)
+  "Like `dap-eval', but in a new treemacs buffer."
+  (interactive "sExpr: ")
+  (let ((debug-session (dap--cur-active-session-or-die)))
+    (if-let ((active-frame-id (-some->> debug-session
+                                dap--debug-session-active-frame
+                                (gethash "id"))))
+        (dap--send-message
+         (dap--make-request "evaluate"
+                            (list :expression expression
+                                  :frameId active-frame-id
+                                  :context "hover"))
+         (dap--resp-handler
+          (-lambda ((&hash "body" (&hash? "result" "variablesReference"
+                                          variables-reference)))
+            (with-current-buffer
+                (get-buffer-create (format "*evaluate %s*" expression))
+              (let ((inhibit-read-only t)) (erase-buffer))
+              (dap-ui-render-value debug-session expression result
+                                   variables-reference)
+              (display-buffer (current-buffer)))))
+         debug-session)
+      (error "`dap-eval-in-buffer': no stopped debug session"))))
+
+(defun dap-ui-eval-variable-in-buffer ()
+  "Evaluate the symbol at point in a new buffer."
+  (interactive)
+  (dap-ui-eval-in-buffer (thing-at-point 'symbol)))
+
 (defvar dap-ui--locals-timer nil)
 
 (defun dap-ui-locals--refresh (&rest _)