|
| 1 | +/* |
| 2 | + Copyright (c) 2014-2015 Arduino LLC. All right reserved. |
| 3 | + |
| 4 | + This library is free software; you can redistribute it and/or |
| 5 | + modify it under the terms of the GNU Lesser General Public |
| 6 | + License as published by the Free Software Foundation; either |
| 7 | + version 2.1 of the License, or (at your option) any later version. |
| 8 | + |
| 9 | + This library is distributed in the hope that it will be useful, |
| 10 | + but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 11 | + MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. |
| 12 | + See the GNU Lesser General Public License for more details. |
| 13 | + |
| 14 | + You should have received a copy of the GNU Lesser General Public |
| 15 | + License along with this library; if not, write to the Free Software |
| 16 | + Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA |
| 17 | +*/ |
| 18 | + |
| 19 | +/* Linker script to configure memory regions. |
| 20 | + * Need modifying for a specific board. |
| 21 | + * FLASH.ORIGIN: starting address of flash |
| 22 | + * FLASH.LENGTH: length of flash |
| 23 | + * RAM.ORIGIN: starting address of RAM bank 0 |
| 24 | + * RAM.LENGTH: length of RAM bank 0 |
| 25 | + */ |
| 26 | +MEMORY |
| 27 | +{ |
| 28 | + FLASH (rx) : ORIGIN = 0x00000000+0x2000, LENGTH = 0x00040000-0x2000 /* First 8KB used by bootloader */ |
| 29 | + RAM (rwx) : ORIGIN = 0x20000000, LENGTH = 0x00008000 |
| 30 | +} |
| 31 | + |
| 32 | +/* Linker script to place sections and symbol values. Should be used together |
| 33 | + * with other linker script that defines memory regions FLASH and RAM. |
| 34 | + * It references following symbols, which must be defined in code: |
| 35 | + * Reset_Handler : Entry of reset handler |
| 36 | + * |
| 37 | + * It defines following symbols, which code can use without definition: |
| 38 | + * __exidx_start |
| 39 | + * __exidx_end |
| 40 | + * __copy_table_start__ |
| 41 | + * __copy_table_end__ |
| 42 | + * __zero_table_start__ |
| 43 | + * __zero_table_end__ |
| 44 | + * __etext |
| 45 | + * __data_start__ |
| 46 | + * __preinit_array_start |
| 47 | + * __preinit_array_end |
| 48 | + * __init_array_start |
| 49 | + * __init_array_end |
| 50 | + * __fini_array_start |
| 51 | + * __fini_array_end |
| 52 | + * __data_end__ |
| 53 | + * __bss_start__ |
| 54 | + * __bss_end__ |
| 55 | + * __end__ |
| 56 | + * end |
| 57 | + * __HeapLimit |
| 58 | + * __StackLimit |
| 59 | + * __StackTop |
| 60 | + * __stack |
| 61 | + */ |
| 62 | +ENTRY(Reset_Handler) |
| 63 | + |
| 64 | +SECTIONS |
| 65 | +{ |
| 66 | + .text : |
| 67 | + { |
| 68 | + __text_start__ = .; |
| 69 | + |
| 70 | + KEEP(*(.isr_vector)) |
| 71 | + *(.text*) |
| 72 | + |
| 73 | + KEEP(*(.init)) |
| 74 | + KEEP(*(.fini)) |
| 75 | + |
| 76 | + /* .ctors */ |
| 77 | + *crtbegin.o(.ctors) |
| 78 | + *crtbegin?.o(.ctors) |
| 79 | + *(EXCLUDE_FILE(*crtend?.o *crtend.o) .ctors) |
| 80 | + *(SORT(.ctors.*)) |
| 81 | + *(.ctors) |
| 82 | + |
| 83 | + /* .dtors */ |
| 84 | + *crtbegin.o(.dtors) |
| 85 | + *crtbegin?.o(.dtors) |
| 86 | + *(EXCLUDE_FILE(*crtend?.o *crtend.o) .dtors) |
| 87 | + *(SORT(.dtors.*)) |
| 88 | + *(.dtors) |
| 89 | + |
| 90 | + *(.rodata*) |
| 91 | + |
| 92 | + KEEP(*(.eh_frame*)) |
| 93 | + } > FLASH |
| 94 | + |
| 95 | + .ARM.extab : |
| 96 | + { |
| 97 | + *(.ARM.extab* .gnu.linkonce.armextab.*) |
| 98 | + } > FLASH |
| 99 | + |
| 100 | + __exidx_start = .; |
| 101 | + .ARM.exidx : |
| 102 | + { |
| 103 | + *(.ARM.exidx* .gnu.linkonce.armexidx.*) |
| 104 | + } > FLASH |
| 105 | + __exidx_end = .; |
| 106 | + |
| 107 | + /* To copy multiple ROM to RAM sections, |
| 108 | + * uncomment .copy.table section and, |
| 109 | + * define __STARTUP_COPY_MULTIPLE in startup_ARMCMx.S */ |
| 110 | + /* |
| 111 | + .copy.table : |
| 112 | + { |
| 113 | + . = ALIGN(4); |
| 114 | + __copy_table_start__ = .; |
| 115 | + LONG (__etext) |
| 116 | + LONG (__data_start__) |
| 117 | + LONG (__data_end__ - __data_start__) |
| 118 | + LONG (__etext2) |
| 119 | + LONG (__data2_start__) |
| 120 | + LONG (__data2_end__ - __data2_start__) |
| 121 | + __copy_table_end__ = .; |
| 122 | + } > FLASH |
| 123 | + */ |
| 124 | + |
| 125 | + /* To clear multiple BSS sections, |
| 126 | + * uncomment .zero.table section and, |
| 127 | + * define __STARTUP_CLEAR_BSS_MULTIPLE in startup_ARMCMx.S */ |
| 128 | + /* |
| 129 | + .zero.table : |
| 130 | + { |
| 131 | + . = ALIGN(4); |
| 132 | + __zero_table_start__ = .; |
| 133 | + LONG (__bss_start__) |
| 134 | + LONG (__bss_end__ - __bss_start__) |
| 135 | + LONG (__bss2_start__) |
| 136 | + LONG (__bss2_end__ - __bss2_start__) |
| 137 | + __zero_table_end__ = .; |
| 138 | + } > FLASH |
| 139 | + */ |
| 140 | + |
| 141 | + __etext = .; |
| 142 | + |
| 143 | + .data : AT (__etext) |
| 144 | + { |
| 145 | + __data_start__ = .; |
| 146 | + *(vtable) |
| 147 | + *(.data*) |
| 148 | + |
| 149 | + . = ALIGN(4); |
| 150 | + /* preinit data */ |
| 151 | + PROVIDE_HIDDEN (__preinit_array_start = .); |
| 152 | + KEEP(*(.preinit_array)) |
| 153 | + PROVIDE_HIDDEN (__preinit_array_end = .); |
| 154 | + |
| 155 | + . = ALIGN(4); |
| 156 | + /* init data */ |
| 157 | + PROVIDE_HIDDEN (__init_array_start = .); |
| 158 | + KEEP(*(SORT(.init_array.*))) |
| 159 | + KEEP(*(.init_array)) |
| 160 | + PROVIDE_HIDDEN (__init_array_end = .); |
| 161 | + |
| 162 | + |
| 163 | + . = ALIGN(4); |
| 164 | + /* finit data */ |
| 165 | + PROVIDE_HIDDEN (__fini_array_start = .); |
| 166 | + KEEP(*(SORT(.fini_array.*))) |
| 167 | + KEEP(*(.fini_array)) |
| 168 | + PROVIDE_HIDDEN (__fini_array_end = .); |
| 169 | + |
| 170 | + KEEP(*(.jcr*)) |
| 171 | + . = ALIGN(16); |
| 172 | + /* All data end */ |
| 173 | + __data_end__ = .; |
| 174 | + |
| 175 | + } > RAM |
| 176 | + |
| 177 | + .bss : |
| 178 | + { |
| 179 | + . = ALIGN(4); |
| 180 | + __bss_start__ = .; |
| 181 | + *(.bss*) |
| 182 | + *(COMMON) |
| 183 | + . = ALIGN(4); |
| 184 | + __bss_end__ = .; |
| 185 | + } > RAM |
| 186 | + |
| 187 | + .heap (COPY): |
| 188 | + { |
| 189 | + __end__ = .; |
| 190 | + PROVIDE(end = .); |
| 191 | + *(.heap*) |
| 192 | + __HeapLimit = .; |
| 193 | + } > RAM |
| 194 | + |
| 195 | + /* .stack_dummy section doesn't contains any symbols. It is only |
| 196 | + * used for linker to calculate size of stack sections, and assign |
| 197 | + * values to stack symbols later */ |
| 198 | + .stack_dummy (COPY): |
| 199 | + { |
| 200 | + *(.stack*) |
| 201 | + } > RAM |
| 202 | + |
| 203 | + /* Set stack top to end of RAM, and stack limit move down by |
| 204 | + * size of stack_dummy section */ |
| 205 | + __StackTop = ORIGIN(RAM) + LENGTH(RAM); |
| 206 | + __StackLimit = __StackTop - SIZEOF(.stack_dummy); |
| 207 | + PROVIDE(__stack = __StackTop); |
| 208 | + |
| 209 | + __ram_end__ = ORIGIN(RAM) + LENGTH(RAM) -1 ; |
| 210 | + |
| 211 | + /* Check if data + heap + stack exceeds RAM limit */ |
| 212 | + ASSERT(__StackLimit >= __HeapLimit, "region RAM overflowed with stack") |
| 213 | +} |
0 commit comments