get_global_transform_interpolated for 2D?

[elvisish]

Is it possible to get the interpolated transform in 2D or is it exclusively for 3D spatials? I'm using physics interpolation in 2D and am trying to smooth out the camera.

[filantus]

In general there is a global method lerp (linear interpolate) which allow to interpolate anything (between two values by the factor defined in weight).
https://docs.godotengine.org/en/latest/classes/[email protected]#class-globalscope-method-lerp

But Transform2D (and Transform3D too) also have a special method for interpolating - interpolate_with. Which allows to interpolate not between two int or float values but between two transforms.
https://docs.godotengine.org/en/latest/classes/class_transform2d.html#class-transform2d-method-interpolate-with

Example from documentation:

var t = 0.0

func _physics_process(delta):
    t += delta

    $Monkey.transform = $Position1.transform.interpolate_with($Position2.transform, t)

Also vectors (Vector2, Vector3) have a lerp method too. Which allows to interpolate between objects positions. Because e.g. $Sprite2D.position it is a just Vector2.
https://docs.godotengine.org/en/latest/classes/class_vector2.html#class-vector2-method-lerp

Example from documentation:

const FOLLOW_SPEED = 4.0

func _physics_process(delta):
    var mouse_pos = get_local_mouse_position()

    $Sprite2D.position = $Sprite2D.position.lerp(mouse_pos, delta * FOLLOW_SPEED)

Notice that in these examples the delta parameter is involved. That is because method lerp do not account a frame rate by itself. So adding delta need to uniformly interpolate, independently of CPU speed and FPS. See: https://docs.godotengine.org/en/latest/tutorials/math/interpolation.html

[elvisish]

Thanks, I’m referring to physics interpolation which I didn’t realize wasn’t actually implemented for 2D yet. It seems it’ll be roadtested a bit more, then ported to 4.0 and possibly to 2D.

[filantus]

Ou, i got it. Indeed get_global_transform_interpolated it's a different method. Didn't see it before. And, as you said, it's seems available only in Spatial in Godot 3 for now.

[follyfoxe]

For any unlucky souls who have gone down this very same rabbit hole, I've figured out a workaround:
Place this script on a Node2D (ideally as a child of the node you're trying to get the interpolated transform of, specially if you ever call reset_physics_interpolation on your target node)
The script will then calculate the interpolated transform on it's own. To use it, call get_global_transform_interpolated() on the node with the script, or you can also just use the regular transform method and properties (e.g to_local, to_global)

extends Node2D
class_name Interpolator

@export var target : Node2D
var _last : Transform2D = Transform2D.IDENTITY
var _current : Transform2D = Transform2D.IDENTITY

func get_global_transform_interpolated() -> Transform2D:
	return _last.interpolate_with(_current, Engine.get_physics_interpolation_fraction())

func _enter_tree() -> void:
	if !is_instance_valid(target):
		target = get_parent()
	_current = target.global_transform
	_last = _current
	top_level = true
	physics_interpolation_mode = Node.PHYSICS_INTERPOLATION_MODE_OFF
	global_transform = _current
	
func _physics_process(_delta: float) -> void:
	_last = _current
	_current = target.global_transform

func _process(_delta: float) -> void:
	global_transform = get_global_transform_interpolated()
	
func _notification(what: int) -> void:
	if what == NOTIFICATION_RESET_PHYSICS_INTERPOLATION:
		if is_instance_valid(target):
			_current = target.global_transform
			_last = _current