Very basic script to evaluate script via GHA input and output result to GHA output

Very much inspired by https://github.com/actions/github-script

Author: gaggle

lib/CLI.ex

@@ -1,6 +1,9 @@
 defmodule ElixirScript.CLI do
-  def main(args \\ []) do
-    IO.puts "ElixirScript.CLI 👋"
-    IO.inspect args
+  alias ElixirScript.Core
+
+  def main(_args \\ []) do
+    script = Core.get_input("script", required: true)
+    {value, _binding} = Code.eval_string(script)
+    Core.set_output("result", value)
   end
 end

lib/command_utils.ex

@@ -0,0 +1,5 @@
+defmodule ElixirScript.CommandUtils do
+  def to_command_value(nil), do: ""
+
+  def to_command_value(input) when is_binary(input), do: input
+end

lib/core.ex

@@ -0,0 +1,26 @@
+defmodule ElixirScript.Core do
+  alias ElixirScript.FileCommand
+
+  def get_input(name, opts \\ []) do
+    required = Keyword.get(opts, :required, false)
+    trim_whitespace = Keyword.get(opts, :trim_whitespace, true)
+
+    env_var_name = "INPUT_#{String.replace(name, " ", "_") |> String.upcase()}"
+    val = System.get_env(env_var_name, "")
+
+    cond do
+      required && val == "" ->
+        raise "Input '#{name}' required but not supplied in environment variable '#{env_var_name}'"
+
+      trim_whitespace == false ->
+        val
+
+      true ->
+        String.trim(val)
+    end
+  end
+
+  def set_output(name, value) do
+    FileCommand.issue_file_command("OUTPUT", FileCommand.prepare_key_value_message(name, value))
+  end
+end

lib/file_command.ex

@@ -0,0 +1,44 @@
+defmodule ElixirScript.FileCommand do
+  alias ElixirScript.CommandUtils
+
+  def issue_file_command(command, message) do
+    file_path = System.fetch_env!("GITHUB_#{command}")
+
+    if not File.exists?(file_path) do
+      raise "Missing file at path: #{file_path}"
+    end
+
+    File.write!(file_path, CommandUtils.to_command_value(message) <> "\n", [:append])
+  end
+
+  @doc """
+  Prepares a key-value message in a format that uses a unique GitHub Actions-style delimiter
+
+  This function safely prepares a message based on the provided key and value.
+  It encodes that message using a specific delimiter format "ghadelimiter_" followed by a unique reference.
+
+  Note: This format is taken from https://github.com/actions/toolkit/blob/main/packages/core/src/file-command.ts#L27
+  I don't really understand how this delimiter works, and I can't find it documented.
+  But I guess GitHub Actions listens for the "ghadelimiter_" part and then uses that to delimit the message.
+
+  ## Raises:
+    - An error if the key or converted value contains the delimiter
+      (this can't realistically happen as the delimiter is randomly generated, but better cautious than sorry)
+  """
+  def prepare_key_value_message(key, value) do
+    delimiter = "ghadelimiter_" <> to_string(:erlang.ref_to_list(:erlang.make_ref()))
+
+    converted_value = CommandUtils.to_command_value(value)
+
+    cond do
+      String.contains?(key, delimiter) ->
+        raise "Unexpected input: name should not contain the delimiter \"#{delimiter}\""
+
+      String.contains?(converted_value, delimiter) ->
+        raise "Unexpected input: value should not contain the delimiter \"#{delimiter}\""
+
+      true ->
+        "#{key}<<#{delimiter}\n#{converted_value}\n#{delimiter}"
+    end
+  end
+end