Issue with `ESMF_HConfigAdd`

[bena-nasa]

EDIT: I think I've narrowed down the problem more, so I would skip to the 3rd and 4th comment in this issue to start

This issue is meant to accompany the corresponding reproducer I will send to @oehmke
You have two hconfigs from 2 yaml files that define that same key:
In the subsequent examples I will refer to the following 2 yaml files as c1 and c2 respectively

Collections:
  c1: {template: foo1}
Exports:
  e1: {collection: c1}

and

Collections:
  c2: {template: foo2}
Exports:
  e2: {collection: c2}

you want to merge them into a single, new hconfig (I will refer to this as merged_config) that will look like this.

Collections:
  c1: {template: foo1}
  c2: {template: foo2}
Exports:
  e1: {collection: c1}
  e2: {collection: c2}

I will separately send the code used to merge these two. The code basically has a procedure that has the "from" hconfig and "to" hconfig. Lets assume that the "from" has the key you want to merge.

Then it checks, is that key in the "to" hconfig.
If not it just add the value of the key in the "from" to the "to" using ESMF_HConfigAdd.

If they "to" has it. Then it iterates over the key in both configs to create a new hconfig. The they key is set to this in the "to" hconfig using ESMF_HConfigSet

I am unable to merge these two hconfigs together. At the end of the day the culprit seems to be that after adding the key, even to an empty HConfig use ESMF_HConfigAdd; ESMF_HconfigIsDefined says the key does not exist.

There are two cases I've tried.

Case 1
hconfigs for c1 and c2 hard coded in source using ESMF_HConfigCreate(content=...
merged_config created as an empty map using ESMF_HConfigCreate(content='{}')

This produces a file with duplicate keys because after adding a key using EMSF_HConfigAdd, IsDefined says there is not key with that name!

Collections:
  c1: {template: foo1}
Exports:
  e1: {coll: c1}
Collections:
  c2: {template: foo2}
Exports:
  e2: {coll: c2}

Case2
hconfigs for c1 and c2 hard coded in source using ESMF_HConfigCreate(content=...
merged_config with no arguments using ESMF_HConfigCreate()

However, to use this, you must not check the return code of ESMF_HConfigIsDefined which is an issue as well

That manages to merge one key

Collections:
  c2: {template: foo2}
  c1: {template: foo1}
Exports: {e1: {coll: c1}}
Exports: {e2: {coll: c2}}

[bena-nasa]

I'll put the source code here that I'm using to try to merge:

#define _VERIFY(A) if (A/=0) then; print*,"Error on line: ", __LINE__; call MPI_Abort(MPI_COMM_WORLD,error_code,status); endif
#define _RC_(rc,status) rc=status);_VERIFY(status
#define _RC _RC_(rc,status)
program test_merge
use ESMF
use mpi
implicit none

integer :: status, error_code
type(ESMF_HConfig) :: h1, h2, merged_hconfig


call ESMF_Initialize(logKindFlag=ESMF_LOGKIND_MULTI, logAppendFlag=.false. )

! case1
!h1 = ESMF_HConfigCreate(content='{Collections: {c1: {template: foo1}}, Exports: {e1: {coll: c1}}}', _RC)
!h2 = ESMF_HConfigCreate(content='{Collections: {c2: {template: foo2}}, Exports: {e2: {coll: c2}}}', _RC)
!merged_hconfig = ESMF_HConfigCreate(content='{}', _RC)

! case2
!h1 = ESMF_HConfigCreate(content='{Collections: {c1: {template: foo1}}, Exports: {e1: {coll: c1}}}', _RC)
!h2 = ESMF_HConfigCreate(content='{Collections: {c2: {template: foo2}}, Exports: {e2: {coll: c2}}}', _RC)
!merged_hconfig = ESMF_HConfigCreate( _RC)

call merge_map(merged_hconfig, h1, 'Collections', _RC)
call merge_map(merged_hconfig, h1, 'Exports', _RC)
call merge_map(merged_hconfig, h2, 'Collections', _RC)
call merge_map(merged_hconfig, h2, 'Exports', _RC)

call ESMF_HConfigFileSave(merged_hconfig, 'merged_hconfig.yaml', _RC)
call ESMF_Finalize()

contains
   subroutine merge_map(hconfig_to, hconfig_from, key, rc)
      type(ESMF_HConfig), intent(inout) :: hconfig_to
      type(ESMF_HConfig), intent(in) :: hconfig_from
      character(len=*), intent(in) :: key
      integer, optional, intent(out) :: rc

      integer :: status
      type(ESMF_HConfig) :: hconfig_temp, hconfig_exist, hconfig_accum, iter_val
      type(ESMF_HConfigIter) :: iter, iter_begin,iter_end
      character(len=:), allocatable :: iter_key
      logical :: to_defined, from_defined

      ! you cannot check the RC here if the hconfig_to was created with no arguments at ESMF_HConfigCreate
      from_defined = ESMF_HConfigIsDefined(hconfig_from, keyString=key, _RC)
      if (from_defined) then
         write(*,*)"bmaa config from has "//key
         hconfig_temp = ESMF_HConfigCreateAt(hconfig_from, keyString=key, _RC)
      else
         write(*,*)"bmaa config from does not have "//key
         if (present(rc)) rc=0
      end if

      to_defined = ESMF_HConfigIsDefined(hconfig_to, keyString=key, _RC)
      if (to_defined) then
         write(*,*)"bmaa config to has key "//key
         hconfig_accum = ESMF_HConfigCreate(_RC)

         iter_begin = ESMF_HConfigIterBegin(hconfig_temp)
         iter_end = ESMF_HConfigIterEnd(hconfig_temp)
         iter = iter_begin
         do while (ESMF_HConfigIterLoop(iter, iter_begin, iter_end, rc=status))
            _VERIFY(status)
            iter_key = ESMF_HConfigAsStringMapKey(iter, _RC)
            iter_val = ESMF_HConfigCreateAtMapVal(iter, _RC)
            call ESMF_HConfigAdd(hconfig_accum, iter_val, addKeyString=iter_key, _RC)
         enddo

         hconfig_exist = ESMF_HConfigCreateAt(hconfig_to, keyString=key, _RC)
         iter_begin = ESMF_HConfigIterBegin(hconfig_exist)
         iter_end = ESMF_HConfigIterEnd(hconfig_exist)
         iter = iter_begin
         do while (ESMF_HConfigIterLoop(iter, iter_begin, iter_end, rc=status))
            _VERIFY(status)
            iter_key = ESMF_HConfigAsStringMapKey(iter, _RC)
            iter_val = ESMF_HConfigCreateAtMapVal(iter, _RC)
            call ESMF_HConfigAdd(hconfig_accum, iter_val, addKeyString=iter_key, _RC)
         enddo
         call ESMF_HConfigSet(hconfig_to, hconfig_accum, keyString=key, _RC)
      else
         write(*,*)"bmaa config to does not have key "//key
         call ESMF_HConfigAdd(hconfig_to, hconfig_temp, addKeyString=key, _RC)
      end if
      if (present(rc)) rc=0

   end subroutine

end program

[bena-nasa]

Ok, I've narrowed it down further. Here is some really simple code. Basically it seems that if you ask an hconfig if a key is defined (and it is not!), then try to add it, a subsequent query says it is not there, see the following code
It is like doing a query with ESMF_HConfigIsDefined is doing something to the data structure that would affect subsequent behavior!

I've tested this via the following code which demonstrates the problem with ESMF 8.8.1 and confirmed I get the same behavior with ifort and gnu. The 2nd print which should be true comes out false.

#define _VERIFY(A) if (A/=0) then; print*,"Error on line: ", __LINE__; call MPI_Abort(MPI_COMM_WORLD,error_code,status); endif
#define _RC_(rc,status) rc=status);_VERIFY(status
#define _RC _RC_(rc,status)
program test_merge
use ESMF
use mpi
implicit none

integer :: status, error_code
type(ESMF_HConfig) :: h1, merged_hconfig, temp_hconfig
logical :: is_defined

call ESMF_Initialize(logKindFlag=ESMF_LOGKIND_MULTI, logAppendFlag=.false. )

h1 = ESMF_HConfigCreate(content='{Collections: {c1: {template: foo1}}, Exports: {e1: {coll: c1}}}', _RC)
merged_hconfig = ESMF_HConfigCreate(content='{}', _RC)

! if you remove the following 2 lines the last print is true
is_defined = ESMF_HConfigIsDefined(merged_hconfig, keyString='Collections', _RC)
print*,'this should be false: ',is_defined

temp_hconfig = ESMF_HConfigCreateAt(h1, keyString='Collections', _RC)
call ESMF_HConfigAdd(merged_hconfig, temp_hconfig, addKeyString='Collections', _RC)

is_defined = ESMF_HConfigIsDefined(merged_hconfig, keyString='Collections', _RC)
print*,'this should be true: ',is_defined

call ESMF_Finalize()

end program

[bena-nasa]

One more data point. I looked in ESMF_HConfigIsDefined and the first thing it does is try to create a new hconfig "at" the passed in key or index. That is passed to the c layer to see if it is valid.

So in the code in the previous comment I changed

! if you remove the following 2 lines the last print is true
is_defined = ESMF_HConfigIsDefined(merged_hconfig, keyString='Collections', _RC)
print*,'this should be false: ',is_defined

to this:

call ESMF_HConfigCreateAt(merged_hconfig, temp_hconfig, keyString='Collections', _RC)

Interesting even though there is NO key of that name in merged_hconfig yet because it was initialized as an empty map, that call does not return an error which itself seems wrong since the key doesn't exist. But it has the same affect. Later on after adding a key of that name, the is_defined call says the key just added is not present.

[tclune]

To the ESMF core team. I suspect that somewhere in the underlying C++ code someone used map[key] when they should have use at() or when the should have explicitly checked if the entry exists.

[anntsay]

Discussed in Core team and try to resolve this in the next release (9.0)