Add: parsing test case where we can't detect end module statement

If we can't detect the end of a module, then we can't assume that there aren't non-module subprograms present, hence unit type becomes FPM_UNIT_SUBPROGRAM

Author: LKedward

test/fpm_test/test_source_parsing.f90

@@ -27,6 +27,7 @@ subroutine collect_source_parsing(testsuite)
             & new_unittest("program", test_program), &
             & new_unittest("module", test_module), &
             & new_unittest("module-with-subprogram", test_module_with_subprogram), &
+            & new_unittest("module-end-stmt", test_module_end_stmt), &
             & new_unittest("program-with-module", test_program_with_module), &
             & new_unittest("submodule", test_submodule), &
             & new_unittest("submodule-ancestor", test_submodule_ancestor), &
@@ -422,6 +423,71 @@ subroutine test_module_with_subprogram(error)
     end subroutine test_module_with_subprogram
 
 
+    !> Try to parse fortran modules without the full end module statement
+    !>  This should be detected as FPM_UNIT_SUBPROGRAM not FPM_UNIT_MODULE
+    !>  because we cannot guarantee if non-module subprograms are present
+    subroutine test_module_end_stmt(error)
+
+        !> Error handling
+        type(error_t), allocatable, intent(out) :: error
+
+        integer :: unit
+        character(:), allocatable :: temp_file
+        type(srcfile_t), allocatable :: f_source
+
+        allocate(temp_file, source=get_temp_filename())
+
+        open(file=temp_file, newunit=unit)
+        write(unit, '(a)') &
+            & 'module mod1', &
+            & 'contains', &
+            & 'module subroutine f()', &
+            & 'end subroutine f', &
+            & 'module function g()', &
+            & 'end function g', &
+            & 'end', &
+            & 'module mod2', &
+            & 'contains', &
+            & 'module subroutine f()', &
+            & 'end subroutine f', &
+            & 'module function g()', &
+            & 'end function g', &
+            & 'end module mod2'
+        close(unit)
+
+        f_source = parse_f_source(temp_file,error)
+        if (allocated(error)) then
+            return
+        end if
+
+        if (f_source%unit_type /= FPM_UNIT_SUBPROGRAM) then
+            call test_failed(error,'Wrong unit type detected - expecting FPM_UNIT_SUBPROGRAM')
+            return
+        end if
+
+        if (size(f_source%modules_provided) /= 2) then
+            call test_failed(error,'Unexpected modules_provided - expecting two')
+            return
+        end if
+
+        if (size(f_source%modules_used) /= 0) then
+            call test_failed(error,'Incorrect number of modules_used - expecting zero')
+            return
+        end if
+
+        if (.not.('mod1' .in. f_source%modules_provided)) then
+            call test_failed(error,'Missing module in modules_provided')
+            return
+        end if
+
+        if (.not.('mod2' .in. f_source%modules_provided)) then
+            call test_failed(error,'Missing module in modules_provided')
+            return
+        end if
+
+    end subroutine test_module_end_stmt
+
+
     !> Try to parse combined fortran module and program
     !>  Check that parsed unit type is FPM_UNIT_PROGRAM
     subroutine test_program_with_module(error)