Add memcpy override library for ARM + GPU use cases

b/277618912 show what appeared to be glibc's memcpy using unaligned
accesses during command buffer recording which caused SIGBUSs on
some Nvidia GPUs. This little stub library provides a memcpy override
that can be be used via LD_PRELOAD.

Bug: b/277618912
Bug: b/453027517
Test: (On ARM workstation)
      tools/buildutils/build_packages.sh
      sudo apt install ./cuttlefish-base_*.deb ./cuttlefish-user_*.deb
      sudo reboot
      cvd create --gpu_mode=gfxstream_guest_angle
      <play around with device for 5 minutes>

Author: jmacnak

base/cvd/BUILD.arm_optimized_routines.bazel

@@ -0,0 +1,51 @@
+package(
+    default_visibility = [
+        "@//:android_cuttlefish",
+    ],
+)
+
+# Some of the `.h` and `.S` files are treated like `.inl` files.
+cc_library(
+    name = "string_internal_textual_headers",
+    includes = select({
+        "@platforms//cpu:arm": ["string/arm"],
+        "@platforms//cpu:aarch64": ["string/aarch64"],
+        "@platforms//cpu:x86_64": ["string/x86_64"],
+        "//conditions:default": [],
+    }),
+    textual_hdrs = select({
+        "@platforms//cpu:arm": glob([
+            "string/arm/*.h",
+            "string/arm/*.S",
+        ]),
+        "@platforms//cpu:aarch64": glob([
+            "string/aarch64/*.h",
+            "string/aarch64/*.S",
+        ]),
+        "@platforms//cpu:x86_64": glob([
+            "string/x86_64/*.S",
+        ]),
+        "//conditions:default": [],
+    }),
+    visibility = ["//visibility:private"],
+)
+
+cc_library(
+    name = "string",
+    srcs = select({
+        "@platforms//cpu:arm": glob([
+            "string/arm/*.c",
+            "string/arm/*.S",
+        ]),
+        "@platforms//cpu:aarch64": glob([
+            "string/aarch64/*.S",
+        ]),
+        "@platforms//cpu:x86_64": glob([
+            "string/x86_64/*.S",
+        ]),
+        "//conditions:default": [],
+    }),
+    hdrs = glob(["string/include/*.h"]),
+    deps = [":string_internal_textual_headers"],
+    includes = ["string/include"],
+)

base/cvd/MODULE.bazel

@@ -769,3 +769,11 @@ git_repository(
     commit = "f785e9275ee5ed85f98e7b850783ca0559ee1799",
     remote = "https://github.com/google/casimir",
 )
+
+git_repository(
+    name = "arm_optimized_routines",
+    build_file = "@//:BUILD.arm_optimized_routines.bazel",
+    commit = "3bc8091d03e002e25332fcbbd9a754538cb1109e",
+    remote = "https://github.com/ARM-software/optimized-routines.git",
+)
+

base/cvd/cuttlefish/host/graphics/mem_overrides/BUILD

@@ -0,0 +1,30 @@
+load("//cuttlefish/bazel:rules.bzl", "cf_cc_binary")
+
+package(
+    default_visibility = ["//:android_cuttlefish"],
+)
+
+cf_cc_binary(
+    name = "libmem_overrides.so",
+    srcs = select({
+        "@platforms//cpu:arm64": [
+            "mem_overrides.cpp",
+        ],
+        "//conditions:default": [
+            "mem_overrides_noop.cpp",
+        ],
+    }),
+    copts = [
+        "-fPIC",
+    ],
+    linkopts = [
+        "-Wl,-no-undefined",
+    ],
+    linkshared = 1,
+    deps = select({
+        "@platforms//cpu:arm64": [
+            "@arm_optimized_routines//:string",
+        ],
+        "//conditions:default": [],
+    }),
+)

base/cvd/cuttlefish/host/graphics/mem_overrides/mem_overrides.cpp

@@ -0,0 +1,14 @@
+extern "C" {
+#include "string/include/stringlib.h"
+}
+
+// b/277618912: glibc's aarch64 memcpy uses unaligned accesses which seems to
+// cause SIGBUS errors on some Nvidia GPUs. Override memcpy here:
+
+void* memcpy(void* dest, const void* src, size_t n) {
+	return __memcpy_aarch64(dest, src, n);
+}
+
+void* memmove(void* dest, const void* src, size_t n) {
+	return __memmove_aarch64(dest, src, n);
+}

base/cvd/cuttlefish/host/graphics/mem_overrides/mem_overrides_noop.cpp

@@ -0,0 +1,3 @@
+// Empty library to avoid some conditional `select()`s in `BUILD` files which
+// have trouble being modified by buildozer during automated imports:
+// https://github.com/bazelbuild/buildtools/issues/1421.

base/cvd/cuttlefish/package/BUILD.bazel

@@ -8,6 +8,7 @@ package_files(
         "cuttlefish-common/bin/mmd": "cuttlefish-common/bin/mtools",
         "cuttlefish-common/bin/resize.f2fs": "cuttlefish-common/bin/fsck.f2fs",
         "cuttlefish-common/bin/aarch64-linux-gnu/gfxstream_graphics_detector": "cuttlefish-common/bin/graphics_detector",
+        "cuttlefish-common/bin/aarch64-linux-gnu/libmem_overrides.so": "cuttlefish-common/bin/libmem_overrides.so",
         "cuttlefish-common/bin/aarch64-linux-gnu/libvk_swiftshader.so": "cuttlefish-common/bin/libvk_swiftshader.so",
         "cuttlefish-common/bin/x86_64-linux-gnu/gfxstream_graphics_detector": "cuttlefish-common/bin/graphics_detector",
         "cuttlefish-common/lib64/vulkan.lvp.so": "cuttlefish-common/bin/libvk_lavapipe.so",
@@ -52,6 +53,7 @@ package_files(
         "cuttlefish-common/bin/graphics_detector": "//cuttlefish/host/graphics_detector",
         "cuttlefish-common/bin/health": "//cuttlefish/host/commands/health",
         "cuttlefish-common/bin/kernel_log_monitor": "//cuttlefish/host/commands/kernel_log_monitor",
+        "cuttlefish-common/bin/libmem_overrides.so": "//cuttlefish/host/graphics/mem_overrides:libmem_overrides.so",
         "cuttlefish-common/bin/libgfxstream_backend.so": "@gfxstream//host:gfxstream_backend",
         "cuttlefish-common/bin/libvk_lavapipe.so": "@mesa//:vk_lavapipe",
         "cuttlefish-common/bin/libvk_swiftshader.so": "@swiftshader//:vk_swiftshader",