feat: add profile field to dependency configuration (#1243)

Author: perazz

ci/test_features.sh

@@ -157,6 +157,16 @@ grep -q "WITH_DEBUG_DEPENDENCY" output.txt || { echo "ERROR: WITH_DEBUG_DEPENDEN
 grep -q "DEBUG mode enabled" output.txt || { echo "ERROR: DEBUG mode not enabled in dependency profile test"; exit 1; }
 echo "✓ Debug dependency profile works"
 
+# Test 15: Dependency with profile (instead of features list)
+# features_demo's "prof_feats" profile resolves to ["prof_feat1", "prof_feat2"],
+# which sets the PROF_FEAT1 and PROF_FEAT2 macros
+echo "Test 15: Dependency with profile"
+rm -rf build
+"$fpm" run --profile dep_profile > output.txt
+grep -q "PROF_FEAT1 enabled" output.txt || { echo "ERROR: PROF_FEAT1 not enabled via dependency profile=prof_feats"; exit 1; }
+grep -q "PROF_FEAT2 enabled" output.txt || { echo "ERROR: PROF_FEAT2 not enabled via dependency profile=prof_feats"; exit 1; }
+echo "Dependency profile works"
+
 # Cleanup
 rm -rf build output.txt
 popd

example_packages/features_demo/fpm.toml

@@ -30,6 +30,11 @@ mpi.dependencies.mpi = "*"
 openmp.preprocess.cpp.macros = "USE_OPENMP"
 openmp.dependencies.openmp = "*"
 
+# Features for testing dependency profile resolution
+prof_feat1.preprocess.cpp.macros = "PROF_FEAT1"
+prof_feat2.preprocess.cpp.macros = "PROF_FEAT2"
+
 [profiles]
 development = ["debug"]
 production = ["release", "openmp"]
+prof_feats = ["prof_feat1", "prof_feat2"]

example_packages/features_demo/src/features_demo.f90

@@ -34,6 +34,13 @@ subroutine show_features()
         write(*,*) '✓ OpenMP support enabled'
 #endif
 
+#ifdef PROF_FEAT1
+        write(*,*) '✓ PROF_FEAT1 enabled'
+#endif
+#ifdef PROF_FEAT2
+        write(*,*) '✓ PROF_FEAT2 enabled'
+#endif
+
         ! Compiler info (if available)
         write(*,*) 'Build configuration:'
         call show_compiler_info()

example_packages/features_with_dependency/fpm.toml

@@ -33,8 +33,14 @@ gfortran_optimized.gfortran.dependencies.features_demo = { path = "../features_d
 gfortran_optimized.gfortran.flags = "-O3 -mtune=generic -funroll-loops"
 gfortran_optimized.preprocess.cpp.macros = ["WITH_DEMO"]
 
+# Feature that uses a profile name (instead of features list) to build the dependency
+# "prof_feats" profile in features_demo resolves to ["prof_feat1", "prof_feat2"],
+# which sets the PROF_FEAT1 and PROF_FEAT2 macros
+with_dep_profile.dependencies.features_demo = { path = "../features_demo", profile = "prof_feats" }
+with_dep_profile.preprocess.cpp.macros = ["WITH_DEMO"]
 
 [profiles]
 debug_dep = ["with_feat_debug"]
 release_dep = ["with_feat_release"]
 full_test = ["with_feat_multi", "linux_specific"]
+dep_profile = ["with_dep_profile"]

src/fpm.f90

@@ -159,7 +159,7 @@ subroutine build_model(model, settings, package_config, error)
 
                 ! Adapt it to the current profile/platform
                 dependency = dependency_config%export_config(target_platform, &
-                                                             dep%features,verbose=.false.,error=error)
+                                                             dep%features,dep%profile,verbose=.false.,error=error)
                 if (allocated(error)) exit
 
                 manifest => dependency

src/fpm/manifest/dependency.f90

@@ -9,8 +9,14 @@
 !>"dep3" = { git = "url", tag = "name" }
 !>"dep4" = { git = "url", rev = "sha1" }
 !>"dep0" = { path = "path" }
+!>"dep5" = { path = "path", features = ["feat1", "feat2"] }
+!>"dep6" = { path = "path", profile = "myprofile" }
 !>```
 !>
+!> The `features` and `profile` keys are mutually exclusive.
+!> `features` provides a list of individual feature names;
+!> `profile` provides a single profile name defined in the dependency's manifest.
+!>
 !> To reduce the amount of boilerplate code this module provides two constructors
 !> for dependency types, one basic for an actual dependency (inline) table
 !> and another to collect all dependency objects from a dependencies table,
@@ -66,6 +72,9 @@ module fpm_manifest_dependency
         !> Requested features for the dependency
         type(string_t), allocatable :: features(:)
 
+        !> Requested profile for the dependency (mutually exclusive with features)
+        character(len=:), allocatable :: profile
+
         !> Git descriptor
         type(git_target_t), allocatable :: git
 
@@ -136,6 +145,9 @@ subroutine new_dependency(self, table, root, error)
         call get_list(table, "features", self%features, error)
         if (allocated(error)) return
 
+        !> Get optional profile name
+        call get_value(table, "profile", self%profile)
+
         call get_value(table, "path", uri)
         if (allocated(uri)) then
             if (get_os_type() == OS_WINDOWS) uri = windows_path(uri)
@@ -197,7 +209,8 @@ subroutine check(table, error)
               "branch", &
               "rev", &
               "preprocess", &
-              "features" &
+              "features", &
+              "profile" &
             & ]
 
         call table%get_key(name)
@@ -252,7 +265,13 @@ subroutine check(table, error)
             end if
 
         end if
-        
+
+        ! Check that features and profile are not both specified
+        if (table%has_key('features') .and. table%has_key('profile')) then
+            call syntax_error(error, "Dependency '"//name//"' cannot have both 'features' and 'profile' entries")
+            return
+        end if
+
     end subroutine check
 
     !> Construct new dependency array from a TOML data structure
@@ -381,6 +400,10 @@ subroutine info(self, unit, verbosity)
           end do
        end if
 
+       if (allocated(self%profile)) then
+          write(unit, fmt) " - profile", self%profile
+       end if
+
     end subroutine info
 
     !> Check if two dependency configurations are different
@@ -418,6 +441,7 @@ elemental subroutine dependency_destroy(self)
         if (allocated(self%requested_version)) deallocate(self%requested_version)
         if (allocated(self%git)) deallocate(self%git)
         if (allocated(self%features)) deallocate(self%features)
+        if (allocated(self%profile)) deallocate(self%profile)
 
     end subroutine dependency_destroy
 
@@ -450,7 +474,11 @@ logical function dependency_is_same(this,that)
               if (allocated(this%features).neqv.allocated(other%features)) return
               if (allocated(this%features)) then
                 if (.not.(this%features==other%features)) return
-              endif              
+              endif
+              if (allocated(this%profile).neqv.allocated(other%profile)) return
+              if (allocated(this%profile)) then
+                if (.not.(this%profile==other%profile)) return
+              endif
 
               if ((allocated(this%git).neqv.allocated(other%git))) return
               if (allocated(this%git)) then
@@ -493,7 +521,9 @@ subroutine dump_to_toml(self, table, error)
              if (allocated(error)) return
         endif
        call set_list(table, "features", self%features, error)
-       if (allocated(error)) return        
+       if (allocated(error)) return
+       call set_string(table, "profile", self%profile, error, 'dependency_config_t')
+       if (allocated(error)) return
 
         if (allocated(self%git)) then
             call add_table(table, "git", ptr, error)
@@ -537,7 +567,8 @@ subroutine load_from_toml(self, table, error)
             endif
         end if
         call get_list(table, "features", self%features, error)
-        if (allocated(error)) return        
+        if (allocated(error)) return
+        call get_value(table, "profile", self%profile)
 
         call table%get_keys(list)
         add_git: do ii = 1, size(list)

test/fpm_test/test_manifest.f90

@@ -41,6 +41,10 @@ subroutine collect_manifest(testsuite)
             & new_unittest("dependency-features-present", test_dependency_features_present), &
             & new_unittest("dependency-features-absent",  test_dependency_features_absent),  &
             & new_unittest("dependency-features-empty",   test_dependency_features_empty),   &
+            & new_unittest("dependency-profile-present",  test_dependency_profile_present),  &
+            & new_unittest("dependency-profile-absent",   test_dependency_profile_absent),   &
+            & new_unittest("dependency-profile-features-conflict", &
+            &              test_dependency_profile_features_conflict, should_fail=.true.), &
             & new_unittest("dependency-wrongkey", test_dependency_wrongkey, should_fail=.true.), &
             & new_unittest("dependencies-empty", test_dependencies_empty), &
             & new_unittest("dependencies-typeerror", test_dependencies_typeerror, should_fail=.true.), &
@@ -1809,4 +1813,129 @@ subroutine test_features_demo_serialization(error)
     end subroutine test_features_demo_serialization
 
 
+    !> Test that a dependency with "profile" key is parsed correctly
+    subroutine test_dependency_profile_present(error)
+        !> Error handling
+        type(error_t), allocatable, intent(out) :: error
+
+        type(package_config_t) :: package
+        character(:), allocatable :: temp_file
+        integer :: unit, i, idx_dep0, idx_dep1
+
+        allocate(temp_file, source=get_temp_filename())
+
+        open(file=temp_file, newunit=unit)
+        write(unit, '(a)') &
+            & 'name = "example"', &
+            & 'version = "0.1.0"', &
+            & '[dependencies]', &
+            & '"dep0" = { path = "local/dep0", profile = "release" }', &
+            & '"dep1" = { path = "local/dep1" }'
+        close(unit)
+
+        call get_package_data(package, temp_file, error)
+        if (allocated(error)) return
+
+        if (.not.allocated(package%dependency)) then
+            call test_failed(error, 'No dependencies parsed from manifest')
+            return
+        end if
+
+        idx_dep0 = 0; idx_dep1 = 0
+        do i = 1, size(package%dependency)
+            select case (package%dependency(i)%name)
+            case ('dep0'); idx_dep0 = i
+            case ('dep1'); idx_dep1 = i
+            end select
+        end do
+
+        if (idx_dep0 == 0 .or. idx_dep1 == 0) then
+            call test_failed(error, 'Expected dependencies dep0/dep1 not found')
+            return
+        end if
+
+        ! dep0: profile = "release"
+        if (.not.allocated(package%dependency(idx_dep0)%profile)) then
+            call test_failed(error, 'dep0 profile not allocated')
+            return
+        end if
+        if (package%dependency(idx_dep0)%profile /= 'release') then
+            call test_failed(error, 'dep0 profile value mismatch, expected "release"')
+            return
+        end if
+        ! dep0 should NOT have features allocated
+        if (allocated(package%dependency(idx_dep0)%features)) then
+            if (size(package%dependency(idx_dep0)%features) > 0) then
+                call test_failed(error, 'dep0 features should not be present when profile is used')
+                return
+            end if
+        end if
+
+        ! dep1: no profile key -> should be NOT allocated
+        if (allocated(package%dependency(idx_dep1)%profile)) then
+            call test_failed(error, 'dep1 profile should be unallocated when key is absent')
+            return
+        end if
+    end subroutine test_dependency_profile_present
+
+
+    !> Ensure a dependency without "profile" key leaves it unallocated
+    subroutine test_dependency_profile_absent(error)
+        !> Error handling
+        type(error_t), allocatable, intent(out) :: error
+
+        type(package_config_t) :: package
+        character(:), allocatable :: temp_file
+        integer :: unit, i
+
+        allocate(temp_file, source=get_temp_filename())
+
+        open(file=temp_file, newunit=unit)
+        write(unit, '(a)') &
+            & 'name = "example"', &
+            & '[dependencies]', &
+            & '"a" = { path = "a" }', &
+            & '"b" = { git = "https://example.org/b.git", branch = "main" }'
+        close(unit)
+
+        call get_package_data(package, temp_file, error)
+        if (allocated(error)) return
+
+        if (.not.allocated(package%dependency)) then
+            call test_failed(error, 'No dependencies parsed from manifest')
+            return
+        end if
+
+        do i = 1, size(package%dependency)
+            if (allocated(package%dependency(i)%profile)) then
+                call test_failed(error, 'profile should be unallocated when not specified')
+                return
+            end if
+        end do
+    end subroutine test_dependency_profile_absent
+
+
+    !> Specifying both "features" and "profile" should be an error
+    subroutine test_dependency_profile_features_conflict(error)
+        !> Error handling
+        type(error_t), allocatable, intent(out) :: error
+
+        type(package_config_t) :: package
+        character(:), allocatable :: temp_file
+        integer :: unit
+
+        allocate(temp_file, source=get_temp_filename())
+
+        open(file=temp_file, newunit=unit)
+        write(unit, '(a)') &
+            & 'name = "example"', &
+            & '[dependencies]', &
+            & '"bad" = { path = "bad", features = ["f1"], profile = "release" }'
+        close(unit)
+
+        call get_package_data(package, temp_file, error)
+
+    end subroutine test_dependency_profile_features_conflict
+
+
 end module test_manifest