add phoenix endpoint and test

Author: mitchellhenke

lib/sentry/phoenix_endpoint.ex

@@ -0,0 +1,34 @@
+defmodule Sentry.Phoenix.Endpoint do
+  defmacro __using__(_opts) do
+    quote do
+      @before_compile Sentry.Phoenix.Endpoint
+    end
+  end
+
+  defmacro __before_compile__(_) do
+    quote do
+      defoverridable call: 2
+
+      def call(conn, opts) do
+        try do
+          super(conn, opts)
+        catch
+          kind, reason ->
+            stacktrace = System.stacktrace()
+            request = Sentry.Plug.build_request_interface_data(conn, [])
+            exception = Exception.normalize(kind, reason, stacktrace)
+
+            Sentry.capture_exception(
+              exception,
+              stacktrace: stacktrace,
+              request: request,
+              event_source: :endpoint,
+              error_type: kind
+            )
+
+            :erlang.raise(kind, reason, stacktrace)
+        end
+      end
+    end
+  end
+end

test/phoenix_endpoint_test.exs

@@ -0,0 +1,43 @@
+defmodule Sentry.PhoenixEndpointTest do
+  use ExUnit.Case
+  use Plug.Test
+  import Sentry.TestEnvironmentHelper
+
+  Application.put_env(
+    :sentry,
+    __MODULE__.Endpoint,
+    render_errors: [view: Sentry.ErrorView, accepts: ~w(html)]
+  )
+
+  defmodule Endpoint do
+    use Phoenix.Endpoint, otp_app: :sentry
+    use Sentry.Phoenix.Endpoint
+    plug(:error)
+    plug(Sentry.ExampleApp)
+
+    def error(_conn, _opts) do
+      raise "EndpointError"
+    end
+  end
+
+  test "reports errors occurring in Phoenix Endpoint" do
+    bypass = Bypass.open()
+
+    Bypass.expect(bypass, fn conn ->
+      {:ok, body, conn} = Plug.Conn.read_body(conn)
+      json = Poison.decode!(body)
+      assert json["culprit"] == "Sentry.PhoenixEndpointTest.Endpoint.error/2"
+      assert json["message"] == "(RuntimeError) EndpointError"
+      Plug.Conn.resp(conn, 200, ~s<{"id": "340"}>)
+    end)
+
+    modify_env(:sentry, dsn: "http://public:secret@localhost:#{bypass.port}/1")
+    modify_env(:phoenix, format_encoders: [])
+    {:ok, _} = Endpoint.start_link()
+
+    assert_raise RuntimeError, "EndpointError", fn ->
+      conn(:get, "/")
+      |> Endpoint.call([])
+    end
+  end
+end

test/support/test_error_view.exs

@@ -0,0 +1,5 @@
+defmodule Sentry.ErrorView do
+  def render(_, _) do
+    "error"
+  end
+end

test/test_helper.exs

@@ -4,6 +4,7 @@ Code.require_file("test/support/test_before_send_event.exs")
 Code.require_file("test/support/test_filter.exs")
 Code.require_file("test/support/test_gen_server.exs")
 Code.require_file("test/support/test_client.exs")
+Code.require_file("test/support/test_error_view.exs")
 
 ExUnit.start()
 Application.ensure_all_started(:bypass)