Context menu item "Create AudioStreamRandomizer" when one or more audio files are selected and rightclicked in FileSystem

[Wiggan]

Hi!

When working with sound designers I often find myself in the situation of having a bunch of sounds with 8 takes per sound.
Manually adding a AudioStreamRandomizer, adding 8 streams, drag/dropping the files into the streams is pretty cumbersome. What would have been great is a context menu item that appears when rightclicking audio files.

Is the randomizer underused, because I find 0 issues about it? I think it's awesome!

As a workaround I made an ugly plugin:

@tool
extends EditorPlugin

const COMMAND_NAME = "Generate Randomizer"
var dialog

func _enter_tree():
	add_tool_menu_item(COMMAND_NAME, show_dialog)
	dialog = FileDialog.new()
	dialog.set_filters(PackedStringArray(["*.wav"]))
	dialog.set_file_mode(FileDialog.FILE_MODE_OPEN_FILES)
	dialog.connect("files_selected", files_selected)

func _input(event):
	if Input.is_key_pressed(KEY_R) and Input.is_key_pressed(KEY_CTRL) and Input.is_key_pressed(KEY_SHIFT) and Input.is_key_pressed(KEY_ALT):
		show_dialog()

func show_dialog():
	add_child(dialog)
	dialog.popup_centered(Vector2(300, 400))

func files_selected(paths):
	var randomizer = FileAccess.open(paths[0].get_basename()+".tres", FileAccess.WRITE)
	randomizer.store_line('[gd_resource type="AudioStreamRandomizer"]')

	for path in paths:
		randomizer.store_line('[ext_resource type="AudioStream" path="' + path + '" id="' + path.sha1_text() +'"]')
	
	randomizer.store_line('[resource]')
	randomizer.store_line('streams_count = ' + str(len(paths)))
	for i in range(len(paths)):
		randomizer.store_line('stream_' + str(i) + '/stream = ExtResource("' + paths[i].sha1_text() + '")')	
		randomizer.store_line('stream_' + str(i) + '/weight = 1.0')
	
	randomizer.close()
	get_editor_interface().get_resource_filesystem().scan()
	print("Done!")
	
func _exit_tree():
	remove_tool_menu_item(COMMAND_NAME)
	if dialog:
		dialog.queue_free()

[Calinou]

I'm not sure if we should start adding "bespoke" actions for specific resource types in the FileSystem dock. Discoverability will likely suffer. We already have this problem in the inspector resource dropdowns for things like BaseMaterial3D and MeshInstance3D, both of which offer special options in the resource dropdown (for BaseMaterial3D) and inspector toolbox (for both).

I think it might be better to have a system that lets you automatically load multiple sounds in a AudioStreamRandomizer based on a naming convention. When naming random sound variations, it's pretty common to use incremental numbers as follows:

• footstep_dirt.1.ogg
• footstep_dirt.2.ogg
• footstep_dirt.3.ogg
• footstep_dirt.4.ogg

We could detect this automatically when loading an AudioStream in the inspector, either via drag-and-drop or using the usual Quick Load or Load options.

[Wiggan]

I guess "simply" allowing drag and drop to the streams slot of an AudioStreamRandomizer inspector would do the trick. Not sure how simple that is to implement though.