Initial commit

Author: samueltardieu

.formatter.exs

@@ -0,0 +1,4 @@
+# Used by "mix format"
+[
+  inputs: ["{mix,.formatter}.exs", "{config,lib,test}/**/*.{ex,exs}"]
+]

.gitignore

@@ -0,0 +1,23 @@
+# The directory Mix will write compiled artifacts to.
+/_build/
+
+# If you run "mix test --cover", coverage assets end up here.
+/cover/
+
+# The directory Mix downloads your dependencies sources to.
+/deps/
+
+# Where third-party dependencies like ExDoc output generated docs.
+/doc/
+
+# If the VM crashes, it generates a dump, let's ignore it too.
+erl_crash.dump
+
+# Also ignore archive artifacts (built via "mix archive.build").
+*.ez
+
+# Ignore package tarball (built via "mix hex.build").
+otpauth-*.tar
+
+# Temporary files, for example, from tests.
+/tmp/

README.md

@@ -0,0 +1,21 @@
+# OTPAuth
+
+** Decode otpauth URI and extract secret
+
+## Installation
+
+If [available in Hex](https://hex.pm/docs/publish), the package can be installed
+by adding `otpauth` to your list of dependencies in `mix.exs`:
+
+```elixir
+def deps do
+  [
+    {:otpauth, "~> 0.1.0"}
+  ]
+end
+```
+
+Documentation can be generated with [ExDoc](https://github.com/elixir-lang/ex_doc)
+and published on [HexDocs](https://hexdocs.pm). Once published, the docs can
+be found at <https://hexdocs.pm/otpauth>.
+

lib/otpauth.ex

@@ -0,0 +1,54 @@
+defmodule OTPAuth do
+  @moduledoc """
+  This module decodes `otpauth://totp/…` URIs and extract the various fields.
+
+  Once the secret is extracted, it can be used with the
+  [NimbleTOTP](https://hex.pm/packages/nimble_totp) library to generate the current secret.
+  """
+
+  @doc """
+  Extract the secret and label from an otpauth URI, as well as the extra properties.
+
+  The issuer will be extracted either from the label prefix or from the extra URI parameter.
+  If both are present, they have to be equal or an error will be returned.
+
+  ## Examples
+
+      iex> OTPAuth.decompose_uri("otpauth://totp/Acme:alice?secret=MFRGGZA&issuer=Acme")
+      {:ok, "abcd", "alice", %{"issuer" => "Acme"}}
+
+      iex> OTPAuth.decompose_uri("otpauth://totp/Acme:alice?secret=INVALID!&issuer=Acme")
+      :error
+
+  """
+  @spec decompose_uri(String.t()) ::
+          {:ok, binary(), String.t(), map()} | {:error, :invalid_uri}
+  def decompose_uri(uri) when is_binary(uri) do
+    with true <- uri =~ ~r"^otpauth://totp/",
+         {:ok, uri} <- URI.new(uri),
+         ["", label] <- String.split(uri.path, "/"),
+         # Reject empty prefix issuer or empty labels (with or without prefix issuer)
+         false <- label =~ ~r/^(:|$|.*:$)/,
+         query = URI.decode_query(uri.query, %{}, :rfc3986),
+         {secret, query} <- Map.pop(query, "secret"),
+         {:ok, secret} <- Base.decode32(secret, padding: false),
+         param_issuer <- Map.get(query, "issuer"),
+         false <- (param_issuer || "") =~ ":" do
+      case String.split(label |> URI.decode(), ":") do
+        [label] when param_issuer != "" ->
+          {:ok, secret, label, query}
+
+        [^param_issuer, label] ->
+          {:ok, secret, label, query}
+
+        [issuer, label] when is_nil(param_issuer) ->
+          {:ok, secret, label, Map.put(query, "issuer", issuer)}
+
+        _ ->
+          :error
+      end
+    else
+      _ -> :error
+    end
+  end
+end

mix.exs

@@ -0,0 +1,31 @@
+defmodule OTPAuth.MixProject do
+  use Mix.Project
+
+  def project do
+    [
+      app: :otpauth,
+      version: "0.1.0",
+      elixir: "~> 1.18",
+      start_permanent: Mix.env() == :prod,
+      deps: deps(),
+
+      # Docs
+      name: "OTPAuth",
+      source_url: "https://github.com/evenfurther/otpauth",
+      docs: &docs/0
+    ]
+  end
+
+  defp deps do
+    [
+      {:ex_doc, "~> 0.34", only: :dev, runtime: false, warn_if_outdated: true}
+    ]
+  end
+
+  defp docs do
+    [
+      main: "OTPAuth",
+      extras: ["README.md"]
+    ]
+  end
+end

mix.lock

@@ -0,0 +1,8 @@
+%{
+  "earmark_parser": {:hex, :earmark_parser, "1.4.44", "f20830dd6b5c77afe2b063777ddbbff09f9759396500cdbe7523efd58d7a339c", [:mix], [], "hexpm", "4778ac752b4701a5599215f7030989c989ffdc4f6df457c5f36938cc2d2a2750"},
+  "ex_doc": {:hex, :ex_doc, "0.39.1", "e19d356a1ba1e8f8cfc79ce1c3f83884b6abfcb79329d435d4bbb3e97ccc286e", [:mix], [{:earmark_parser, "~> 1.4.44", [hex: :earmark_parser, repo: "hexpm", optional: false]}, {:makeup_c, ">= 0.1.0", [hex: :makeup_c, repo: "hexpm", optional: true]}, {:makeup_elixir, "~> 0.14 or ~> 1.0", [hex: :makeup_elixir, repo: "hexpm", optional: false]}, {:makeup_erlang, "~> 0.1 or ~> 1.0", [hex: :makeup_erlang, repo: "hexpm", optional: false]}, {:makeup_html, ">= 0.1.0", [hex: :makeup_html, repo: "hexpm", optional: true]}], "hexpm", "8abf0ed3e3ca87c0847dfc4168ceab5bedfe881692f1b7c45f4a11b232806865"},
+  "makeup": {:hex, :makeup, "1.2.1", "e90ac1c65589ef354378def3ba19d401e739ee7ee06fb47f94c687016e3713d1", [:mix], [{:nimble_parsec, "~> 1.4", [hex: :nimble_parsec, repo: "hexpm", optional: false]}], "hexpm", "d36484867b0bae0fea568d10131197a4c2e47056a6fbe84922bf6ba71c8d17ce"},
+  "makeup_elixir": {:hex, :makeup_elixir, "1.0.1", "e928a4f984e795e41e3abd27bfc09f51db16ab8ba1aebdba2b3a575437efafc2", [:mix], [{:makeup, "~> 1.0", [hex: :makeup, repo: "hexpm", optional: false]}, {:nimble_parsec, "~> 1.2.3 or ~> 1.3", [hex: :nimble_parsec, repo: "hexpm", optional: false]}], "hexpm", "7284900d412a3e5cfd97fdaed4f5ed389b8f2b4cb49efc0eb3bd10e2febf9507"},
+  "makeup_erlang": {:hex, :makeup_erlang, "1.0.2", "03e1804074b3aa64d5fad7aa64601ed0fb395337b982d9bcf04029d68d51b6a7", [:mix], [{:makeup, "~> 1.0", [hex: :makeup, repo: "hexpm", optional: false]}], "hexpm", "af33ff7ef368d5893e4a267933e7744e46ce3cf1f61e2dccf53a111ed3aa3727"},
+  "nimble_parsec": {:hex, :nimble_parsec, "1.4.2", "8efba0122db06df95bfaa78f791344a89352ba04baedd3849593bfce4d0dc1c6", [:mix], [], "hexpm", "4b21398942dda052b403bbe1da991ccd03a053668d147d53fb8c4e0efe09c973"},
+}

test/otpauth_test.exs

@@ -0,0 +1,95 @@
+defmodule OTPAuthTest do
+  use ExUnit.Case, async: true
+  doctest OTPAuth
+
+  describe "decompose_uri" do
+    test "supports the absence of issuer" do
+      uri = "otpauth://totp/alice?secret=MFRGGZA"
+      assert {:ok, "abcd", "alice", %{}} == OTPAuth.decompose_uri(uri)
+    end
+
+    test "extracts the issuer from the prefix" do
+      uri = "otpauth://totp/Acme:alice?secret=MFRGGZA"
+
+      assert {:ok, "abcd", "alice", %{"issuer" => "Acme"}} ==
+               OTPAuth.decompose_uri(uri)
+    end
+
+    test "extracts the issuer from the URI params" do
+      uri = "otpauth://totp/alice?secret=MFRGGZA&issuer=Acme"
+
+      assert {:ok, "abcd", "alice", %{"issuer" => "Acme"}} ==
+               OTPAuth.decompose_uri(uri)
+    end
+
+    test "accepts identical issuers in prefix and URI params" do
+      uri = "otpauth://totp/Acme:alice?secret=MFRGGZA&issuer=Acme"
+
+      assert {:ok, "abcd", "alice", %{"issuer" => "Acme"}} ==
+               OTPAuth.decompose_uri(uri)
+    end
+
+    test "preserves extra URI params" do
+      uri = "otpauth://totp/Acme:alice?secret=MFRGGZA&issuer=Acme&extra=1"
+
+      {:ok, "abcd", "alice", params} = OTPAuth.decompose_uri(uri)
+      assert [{"extra", "1"}, {"issuer", "Acme"}] == Enum.sort(params)
+    end
+
+    test "rejects an empty label with no prefix issuer" do
+      uri = "otpauth://totp/?secret=MFRGGZA"
+
+      assert :error == OTPAuth.decompose_uri(uri)
+    end
+
+    test "rejects an empty label with a prefix issuer" do
+      uri = "otpauth://totp/Acme:?secret=MFRGGZA"
+
+      assert :error == OTPAuth.decompose_uri(uri)
+    end
+
+    test "rejects an empty prefix issuer" do
+      uri = "otpauth://totp/:alice?secret=MFRGGZA"
+
+      assert :error == OTPAuth.decompose_uri(uri)
+    end
+
+    test "rejects an empty issuer from URI params" do
+      uri = "otpauth://totp/alice?secret=MFRGGZA&issuer="
+
+      assert :error == OTPAuth.decompose_uri(uri)
+    end
+
+    test "rejects different issuers in prefix and URI params" do
+      uri = "otpauth://totp/Acme:alice?secret=MFRGGZA&issuer=Corp"
+
+      assert :error == OTPAuth.decompose_uri(uri)
+    end
+
+    test "rejects URI with wrong scheme or host" do
+      uri = "otpauth://hotp/Acme:alice?secret=MFRGGZA&issuer=Corp"
+
+      assert :error == OTPAuth.decompose_uri(uri)
+    end
+
+    test "rejects URI if issuer contains ':'" do
+      uri = "otpauth://hotp/alice?secret=MFRGGZA&issuer=Acme:Corp"
+
+      assert :error == OTPAuth.decompose_uri(uri)
+    end
+
+    test "rejects URI if label contains ':'" do
+      uri = "otpauth://hotp/Acme:Corp:alice?secret=MFRGGZA"
+
+      assert :error == OTPAuth.decompose_uri(uri)
+    end
+
+    test "decode an URI containing encoded label" do
+      uri =
+        "otpauth://totp/T%C3%A9l%C3%A9com%20Paris:user?secret=MFRGGZA&issuer=T%C3%A9l%C3%A9com%20Paris"
+
+      assert {:ok, "abcd", "user", %{"issuer" => "Télécom Paris"}} ==
+               OTPAuth.decompose_uri(uri)
+    end
+  end
+end

test/test_helper.exs

@@ -0,0 +1 @@
+ExUnit.start()