feat: Add XML support (#222)

* feat: Add XML support

* Specify path

* Specify path

* Update CHANGELOG.md

Author: jcs090218

.gitmodules

@@ -346,3 +346,9 @@
 	branch = main
 	update = none
 	ignore = dirty
+[submodule "repos/xml"]
+	path = repos/xml
+	url = https://github.com/ObserverOfTime/tree-sitter-xml
+	branch = master
+	update = none
+	ignore = dirty

CHANGELOG.md

@@ -1,6 +1,7 @@
 # Changelog
 
 ## Unreleased
+- Add `Xml` support
 
 ## 0.12.36 - 2023-09-02
 - Add `VHDL` support

queries/xml/highlights.scm

@@ -0,0 +1,171 @@
+;; XML declaration
+
+(XMLDecl "xml" @keyword)
+
+(XMLDecl [ "version" "encoding" "standalone" ] @property)
+
+(XMLDecl (EncName) @string.special)
+
+(XMLDecl (VersionNum) @number)
+
+(XMLDecl [ "yes" "no" ] @boolean)
+
+;; Processing instructions
+
+(PI) @embedded
+
+(PI (PITarget) @keyword)
+
+;; Element declaration
+
+(elementdecl
+  "ELEMENT" @keyword
+  (Name) @tag)
+
+(contentspec
+  (_ (Name) @property))
+
+"#PCDATA" @type.builtin
+
+[ "EMPTY" "ANY" ] @string
+
+[ "*" "?" "+" ] @operator
+
+;; Entity declaration
+
+(GEDecl
+  "ENTITY" @keyword
+  (Name) @constant)
+
+(GEDecl (EntityValue) @string)
+
+(NDataDecl
+  "NDATA" @keyword
+  (Name) @label)
+
+;; Parsed entity declaration
+
+(PEDecl
+  "ENTITY" @keyword
+  "%" @operator
+  (Name) @constant)
+
+(PEDecl (EntityValue) @string)
+
+;; Notation declaration
+
+(NotationDecl
+  "NOTATION" @keyword
+  (Name) @constant)
+
+(NotationDecl
+  (ExternalID
+    (SystemLiteral (URI) @string.special)))
+
+;; Attlist declaration
+
+(AttlistDecl
+  "ATTLIST" @keyword
+  (Name) @tag)
+
+(AttDef (Name) @property)
+
+(AttDef (Enumeration (Nmtoken) @string))
+
+[
+  (StringType)
+  (TokenizedType)
+] @type.builtin
+
+(NotationType "NOTATION" @type.builtin)
+
+[
+  "#REQUIRED"
+  "#IMPLIED"
+  "#FIXED"
+] @attribute
+
+;; Entities
+
+(EntityRef) @constant
+
+((EntityRef) @constant.builtin
+ (#any-of? @constant.builtin
+   "&" "<" ">" """ "'"))
+
+(CharRef) @constant
+
+(PEReference) @constant
+
+;; External references
+
+[ "PUBLIC" "SYSTEM" ] @keyword
+
+(PubidLiteral) @string.special
+
+(SystemLiteral (URI) @markup.link)
+
+;; Processing instructions
+
+(XmlModelPI "xml-model" @keyword)
+
+(StyleSheetPI "xml-stylesheet" @keyword)
+
+(PseudoAtt (Name) @property)
+
+(PseudoAtt (PseudoAttValue) @string)
+
+;; Doctype declaration
+
+(doctypedecl "DOCTYPE" @keyword)
+
+(doctypedecl (Name) @type)
+
+;; Tags
+
+(STag (Name) @tag)
+
+(ETag (Name) @tag)
+
+(EmptyElemTag (Name) @tag)
+
+;; Attributes
+
+(Attribute (Name) @property)
+
+(Attribute (AttValue) @string)
+
+;; Text
+
+(CharData) @markup
+
+(CDSect
+  (CDStart) @markup.heading
+  (CData) @markup.raw
+  "]]>" @markup.heading)
+
+;; Delimiters & punctuation
+
+[
+ "<?" "?>"
+ "<!" "]]>"
+ "<" ">"
+ "</" "/>"
+] @punctuation.delimiter
+
+[
+  "(" ")"
+  "[" "]"
+] @punctuation.bracket
+
+[ "\"" "'" ] @punctuation.delimiter
+
+[ "," "|" "=" ] @operator
+
+;; Misc
+
+[ "INCLUDE" "IGNORE" ] @keyword
+
+(Comment) @comment
+
+(ERROR) @error

repos/xml

@@ -160,6 +160,7 @@ git checkout."
                 ;; XXX
                 ('typescript '("typescript" ("tsx" . tsx)))
                 ('ocaml '("ocaml" ("interface" . ocaml-interface)))
+                ('xml '("tree-sitter-xml" ("tree-sitter-dtd" . dtd)))
                 (_ '("")))))))
 
 (defun tree-sitter-langs--repo-status (lang-symbol)

tree-sitter-langs-build.el

@@ -162,6 +162,7 @@ See `tree-sitter-langs-repos'."
                 (typescript-mode . typescript)
                 (verilog-mode    . verilog)
                 (vhdl-mode       . vhdl)
+                (nxml-mode       . xml)
                 (yaml-mode       . yaml)
                 (zig-mode        . zig))))
     (cl-pushnew entry tree-sitter-major-mode-language-alist