ui-tests: verify that a sleep in Windows Terminal can be interrupted

The Ctrl+C way to interrupt run-away processes is highly important. It
was recently broken in multiple ways in the Cygwin runtime (and hence
also in the MSYS2 runtime).

Let's add some integration tests that will catch regressions.

It is admittedly less than ideal to add _integration_ tests; While
imitating exactly what the end user does looks appealing at first,
excellent tests impress by how quickly they allow regressions not only
to be identified but also to be fixed. Even worse: all integration
tests, by virtue of working in a broader environment than, say, unit
tests, incur the price of sometimes catching unactionable bugs, i.e.
bugs in software that is both outside of our control as well as not the
target of our testing at all.

Nevertheless, seeing as Cygwin did not add any unit tests for those
Ctrl+C fixes (which is understandable, given how complex testing for
Ctrl+C without UI testing would be), it is better to have integration
tests than no tests at all.

So here goes: This commit introduces a test that verifies that the MSYS2
`sleep.exe` can be interrupted when run from PowerShell in a Windows
Terminal. This was broken in v3.6.0 and fixed in 7674c51 (Cygwin:
console: Set ENABLE_PROCESSED_INPUT when disable_master_thread,
2025-07-01).

Signed-off-by: Johannes Schindelin <[email protected]>

Author: dscho

.github/workflows/ui-tests.yml

@@ -90,11 +90,16 @@ jobs:
           & "${env:RUNNER_TEMP}\ahk\AutoHotKey64.exe" /ErrorStdOut /force background-hook.ahk "$PWD\bg-hook" 2>&1 | Out-Default
           if (!$?) { $exitCode = 1; echo "::error::Test failed!" } else { echo "::notice::Test log" }
           type bg-hook.log
+          & "${env:RUNNER_TEMP}\ahk\AutoHotKey64.exe" /ErrorStdOut /force ctrl-c.ahk "$PWD\ctrl-c" 2>&1 | Out-Default
+          if (!$?) { $exitCode = 1; echo "::error::Ctrl+C Test failed!" } else { echo "::notice::Ctrl+C Test log" }
+          type ctrl-c.log
           exit $exitCode
       - name: Show logs
         if: always()
         working-directory: ui-tests
-        run: type bg-hook.log
+        run: |
+          type bg-hook.log
+          type ctrl-c.log
       - name: Take screenshot, if canceled
         id: take-screenshot
         if: cancelled() || failure()

ui-tests/ctrl-c.ahk

@@ -0,0 +1,46 @@
+#Requires AutoHotkey v2.0
+#Include ui-test-library.ahk
+
+SetWorkTree('git-test-ctrl-c')
+
+powerShellPath := EnvGet('SystemRoot') . '\System32\WindowsPowerShell\v1.0\powershell.exe'
+Run 'wt.exe -d . "' powerShellPath '"', , , &childPid
+if A_LastError
+    ExitWithError 'Error launching PowerShell: ' A_LastError
+Info 'Launched PowerShell: ' childPid
+; Sadly, `WinWait('ahk_pid ' childPid)` does not work because the Windows Terminal window seems
+; to be owned by the `wt.exe` process that launched.
+;
+; Probably should use the trick mentioned in
+; https://www.autohotkey.com/boards/viewtopic.php?p=580081&sid=a40d0ce73efff728ffa6b4573dff07b9#p580081
+; where the `before` variable is assigned `WinGetList(winTitle).Length` before the `Run` command,
+; and a `Loop` is used to wait until [`WinGetList()`](https://www.autohotkey.com/docs/v2/lib/WinGetList.htm)
+; returns a different length, in which case the first array element is the new window.
+;
+; Also: This is crying out loud to be refactored into a function and then also used in `background-hook.ahk`!
+hwnd := WinWait(powerShellPath, , 9)
+if not hwnd
+    ExitWithError 'PowerShell window did not appear'
+Info 'Got window'
+WinActivate
+CloseWindow := true
+WinMove 0, 0
+Info 'Moved window to top left (so that the bottom is not cut off)'
+
+; sleep test
+Sleep 1500
+; The `:;` is needed to force Git to call this via the shell, otherwise `/usr/bin/` would not resolve.
+Send('git -c alias.sleep="{!}:;/usr/bin/sleep" sleep 15{Enter}')
+Sleep 500
+; interrupt sleep; Ideally we'd call `Send('^C')` but that would too quick on GitHub Actions' runners.
+; The idea for this work-around comes from https://www.reddit.com/r/AutoHotkey/comments/aok10s/comment/eg57e81/.
+Send '{Ctrl down}{c down}'
+Sleep 50
+Send '{c up}{Ctrl up}'
+Sleep 150
+; Wait for the `^C` tell-tale that is the PowerShell prompt to appear
+WaitForRegExInWindowsTerminal('>[ `n`r]*$', 'Timed out waiting for interrupt', 'Sleep was interrupted as desired')
+
+Send('exit{Enter}')
+Sleep 50
+CleanUpWorkTree()