Merge pull request #510 from SAWGraph/main

Add Sawgraph questions

Author: mahir256

docs/registry/queries/federation/sawgraph-samples-near-PFAS-facilities.rq

@@ -0,0 +1,47 @@
+# Find PFAS results near suspected PFAS industry using facilities, by State
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+PREFIX fio: <http://w3id.org/fio/v1/fio#>
+PREFIX fio-pfas: <http://w3id.org/fio/v1/pfas#>
+PREFIX naics: <http://w3id.org/fio/v1/naics#> 
+PREFIX epa-frs: <http://w3id.org/fio/v1/epa-frs#>
+PREFIX geo: <http://www.opengis.net/ont/geosparql#>
+PREFIX kwg-ont: <http://stko-kwg.geog.ucsb.edu/lod/ontology/>
+PREFIX kwgr: <http://stko-kwg.geog.ucsb.edu/lod/resource/>
+PREFIX spatial: <http://purl.org/spatialai/spatial/spatial-full#>
+PREFIX coso:<http://w3id.org/coso/v1/contaminoso#> 
+PREFIX qudt: <http://qudt.org/schema/qudt/>
+
+SELECT DISTINCT ?observation  ?stateName ?townName ?concentration ?unit ?normalizedConc ?substance ?date ?facilityName ?industryName WHERE {
+  #find s2 cells with detect samples
+   ?sp a coso:SamplePoint;
+    kwg-ont:sfWithin ?s2, ?town.
+   ?observation coso:observedAtSamplePoint ?sp;
+        coso:ofDSSToxSubstance/skos:altLabel ?substance;
+        coso:hasResult ?result;
+        coso:observedTime ?date.
+   ?result qudt:quantityValue/qudt:numericValue ?concentration;
+           qudt:quantityValue/qudt:hasUnit ?rawUnit.  #only detected values
+   ?rawUnit qudt:symbol ?unit;
+            qudt:conversionMultiplier ?unitConversion.
+  BIND((?unitConversion * ?concentration) as ?normalizedConc ) #normalize different units
+  ?s2 rdf:type kwg-ont:S2Cell_Level13.
+  ?town rdf:type kwg-ont:AdministrativeRegion_3;
+        kwg-ont:administrativePartOf+ ?state;
+        rdfs:label ?townName.
+  ?state rdf:type kwg-ont:AdministrativeRegion_1;
+         rdfs:label ?stateName. 
+        
+  #find facilities in s2 cells
+  ?facility kwg-ont:sfWithin ?s2;
+  		rdf:type fio:Facility;
+    	rdfs:label ?facilityName;
+        fio:ofIndustry ?industry.
+  ?pfasIndustryList rdfs:subClassOf fio-pfas:IndustryCollectionByPFASContaminationConcern;
+    				  fio:hasMember ?industry. 
+  ?industry rdfs:label ?industryName. 
+  
+} ORDER BY DESC(?normalizedConc) # highest normalized concentration first
+limit 100
+

docs/registry/queries/sawgraph/samples_longchain_biota.rq

@@ -0,0 +1,35 @@
+# Retrieve 100 plant and animal (biota) sample results with the location type sampled, sample material type, observed property, substance, and detected result.  
+PREFIX coso: <http://w3id.org/coso/v1/contaminoso#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX rdf:  <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+PREFIX qudt: <http://qudt.org/schema/qudt/>
+PREFIX pfas: <http://w3id.org/pfas/v1/>
+PREFIX dsstox: <http://w3id.org/DSSTox/v1/>
+PREFIX geo: <http://www.opengis.net/ont/geosparql#>
+
+SELECT ?sample ?sampleName ?location ?coordinates (GROUP_CONCAT(DISTINCT ?materialTypeName;separator=",") as ?materialType) ?substance ?substanceName ?value ?unit ?date 
+WHERE {
+  ?sample rdf:type coso:BiotaSample;
+            coso:sampleOfMaterialType ?sampletype;
+    		coso:fromSamplePoint ?samplePoint;
+      		rdfs:label ?sampleName.
+  ?observation coso:analyzedSample ?sample;
+            a coso:ContaminantSampleObservation;
+            coso:hasFeatureOfInterest ?feature;
+            coso:ofSubstance ?substance;
+            coso:observedTime ?date;
+            coso:hasResult ?result.
+    ?substance rdf:type pfas:PerFAs; #Perfluoroalkyl substances (not poly)
+              skos:altLabel ?substanceName;
+              dsstox:hasCarbonChainLength ?carbonChainLength.
+  	FILTER(?carbonChainLength > 6)  #carbon chain > 6
+    ?result coso:measurementValue ?value.
+  	OPTIONAL{?result coso:measurementUnit/qudt:symbol ?unit.}  
+  	MINUS {VALUES ?value{"non-detect" "non-quantified"}} #only detect values
+  	?samplePoint geo:hasGeometry/geo:asWKT ?coordinates.
+  	?feature coso:ofFeatureType/rdfs:label ?location.
+  	?sampletype rdf:type coso:SampleMaterialType;
+            rdfs:label ?materialTypeName.
+} GROUP BY ?sample ?sampleName ?location ?substance ?substanceName ?value ?unit ?date ?coordinates
+LIMIT 100