Automatic installation of eslint language server (#2228)

* Automatic installation of eslint language server

- Fixed also handling of `eslint/confirmLocalESLint`
- Fixes #1932
- Fixes #1870

* Fix typo: unziped -> unzipped

Co-authored-by: Brian Leung <[email protected]>

Author: yyoncho

clients/lsp-eslint.el

@@ -36,6 +36,12 @@
   :group 'lsp-mode
   :link '(url-link "https://github.com/Microsoft/vscode-eslint"))
 
+(defcustom lsp-eslint-unzipped-path (f-join lsp-server-install-dir "eslint/unzipped")
+  "The path to the file in which `eslint' will be stored."
+  :type 'file
+  :group 'lsp-eslint
+  :package-version '(lsp-mode . "7.1"))
+
 (defcustom lsp-eslint-server-command `("node"
                                        "~/server/out/eslintServer.js"
                                        "--stdio")
@@ -67,6 +73,11 @@
   :type '(repeat string)
   :package-version '(lsp-mode . "6.3"))
 
+(defcustom lsp-eslint-node "node"
+  "Path to nodejs."
+  :type 'file
+  :package-version '(lsp-mode . "7.1"))
+
 (defcustom lsp-eslint-options nil
   "The eslint options object to provide args normally passed to
   eslint when executed from a command line (see
@@ -227,16 +238,32 @@ source.fixAll code action."
      (when (called-interactively-p 'any)
        (lsp--info "source.fixAll.eslint action not available")))))
 
+(defun lsp-eslint-server-command ()
+  (if (lsp-eslint-server-exists? lsp-eslint-server-command)
+      lsp-eslint-server-command
+    `(,lsp-eslint-node ,(f-join lsp-eslint-unzipped-path
+                                "extension/server/out/eslintServer.js")
+                       "--stdio")))
+
+(defun lsp-eslint-server-exists? (eslint-server-command)
+  (let* ((command-name (f-base (f-filename (cl-first eslint-server-command))))
+         (first-argument (cl-second eslint-server-command))
+         (first-argument-exist (and first-argument (file-exists-p first-argument))))
+    (if (equal command-name lsp-eslint-node)
+        first-argument-exist
+      (executable-find (cl-first eslint-server-command)))))
+
+(defun lsp-eslint--confirm-local (_workspace _params)
+  ;; don't bother implementing since it will be dropped in next version of the
+  ;; server
+  t)
+
 (lsp-register-client
  (make-lsp-client
   :new-connection
   (lsp-stdio-connection
-   (lambda () lsp-eslint-server-command)
-   (lambda ()
-    (let* ((command-name (f-base (f-filename (cl-first lsp-eslint-server-command))))
-           (first-argument (cl-second lsp-eslint-server-command))
-           (first-argument-exist (and first-argument (file-exists-p first-argument))))
-     (if (equal command-name "node") first-argument-exist (executable-find (cl-first lsp-eslint-server-command))))))
+   (lambda () (lsp-eslint-server-command))
+   (lambda () (lsp-eslint-server-exists? (lsp-eslint-server-command))))
   :activation-fn (lambda (filename &optional _)
                    (or (string-match-p (rx (one-or-more anything) "."
                                            (or "ts" "js" "jsx" "tsx" "html" "vue"))
@@ -248,7 +275,8 @@ source.fixAll code action."
   :multi-root t
   :notification-handlers (ht ("eslint/status" #'lsp-eslint-status-handler))
   :request-handlers (ht ("workspace/configuration" #'lsp-eslint--configuration)
-                        ("eslint/openDoc" 'lsp-eslint--open-doc))
+                        ("eslint/openDoc" #'lsp-eslint--open-doc)
+                        ("eslint/confirmLocalESLint" #'lsp-eslint--confirm-local))
   :server-id 'eslint
   :initialized-fn (lambda (workspace)
                     (with-lsp-workspace workspace
@@ -263,7 +291,20 @@ source.fixAll code action."
                                               ,(lsp-make-file-system-watcher
                                                 :glob-pattern "**/.eslintignore")
                                               ,(lsp-make-file-system-watcher
-                                                :glob-pattern "**/package.json")])))))))
+                                                :glob-pattern "**/package.json")])))))
+  :download-server-fn (lambda (_client callback error-callback _update?)
+                        (let ((tmp-zip (make-temp-file "ext" nil ".zip")))
+                          (delete-file tmp-zip)
+                          (lsp-download-install
+                           (lambda (&rest _)
+                             (condition-case err
+                                 (progn
+                                   (lsp-unzip tmp-zip lsp-eslint-unzipped-path)
+                                   (funcall callback))
+                               (error (funcall error-callback err))))
+                           error-callback
+                           :url (lsp-vscode-extension-url "dbaeumer" "vscode-eslint")
+                           :store-path tmp-zip)))))
 
 (provide 'lsp-eslint)
 ;;; lsp-eslint.el ends here

lsp-mode.el

@@ -7033,6 +7033,46 @@ STORE-PATH to make it executable."
       (set-file-modes store-path #o0700)
       store-path)
      ((f-exists? store-path) store-path))))
+
+;; unzip
+
+(defconst lsp-ext-pwsh-script "powershell -noprofile -noninteractive \
+-nologo -ex bypass Expand-Archive -path '%s' -dest '%s'"
+  "Powershell script to unzip file.")
+
+(defconst lsp-ext-unzip-script "bash -c 'mkdir -p %2$s && unzip -qq %1$s -d %2$s'"
+  "Unzip script to unzip file.")
+
+(defcustom lsp-unzip-script (cond ((executable-find "powershell") lsp-ext-pwsh-script)
+                                  ((executable-find "unzip") lsp-ext-unzip-script)
+                                  (t nil))
+  "The script to unzip."
+  :group 'lsp-mode
+  :type 'string
+  :package-version '(lsp-mode . "7.1"))
+
+(defun lsp-unzip (zip-file dest)
+  "Get extension from URL and extract to DEST."
+  (unless lsp-unzip-script
+    (error "Unable to find `unzip' or `powershell' on the path, please customize `lsp-unzip-script'"))
+  (shell-command (format lsp-unzip-script zip-file dest)))
+
+
+;; VSCode marketplace
+
+(defcustom lsp-vscode-ext-url
+  "https://marketplace.visualstudio.com/_apis/public/gallery/publishers/%s/vsextensions/%s/%s/vspackage"
+  "Vscode extension template url."
+  :group 'lsp-mode
+  :type 'string
+  :package-version '(lsp-mode . "7.1"))
+
+(defun lsp-vscode-extension-url (publisher name &optional version)
+  "Return the URL to vscode extension.
+PUBLISHER is the extension publisher.
+NAME is the name of the extension.
+VERSION is the version of the extension, defaults to `latest'"
+  (format lsp-vscode-ext-url publisher name (or version "latest")))
 
 
 

lsp-protocol.el

@@ -261,7 +261,8 @@ See `-let' for a description of the destructuring mechanism."
     (lsp-get ,source ,key)))
 
 (lsp-interface (eslint:StatusParams  (:state) nil)
-               (eslint:OpenESLintDocParams (:url) nil))
+               (eslint:OpenESLintDocParams (:url) nil)
+               (eslint:ConfirmESLintLibraryParams (:scope :file :libraryPath) nil))
 
 (lsp-interface (haxe:ProcessStartNotification (:title) nil))