Differences between returning None and Some httpCtx from Giraffe middlewares

[64J0]

So, I came up with this example for the differences between returning None and Some httpCtx in a Giraffe middleware:

The project code (Program.fs):

open Microsoft.AspNetCore.Builder
open Microsoft.Extensions.DependencyInjection
open Microsoft.Extensions.Hosting

open Giraffe
open Giraffe.EndpointRouting

let mw1: HttpHandler =
    fun (next: HttpFunc) (ctx: Microsoft.AspNetCore.Http.HttpContext) ->
        task {
            printfn "[mw1] Status code before: %d" ctx.Response.StatusCode
            let! _ = next ctx
            printfn "[mw1] Status code after: %d" ctx.Response.StatusCode
            return Some ctx
        }

let mw2: HttpHandler =
    fun (next: HttpFunc) (ctx: Microsoft.AspNetCore.Http.HttpContext) ->
        task {
            printfn "[mw2] Status code before: %d" ctx.Response.StatusCode
            let! _ = next ctx
            printfn "[mw2] Status code after: %d" ctx.Response.StatusCode
            // Returning None here will cause this exception to be thrown:
            //
            //
            // fail: Microsoft.AspNetCore.Server.Kestrel[13]
            //     Connection id "0HNCUSVEAO7R6", Request id "0HNCUSVEAO7R6:00000001": An unhandled exception was thrown by the application.
            //     System.InvalidOperationException: StatusCode cannot be set because the response has already started.
            //         at Microsoft.AspNetCore.Server.Kestrel.Core.Internal.Http.HttpProtocol.ThrowResponseAlreadyStartedException(String value)
            //         at Microsoft.AspNetCore.Server.Kestrel.Core.Internal.Http.HttpProtocol.set_StatusCode(Int32 value)
            //         at Giraffe.EndpointRouting.RequestDelegateBuilder.createRequestDelegate@110-1.MoveNext()
            //         at Microsoft.AspNetCore.Routing.EndpointMiddleware.<Invoke>g__AwaitRequestTask|7_0(Endpoint endpoint, Task requestTask, ILogger logger)
            //         at Microsoft.AspNetCore.Server.Kestrel.Core.Internal.Http.HttpProtocol.ProcessRequests[TContext](IHttpApplication`1 application)
            //
            // The reason:
            // https://github.com/giraffe-fsharp/Giraffe/blob/master/src/Giraffe/EndpointRouting.fs#L101
            return None
        }

let index () : HttpHandler =
    fun (next: HttpFunc) (ctx: Microsoft.AspNetCore.Http.HttpContext) ->
        task {
            printfn "Status code inside: %d" ctx.Response.StatusCode
            return! (setStatusCode 201 >=> json {| Message = "Hello, World!" |}) next ctx
        }

let appRouter: Endpoint list =
    [ GET [ route "/health1" (mw1 >=> index ()); route "/health2" (mw2 >=> index ()) ] ]

[<EntryPoint>]
let main (args: string[]) =
    let builder = WebApplication.CreateBuilder(args)
    builder.Services.AddRouting().AddGiraffe() |> ignore

    let app = builder.Build()
    app.Urls.Add($"http://localhost:5000")
    app.UseRouting().UseEndpoints(_.MapGiraffeEndpoints(appRouter)) |> ignore

    app.Run()

    0

• Giraffe version used: 8.0.0-alpha-002
• Target framework: net9.0

To use it locally, after starting the server:

# Ok
curl localhost:5000/health1

# Exception
curl localhost:5000/health2

After starting this project locally, if you go through the "Return early" path (Some httpCtx), everything works fine. But, if you go through the "Skip" path (None), the server raises an exception (more details in the mw2 code).

More details about "Return early" and "Skip" here: link.