Implement emscripten_cache

Author: allsey87

bazel/README.md

@@ -18,6 +18,9 @@ emsdk_deps()
 load("@emsdk//:emscripten_deps.bzl", emsdk_emscripten_deps = "emscripten_deps")
 emsdk_emscripten_deps(emscripten_version = "2.0.31")
 
+load("@emsdk//:emscripten_cache.bzl", emsdk_emscripten_cache = "emscripten_cache")
+emsdk_emscripten_cache()
+
 load("@emsdk//:toolchains.bzl", "register_emscripten_toolchains")
 register_emscripten_toolchains()
 ```
@@ -66,4 +69,14 @@ rules.
 and all of its dependencies, and does not require amending `.bazelrc`. This
 is the preferred way, since it also unpacks the resulting tarball.
 
+The Emscripten cache shipped by default does not include LTO, 64-bit or PIC
+builds of the system libraries and ports. If you wish to use these features you
+will need to create a secondary cache as follows. Note that the flags are the
+same flags that can be passed to embuilder.
+
+```starlark
+load("@emsdk//:emscripten_cache.bzl", emsdk_emscripten_cache = "emscripten_cache")
+emsdk_emscripten_cache(flags = "--lto")
+```
+
 See `test_external/` for an example using [embind](https://emscripten.org/docs/porting/connecting_cpp_and_javascript/embind.html).

bazel/WORKSPACE

@@ -8,6 +8,10 @@ load(":emscripten_deps.bzl", "emscripten_deps")
 
 emscripten_deps()
 
+load(":emscripten_cache.bzl", "emscripten_cache")
+
+emscripten_cache()
+
 load(":toolchains.bzl", "register_emscripten_toolchains")
 
 register_emscripten_toolchains()

bazel/emscripten_cache.bzl

@@ -0,0 +1,59 @@
+BUILD_FILE_CONTENT_TEMPLATE = """
+package(default_visibility = ['//visibility:public'])
+exports_files(['emscripten_config'])
+"""
+
+def _emscripten_cache_impl(repository_ctx):
+    # Read the default emscripten configuration file
+    default_config = repository_ctx.read(
+        repository_ctx.path(
+            Label("@emsdk//emscripten_toolchain:default_config")
+        )
+    )
+
+    # TODO I need a cross platform way to get embuilder and bin/node
+    if repository_ctx.attr.libraries or repository_ctx.attr.flags:
+        # Get paths to tools (toolchain is not yet setup, so we cannot use emscripten_config)
+        embuilder_path = repository_ctx.path(Label("@emscripten_bin_linux//:emscripten/embuilder.py"))
+        binaryen_root = embuilder_path.dirname.dirname
+        llvm_root = binaryen_root.get_child("bin")
+        nodejs = repository_ctx.path(Label("@nodejs//:node_files")).dirname.get_child('bin/node')
+        # Create configuration file
+        embuilder_config_content  = "LLVM_ROOT = '{}'\n".format(llvm_root)
+        embuilder_config_content += "NODE_JS = '{}'\n".format(nodejs)
+        embuilder_config_content += "BINARYEN_ROOT = '{}'\n".format(binaryen_root)
+        embuilder_config_content += "CACHE = 'cache'\n"
+        repository_ctx.file('embuilder_config', embuilder_config_content)
+        embuilder_config_path = repository_ctx.path('embuilder_config')
+        # Prepare the command line
+        if repository_ctx.attr.libraries:
+            libraries = repository_ctx.attr.libraries
+        else:
+            # if no libraries are requested, build everything
+            libraries = ["ALL"]
+        flags = ["--em-config", embuilder_config_path] + repository_ctx.attr.flags
+        embuilder_args = [embuilder_path] + flags + ["build"] + libraries
+        # Run embuilder
+        repository_ctx.report_progress("Building secondary cache")
+        repository_ctx.execute(embuilder_args, quiet=False)
+        # Override Emscripten's cache with the secondary cache
+        default_config += "CACHE = '{}'\n".format(repository_ctx.path('cache'))
+    # Create the configuration file for the toolchain and export
+    repository_ctx.file('emscripten_config', default_config)
+    repository_ctx.file('BUILD.bazel', BUILD_FILE_CONTENT_TEMPLATE)
+
+_emscripten_cache = repository_rule(
+    implementation = _emscripten_cache_impl,
+    attrs = {
+        "flags": attr.string_list(),
+        "libraries": attr.string_list(),
+    },
+    local = True
+)
+
+def emscripten_cache(flags = [], libraries = []):
+    _emscripten_cache(
+        name = "emscripten_cache",
+        flags = flags,
+        libraries = libraries,
+    )

bazel/emscripten_deps.bzl

@@ -27,6 +27,7 @@ filegroup(
     name = "emcc_common",
     srcs = [
         "emscripten/emcc.py",
+        "emscripten/embuilder.py",
         "emscripten/emscripten-version.txt",
         "emscripten/cache/sysroot_install.stamp",
         "emscripten/src/settings.js",

bazel/emscripten_toolchain/BUILD.bazel

@@ -5,7 +5,7 @@ package(default_visibility = ["//visibility:public"])
 filegroup(
     name = "common_files",
     srcs = [
-        "emscripten_config",
+        "@emscripten_cache//:emscripten_config",
         "env.sh",
         "env.bat",
         "@nodejs//:node_files",
@@ -60,7 +60,7 @@ cc_library(name = "malloc")
 emscripten_cc_toolchain_config_rule(
     name = "wasm",
     cpu = "wasm",
-    em_config = "emscripten_config",
+    em_config = "@emscripten_cache//:emscripten_config",
     emscripten_binaries = "@emsdk//:compiler_files",
     script_extension = select({
         "@bazel_tools//src/conditions:host_windows": "bat",