Remove arbitrary limit on width of input files, (#941)

Fixes #902.

Author: perazz

src/fpm_filesystem.F90

@@ -6,17 +6,16 @@ module fpm_filesystem
                                OS_UNKNOWN, OS_LINUX, OS_MACOS, OS_WINDOWS, &
                                OS_CYGWIN, OS_SOLARIS, OS_FREEBSD, OS_OPENBSD
     use fpm_environment, only: separator, get_env, os_is_unix
-    use fpm_strings, only: f_string, replace, string_t, split, notabs, str_begins_with_str
+    use fpm_strings, only: f_string, replace, string_t, split, dilate, str_begins_with_str
     use iso_c_binding, only: c_char, c_ptr, c_int, c_null_char, c_associated, c_f_pointer
     use fpm_error, only : fpm_stop, error_t, fatal_error
     implicit none
     private
     public :: basename, canon_path, dirname, is_dir, join_path, number_of_rows, list_files, get_local_prefix, &
             mkdir, exists, get_temp_filename, windows_path, unix_path, getline, delete_file, fileopen, fileclose, &
             filewrite, warnwrite, parent_dir, is_hidden_file, read_lines, read_lines_expanded, which, run, &
-            LINE_BUFFER_LEN, os_delete_dir, is_absolute_path, env_variable, get_home, execute_and_read_output, &
+            os_delete_dir, is_absolute_path, env_variable, get_home, execute_and_read_output, &
             get_dos_path
-    integer, parameter :: LINE_BUFFER_LEN = 32768
 
 #ifndef FPM_BOOTSTRAP
     interface
@@ -332,14 +331,13 @@ function read_lines_expanded(fh) result(lines)
     type(string_t), allocatable :: lines(:)
 
     integer :: i
-    integer :: ilen
-    character(LINE_BUFFER_LEN) :: line_buffer_read, line_buffer_expanded
+    integer :: iostat
+    character(len=:),allocatable :: line_buffer_read
 
     allocate(lines(number_of_rows(fh)))
     do i = 1, size(lines)
-        read(fh, '(A)') line_buffer_read
-        call notabs(line_buffer_read, line_buffer_expanded, ilen)
-        lines(i)%s = trim(line_buffer_expanded)
+        call getline(fh, line_buffer_read, iostat)
+        lines(i)%s = dilate(line_buffer_read)
     end do
 
 end function read_lines_expanded
@@ -350,12 +348,11 @@ function read_lines(fh) result(lines)
     type(string_t), allocatable :: lines(:)
 
     integer :: i
-    character(LINE_BUFFER_LEN) :: line_buffer
+    integer :: iostat
 
     allocate(lines(number_of_rows(fh)))
     do i = 1, size(lines)
-        read(fh, '(A)') line_buffer
-        lines(i)%s = trim(line_buffer)
+        call getline(fh, lines(i)%s, iostat)
     end do
 
 end function read_lines
@@ -560,6 +557,7 @@ logical function exists(filename) result(r)
 function get_temp_filename() result(tempfile)
     !
     use iso_c_binding, only: c_ptr, C_NULL_PTR, c_f_pointer
+    integer, parameter :: MAX_FILENAME_LENGTH = 32768
     character(:), allocatable :: tempfile
 
     type(c_ptr) :: c_tempfile_ptr
@@ -582,7 +580,7 @@ end subroutine c_free
     end interface
 
     c_tempfile_ptr = c_tempnam(C_NULL_PTR, C_NULL_PTR)
-    call c_f_pointer(c_tempfile_ptr,c_tempfile,[LINE_BUFFER_LEN])
+    call c_f_pointer(c_tempfile_ptr,c_tempfile,[MAX_FILENAME_LENGTH])
 
     tempfile = f_string(c_tempfile)
 
@@ -628,8 +626,68 @@ function unix_path(path) result(nixpath)
 
 end function unix_path
 
-
-!> read a line of arbitrary length into a CHARACTER variable from the specified LUN
+!>AUTHOR: fpm(1) contributors
+!!LICENSE: MIT
+!>
+!!##NAME
+!!     getline(3f) - [M_io:READ] read a line of arbintrary length from specified
+!!     LUN into allocatable string (up to system line length limit)
+!!    (LICENSE:PD)
+!!
+!!##SYNTAX
+!!   subroutine getline(unit,line,iostat,iomsg)
+!!
+!!    integer,intent(in)                       :: unit
+!!    character(len=:),allocatable,intent(out) :: line
+!!    integer,intent(out)                      :: iostat
+!!    character(len=:), allocatable, optional  :: iomsg
+!!
+!!##DESCRIPTION
+!!    Read a line of any length up to programming environment maximum
+!!    line length. Requires Fortran 2003+.
+!!
+!!    It is primarily expected to be used when reading input which will
+!!    then be parsed or echoed.
+!!
+!!    The input file must have a PAD attribute of YES for the function
+!!    to work properly, which is typically true.
+!!
+!!    The simple use of a loop that repeatedly re-allocates a character
+!!    variable in addition to reading the input file one buffer at a
+!!    time could (depending on the programming environment used) be
+!!    inefficient, as it could reallocate and allocate memory used for
+!!    the output string with each buffer read.
+!!
+!!##OPTIONS
+!!    LINE    The line read when IOSTAT returns as zero.
+!!    LUN     LUN (Fortran logical I/O unit) number of file open and ready
+!!            to read.
+!!    IOSTAT  status returned by READ(IOSTAT=IOS). If not zero, an error
+!!            occurred or an end-of-file or end-of-record was encountered.
+!!    IOMSG   error message returned by system when IOSTAT is not zero.
+!!
+!!##EXAMPLE
+!!
+!!   Sample program:
+!!
+!!    program demo_getline
+!!    use,intrinsic :: iso_fortran_env, only : stdin=>input_unit
+!!    use,intrinsic :: iso_fortran_env, only : iostat_end
+!!    use FPM_filesystem, only : getline
+!!    implicit none
+!!    integer :: iostat
+!!    character(len=:),allocatable :: line, iomsg
+!!       open(unit=stdin,pad='yes')
+!!       INFINITE: do 
+!!          call getline(stdin,line,iostat,iomsg)
+!!          if(iostat /= 0) exit INFINITE
+!!          write(*,'(a)')'['//line//']'
+!!       enddo INFINITE
+!!       if(iostat /= iostat_end)then
+!!          write(*,*)'error reading input:',iomsg
+!!       endif
+!!    end program demo_getline
+!!
 subroutine getline(unit, line, iostat, iomsg)
 
     !> Formatted IO unit
@@ -644,11 +702,13 @@ subroutine getline(unit, line, iostat, iomsg)
     !> Error message
     character(len=:), allocatable, optional :: iomsg
 
-    character(len=LINE_BUFFER_LEN) :: buffer
-    character(len=LINE_BUFFER_LEN) :: msg
+    integer, parameter :: BUFFER_SIZE = 32768
+    character(len=BUFFER_SIZE)       :: buffer
+    character(len=256)               :: msg
     integer :: size
     integer :: stat
 
+
     allocate(character(len=0) :: line)
     do
         read(unit, '(a)', advance='no', iostat=stat, iomsg=msg, size=size) &
@@ -1095,7 +1155,7 @@ subroutine execute_and_read_output(cmd, output, error, exitstat)
 
         integer :: cmdstat, unit, stat = 0
         character(len=:), allocatable :: cmdmsg, tmp_file
-        character(len=1000) :: output_line
+        character(len=:),allocatable :: output_line
 
         tmp_file = get_temp_filename()
 
@@ -1105,12 +1165,12 @@ subroutine execute_and_read_output(cmd, output, error, exitstat)
         open(newunit=unit, file=tmp_file, action='read', status='old')
         output = ''
         do
-          read(unit, *, iostat=stat) output_line
-          if (stat /= 0) exit
-          output = output//trim(output_line)//' '
+           call getline(unit, output_line, stat)
+           if (stat /= 0) exit
+           output = output//output_line//' '
         end do
-        close(unit, status='delete')
-    end
+        close(unit, status='delete',iostat=stat)
+    end subroutine execute_and_read_output
 
     !> Ensure a windows path is converted to an 8.3 DOS path if it contains spaces
     function get_dos_path(path,error)

src/fpm_strings.f90

@@ -23,7 +23,8 @@
 !! - [[IS_FORTRAN_NAME]]  determine whether a string is an acceptable Fortran entity name
 !! - [[TO_FORTRAN_NAME]]  replace allowed special but unusuable characters in names with underscore
 !!### Whitespace
-!! - [[NOTABS]]  Expand tab characters assuming a tab space every eight characters
+!! - [[NOTABS]]  subroutine to expand tab characters assuming a tab space every eight characters
+!! - [[DILATE]]  function to expand tab characters assuming a tab space every eight characters
 !! - [[LEN_TRIM]]  Determine total trimmed length of **STRING_T** array
 !!### Miscellaneous
 !! - [[FNV_1A]]  Hash a **CHARACTER(*)** string of default kind or a **TYPE(STRING_T)** array
@@ -43,7 +44,7 @@ module fpm_strings
 public :: to_fortran_name, is_fortran_name
 public :: string_array_contains, string_cat, len_trim, operator(.in.), fnv_1a
 public :: replace, resize, str, join, glob
-public :: notabs, remove_newline_characters
+public :: notabs, dilate, remove_newline_characters
 
 !> Module naming
 public :: is_valid_module_name, is_valid_module_prefix, &
@@ -1015,7 +1016,7 @@ pure function to_fortran_name(string) result(res)
     res = replace(string, SPECIAL_CHARACTERS, '_')
 end function to_fortran_name
 
-function is_fortran_name(line) result (lout)
+elemental function is_fortran_name(line) result (lout)
 ! determine if a string is a valid Fortran name ignoring trailing spaces
 ! (but not leading spaces)
     character(len=*),parameter   :: int='0123456789'
@@ -1365,4 +1366,66 @@ elemental impure subroutine notabs(instr,outstr,ilen)
 
 end subroutine notabs
 
+!>AUTHOR: John S. Urban
+!!LICENSE: Public Domain
+!>
+!!##NAME
+!!    dilate(3f) - [M_strings:NONALPHA] expand tab characters
+!!    (LICENSE:PD)
+!!
+!!##SYNOPSIS
+!!
+!!    function dilate(INSTR) result(OUTSTR)
+!!
+!!     character(len=*),intent=(in)  :: INSTR
+!!     character(len=:),allocatable  :: OUTSTR
+!!
+!!##DESCRIPTION
+!!     dilate() converts tabs in INSTR to spaces in OUTSTR.  It assumes a
+!!     tab is set every 8 characters. Trailing spaces are removed.
+!!
+!!     In addition, trailing carriage returns and line feeds are removed
+!!     (they are usually a problem created by going to and from MSWindows).
+!!
+!!##OPTIONS
+!!     instr     Input line to remove tabs from
+!!
+!!##RESULTS
+!!     outstr    Output string with tabs expanded.
+!!
+!!##EXAMPLES
+!!
+!!   Sample program:
+!!
+!!    program demo_dilate
+!!
+!!    use M_strings, only : dilate
+!!    implicit none
+!!    character(len=:),allocatable :: in
+!!    integer                      :: i
+!!       in='  this is my string  '
+!!       ! change spaces to tabs to make a sample input
+!!       do i=1,len(in)
+!!          if(in(i:i) == ' ')in(i:i)=char(9)
+!!       enddo
+!!       write(*,'(a)')in,dilate(in)
+!!    end program demo_dilate
+!!
+function dilate(instr) result(outstr)
+
+   character(len=*), intent(in)  :: instr        ! input line to scan for tab characters
+   character(len=:), allocatable :: outstr       ! tab-expanded version of INSTR produced
+   integer                       :: i
+   integer                       :: icount
+   integer                       :: lgth
+   icount = 0
+   do i = 1, len(instr)
+      if (instr(i:i) == char(9)) icount = icount + 1
+   end do
+   allocate (character(len=(len(instr) + 8*icount)) :: outstr)
+   call notabs(instr, outstr, lgth)
+   outstr = outstr(:lgth)
+
+end function dilate
+
 end module fpm_strings