Inline lots of environment variables

The biggest change is going from := to :-
The downside is we dont have these nice list of environment variables
at the top of each function.

The upside is we are no longer making global assignments

The main difference between := and :- is that :- just substitutes
the word on the right hand side inline, while := assigns the variable
on the left hand side to the value on the right.

    echo ${A:=something} # assign A to 'something', then expand $A
    echo ${A:-something} # expand to 'something'

One reason this is hard to understand is the zsh manpages describe
:= and :- in an inverted manner - one description uses negatives
and exceptions, while the other uses positives. I'm not sure if its
more accurate but at least we aren't polluting variables as much.

This rabbit hole happened when I came across `setopt warn_global_assign`

Author: Jonathan Dahan

functions/geometry_echo.zsh

@@ -1,3 +1,3 @@
 # geometry_echo - simple echo for a balanced terminal
 
-geometry_echo() { echo -n ${GEOMETRY_ECHO:=''}; }
+geometry_echo() { echo -n ${GEOMETRY_ECHO:-''}; }

functions/geometry_git.zsh

@@ -13,78 +13,64 @@ geometry_git_time() {
   local seconds_since_last_commit
   last_commit=$(git log -1 --pretty=format:'%at' 2> /dev/null)
 
-  [[ -z "$last_commit" ]] && ansi ${GEOMETRY_COLOR_NO_TIME:=default} ${GEOMETRY_GIT_NO_COMMITS_MESSAGE:=no-commits} && return
+  [[ -z "$last_commit" ]] && ansi ${GEOMETRY_COLOR_NO_TIME:-default} ${GEOMETRY_GIT_NO_COMMITS_MESSAGE:-no-commits} && return
 
   now=$(date +%s)
   seconds_since_last_commit=$((now - last_commit))
-  geometry::time $seconds_since_last_commit ${GEOMETRY_GIT_TIME_DETAILED:=false}
+  geometry::time $seconds_since_last_commit ${GEOMETRY_GIT_TIME_DETAILED:-false}
 }
 
 geometry_git_branch() {
-  ansi ${GEOMETRY_GIT_COLOR_BRANCH:=242} $(git symbolic-ref --short HEAD || git rev-parse --short HEAD)
+  ansi ${GEOMETRY_GIT_COLOR_BRANCH:-242} $(git symbolic-ref --short HEAD || git rev-parse --short HEAD)
 }
 
 geometry_git_status() {
-  : ${GEOMETRY_GIT_COLOR_DIRTY:=red}
-  : ${GEOMETRY_GIT_COLOR_CLEAN:=green}
-  : ${GEOMETRY_GIT_SYMBOL_DIRTY:="⬡"}
-  : ${GEOMETRY_GIT_SYMBOL_CLEAN:="⬢"}
-  local _status
   command git rev-parse --git-dir > /dev/null 2>&1 || return
-  _status=$([[ -z "$(git status --porcelain --ignore-submodules HEAD)" ]] && [[ -z "$(git ls-files --others --modified --exclude-standard $(git rev-parse --show-toplevel))" ]] && echo CLEAN || echo DIRTY)
-  ansi ${(e):-\$GEOMETRY_GIT_COLOR_${_status}} ${(e):-\$GEOMETRY_GIT_SYMBOL_${_status}}
+
+  [[ -z "$(git status --porcelain --ignore-submodules HEAD)" ]] \
+  && [[ -z "$(git ls-files --others --modified --exclude-standard $(git rev-parse --show-toplevel))" ]] \
+  && ansi ${GEOMETRY_GIT_COLOR_DIRTY:-red} ${GEOMETRY_GIT_SYMBOL_DIRTY:-"⬡"} \
+  || ansi ${GEOMETRY_GIT_COLOR_CLEAN:-green} ${GEOMETRY_GIT_SYMBOL_CLEAN:-"⬢"}
 }
 
 geometry_git_rebase() {
-  : ${GEOMETRY_GIT_SYMBOL_REBASE:="®"}
   local git_dir
   git_dir=$(git rev-parse --git-dir)
   [[ -d "$git_dir/rebase-merge" ]] || [[ -d "$git_dir/rebase-apply" ]] || return
-  echo "$GEOMETRY_GIT_SYMBOL_REBASE"
+  echo ${GEOMETRY_GIT_SYMBOL_REBASE:-"®"}
 }
 
 geometry_git_remote() {
-  : ${GEOMETRY_GIT_SYMBOL_UNPUSHED:="⇡"}
-  : ${GEOMETRY_GIT_SYMBOL_UNPULLED:="⇣"}
-  : ${GEOMETRY_GIT_SYMBOL_CONFLICTS_SOLVED:="◆"}
-  : ${GEOMETRY_GIT_SYMBOL_CONFLICTS_UNSOLVED:="◈"}
-
-  local common_base
-  local local_commit
-  local remote_commit
-  local_commit=$(git rev-parse "@" 2>/dev/null)
-  remote_commit=$(git rev-parse "@{u}" 2>/dev/null)
+  local unpushed=${GEOMETRY_GIT_SYMBOL_UNPUSHED:-"⇡"}
+  local unpulled=${GEOMETRY_GIT_SYMBOL_UNPULLED:-"⇣"}
+  local local_commit && local_commit=$(git rev-parse "@" 2>/dev/null)
+  local remote_commit && remote_commit=$(git rev-parse "@{u}" 2>/dev/null)
 
   [[ $local_commit == "@" || $local_commit == $remote_commit ]] && return
 
-  common_base=$(git merge-base "@" "@{u}" 2>/dev/null) # last common commit
-  [[ $common_base == $remote_commit ]] && echo $GEOMETRY_GIT_SYMBOL_UNPUSHED && return
-  [[ $common_base == $local_commit ]]  && echo $GEOMETRY_GIT_SYMBOL_UNPULLED && return
+  local common_base && common_base=$(git merge-base "@" "@{u}" 2>/dev/null) # last common commit
+  [[ $common_base == $remote_commit ]] && echo $unpushed && return
+  [[ $common_base == $local_commit ]]  && echo $unpulled && return
 
-  echo "$GEOMETRY_GIT_SYMBOL_UNPUSHED $GEOMETRY_GIT_SYMBOL_UNPULLED"
+  echo "$unpushed $unpulled"
 }
 
 geometry_git_symbol() { echo ${(j: :):-$(geometry_git_rebase) $(geometry_git_remote)}; }
 
 geometry_git_conflicts() {
-  : ${GEOMETRY_GIT_COLOR_CONFLICTS_UNSOLVED:=red}
-  : ${GEOMETRY_GIT_COLOR_CONFLICTS_SOLVED:=green}
-  local conflicts
   local _grep
-  local conflict_list
-  local raw_file_count
-  local file_count
-  local raw_total
-  local total
+  local conflicts conflict_list
+  local file_count raw_file_count
+  local total raw_total
   conflicts=$(git diff --name-only --diff-filter=U)
 
   [[ -z "$conflicts" ]] && return
 
   pushd -q $(git rev-parse --show-toplevel)
 
   _grep=${GEOMETRY_GIT_GREP:=${commands[rg]:=${commands[ag]:=${commands[grep]}}}}
-
   conflict_list=$($_grep -cH '^=======$' $conflicts)
+
   popd -q
 
   raw_file_count="${#${(@f)conflict_list}}"
@@ -93,9 +79,11 @@ geometry_git_conflicts() {
   raw_total=$(echo $conflict_list | cut -d ':' -f2 | paste -sd+ - | bc)
   total=${raw_total##*(  )}
 
-  [[ -z "$total" ]] && ansi $GEOMETRY_GIT_COLOR_CONFLICTS_SOLVED $GEOMETRY_GIT_SYMBOL_CONFLICTS_SOLVED && return
+  [[ -z "$total" ]] && ansi ${GEOMETRY_GIT_COLOR_CONFLICTS_SOLVED:-green} ${GEOMETRY_GIT_SYMBOL_CONFLICTS_SOLVED:-"◆"} && return
+
+  count="(${file_count}f|${total}c)"
 
-  ansi $GEOMETRY_GIT_COLOR_CONFLICTS_UNSOLVED "$GEOMETRY_GIT_SYMBOL_CONFLICTS_UNSOLVED (${file_count}f|${total}c)"
+  ansi ${GEOMETRY_GIT_COLOR_CONFLICTS_UNSOLVED:-red} "${GEOMETRY_GIT_SYMBOL_CONFLICTS_UNSOLVED:-'◈'} $count"
 }
 
 geometry_git() {
@@ -105,16 +93,13 @@ geometry_git() {
     && ansi ${GEOMETRY_GIT_COLOR_BARE:=blue} ${GEOMETRY_GIT_SYMBOL_BARE:="⬢"} \
     && return
 
-  echo -n $(geometry_git_symbol) $(geometry_git_branch) \
-    $(geometry::git_wrapper \
-      $(geometry_git_conflicts) \
-      $(geometry_git_time) \
-      $(geometry_git_stashes) \
-      $(geometry_git_status)
-    )
-}
+  local geometry_git_details && geometry_git_details=(
+    $(geometry_git_conflicts)
+    $(geometry_git_time)
+    $(geometry_git_stashes)
+    $(geometry_git_status)
+  )
 
-geometry::git_wrapper() {
-  : ${GEOMETRY_GIT_SEPARATOR:=" :: "}
-  echo -n ${(pj.$GEOMETRY_GIT_SEPARATOR.)$(print -r "$@")}
+  local separator=${GEOMETRY_GIT_SEPARATOR:-" :: "}
+  echo -n $(geometry_git_symbol) $(geometry_git_branch) ${(pj.$separator.)geometry_git_details}
 }

functions/geometry_hostname.zsh

@@ -2,6 +2,6 @@
 
 geometry_hostname() {
   local _host=${HOST:-$HOSTNAME}
-  [[ "$_host" = "${GEOMETRY_HOSTNAME_HIDE_ON:=localhost}" ]] && return
-  echo -n "${USER}${GEOMETRY_HOSTNAME_SEPARATOR:=@}${_host}"
+  [[ "$_host" = "${GEOMETRY_HOSTNAME_HIDE_ON:-localhost}" ]] && return
+  echo -n "${USER}${GEOMETRY_HOSTNAME_SEPARATOR:-@}${_host}"
 }

functions/geometry_path.zsh

@@ -1,7 +1,7 @@
 # geometry_path - show the current path
 
 geometry_path() {
-  local dir=${GEOMETRY_PATH_SYMBOL_HOME:="%3~"}   # symbol representing the home directory
-  ( ${GEOMETRY_PATH_SHOW_BASENAME:=false} ) && dir=${PWD:t}
-  ansi ${GEOMETRY_PATH_COLOR:=blue} $dir
+  local dir=${GEOMETRY_PATH_SYMBOL_HOME:-"%3~"}   # symbol representing the home directory
+  ( ${GEOMETRY_PATH_SHOW_BASENAME:-false} ) && dir=${PWD:t}
+  ansi ${GEOMETRY_PATH_COLOR:-blue} $dir
 }

functions/geometry_status.zsh

@@ -1,34 +1,33 @@
 # geometry_status - show a symbol with error/success and root/non-root information
 
 geometry_status() {
-  : ${GEOMETRY_STATUS_COLOR:=default}
-  : ${GEOMETRY_STATUS_COLOR_ERROR:=red}
-  : ${GEOMETRY_STATUS_SYMBOL:=▲}
-  : ${GEOMETRY_STATUS_SYMBOL_ERROR:=△}
-  : ${GEOMETRY_STATUS_SYMBOL_ROOT:=▼}
-  : ${GEOMETRY_STATUS_SYMBOL_ROOT_ERROR:=▽}
+  local root; [[ $UID = 0 || $EUID = 0 ]] && root=true || root=false
+  local error; (( $GEOMETRY_LAST_STATUS )) && error=true || error=false
 
-  ( ${GEOMETRY_STATUS_SYMBOL_COLOR_HASH:=false} ) && {
-    local colors=({1..9})
+  local color=${GEOMETRY_STATUS_COLOR:-default}
 
-    (($(echotc Co) == 256)) && colors+=({17..230})
+  if ( $error ); then color=${GEOMETRY_STATUS_COLOR_ERROR:-red}; else
+    ( ${GEOMETRY_STATUS_SYMBOL_COLOR_HASH:=false} ) && {
+      local colors=({1..9})
 
-    if (( ${+GEOMETRY_STATUS_SYMBOL_COLOR_HASH_COLORS} )); then
-      colors=(${GEOMETRY_STATUS_SYMBOL_COLOR_HASH_COLORS})
-    fi
+      (($(echotc Co) == 256)) && colors+=({17..230})
 
-    local sum=0; for c in ${(s::)^HOST}; do ((sum += $(print -f '%d' "'$c"))); done
+      if (( ${+GEOMETRY_STATUS_SYMBOL_COLOR_HASH_COLORS} )); then
+        colors=(${GEOMETRY_STATUS_SYMBOL_COLOR_HASH_COLORS})
+      fi
 
-    local index=$(($sum % ${#colors}))
+      local sum=0; for c in ${(s::)^HOST}; do ((sum += $(print -f '%d' "'$c"))); done
 
-    [[ "$index" -eq 0 ]] && index=1
+      local index=$(($sum % ${#colors}))
 
-    GEOMETRY_STATUS_COLOR=${colors[${index}]}
-  }
+      [[ "$index" -eq 0 ]] && index=1
 
-  local color=GEOMETRY_STATUS_COLOR symbol=GEOMETRY_STATUS_SYMBOL
-  [[ $UID = 0 || $EUID = 0 ]] && symbol+=_ROOT
-  (( $GEOMETRY_LAST_STATUS )) && symbol+=_ERROR && color+=_ERROR
+      color=${colors[${index}]}
+    }
+  fi
 
-  ansi ${(P)color} ${(P)symbol}
+  ( $root && $error ) && ansi $color ${GEOMETRY_STATUS_SYMBOL_ROOT_ERROR:=▽} && return
+  ( $root ) && ansi $color ${GEOMETRY_STATUS_SYMBOL_ROOT:-▼} && return
+  ( $error ) && ansi $color ${GEOMETRY_STATUS_SYMBOL_ERROR:-△} && return
+  ansi $color ${GEOMETRY_STATUS_SYMBOL:-▲}
 }

geometry.zsh

@@ -53,10 +53,9 @@ add-zsh-hook precmd geometry::clear_title
 # join outputs of functions - pwd first
 geometry::wrap() {
     GEOMETRY_LAST_STATUS="$status"
-    local -a outputs
-    local cmd
-    local output
     setopt localoptions noautopushd; builtin cd -q $1
+    local -a outputs
+    local cmd output
     shift
     for cmd in $@; do output=$($cmd); (( $? )) || outputs+=$output; done
     echo "${(ps.${GEOMETRY_SEPARATOR}.)outputs}"
@@ -85,10 +84,9 @@ geometry::prompt() {
 add-zsh-hook precmd geometry::prompt
 
 geometry::info() { # draw info if no command is given
-    local info
     [[ -n "$BUFFER" ]] && { zle accept-line && return; }
-    info="$(geometry::wrap $PWD $GEOMETRY_INFO)"
-    echo "${(%)info}" && geometry::prompt
+    echo ${(%):-$(geometry::wrap $PWD $GEOMETRY_INFO)}
+    geometry::prompt
 }
 zle -N buffer-empty geometry::info
 bindkey '^M' buffer-empty