Updates related to `routeBind`

[64J0]

I think it sounds like a good idea to update the documentation to avoid confusion. I played around and arrived at a working example which I think should be added in some fashion and mentioned in the section for routeBind (since routeBind does not work with endpoint routing?)

Also I feel like the tryBindRoute function from the example below is missing from the library?

// Program.fs
open Microsoft.AspNetCore.Hosting
open Microsoft.AspNetCore.Builder
open Microsoft.Extensions.Hosting
open Microsoft.Extensions.DependencyInjection
open Giraffe
open Giraffe.EndpointRouting

open Microsoft.AspNetCore.Routing
open Microsoft.AspNetCore.Http
open Microsoft.Extensions.Primitives
open System.Collections.Generic

[<CLIMutable>]
type Person =
    {
        FirstName : string
        LastName  : string
    }

let tryBindRoute<'T> (ctx: HttpContext) : 'T option =
    let routeData = 
        ctx.GetRouteData().Values
        |> Seq.map (fun kvp -> KeyValuePair(kvp.Key, StringValues(kvp.Value :?> string)))
        |> fun kvps -> Dictionary<string, StringValues>(kvps) :> IDictionary<string, StringValues>
    match ModelParser.tryParse<'T> None routeData with
    | Ok model  -> Some model
    | Error _   -> None

let bindRouteHandler<'T> (handler: 'T -> HttpHandler) : HttpHandler =
    fun next ctx ->
        match tryBindRoute<'T> ctx with
        | Some model -> handler model next ctx
        | None       -> RequestErrors.BAD_REQUEST "Failed to bind route parameters" next ctx

let personHandler (person : Person) : HttpHandler =
    sprintf "Hello %s %s" person.FirstName person.LastName
    |> Successful.OK

let endpoints =
    [
        GET [
            route "/p/{firstName}/{lastName}" (bindRouteHandler<Person> personHandler)
        ]
    ]

let configureApp (appBuilder : IApplicationBuilder) =
    appBuilder
        .UseRouting()
        .UseEndpoints(fun e -> e.MapGiraffeEndpoints(endpoints))
    |> ignore

let configureServices (services : IServiceCollection) =
    // Add Giraffe dependencies
    services.AddGiraffe() |> ignore

[<EntryPoint>]
let main _ =
    Host.CreateDefaultBuilder()
        .ConfigureWebHostDefaults(
            fun webHostBuilder ->
                webHostBuilder
                    .Configure(configureApp)
                    .ConfigureServices(configureServices)
                    |> ignore)
        .Build()
        .Run()
    0

Originally posted by @acatuttle in #704

[AugustoRengel]

Hello @64J0 , I would like to work on this.
Should I implement routeBind for EndpointRouting, or should I update the documentation to make it explicit that it only works in the Routing module?

[64J0]

Should I implement routeBind for EndpointRouting, or should I update the documentation to make it explicit that it only works in the Routing module?

Hello @AugustoRengel, I prefer updating the documentation for this case, to make it explicit that this only works for the Giraffe router.

I'm still thinking about the tryBindRoute snippet. From a first look, it seems unnecessary, as the routeBind might already not match the endpoint if it doesn't fit the model. Therefore, having a try... variation seems not needed.

[AugustoRengel]

Hello @64J0 , thank you for the feedback.
While studying the codebase to better understand the library, I ended up implementing a version of routeBind for the Giraffe.EndpointRouting module and opened PR #709 in case this is considered a valid solution.

If you think this implementation is unnecessary or out of scope, please let me know and I will remove it and proceed with updating the documentation only.