Add SchemaExportCommand

Closes gh-71

See graceframework/grace-data-hibernate#123

Author: rainboyan

build.gradle

@@ -63,7 +63,7 @@ dependencies {
     compileOnly "org.graceframework:grace-cli"
     compileOnly 'jakarta.servlet:jakarta.servlet-api'
     implementation "org.graceframework:grace-datastore-gorm"
-    compileOnly "org.graceframework.plugins:hibernate"
+    implementation "org.graceframework.plugins:hibernate"
 
     testImplementation "org.graceframework:grace-shell"
     testImplementation "org.graceframework.plugins:hibernate"

src/main/groovy/org/grails/plugins/databasemigration/command/SchemaExportCommand.groovy

@@ -0,0 +1,102 @@
+/*
+ * Copyright 2015-2025 the original author or authors.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *      https://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+package org.grails.plugins.databasemigration.command
+
+import groovy.transform.CompileStatic
+import org.hibernate.engine.spi.SessionFactoryImplementor
+import org.hibernate.tool.hbm2ddl.SchemaExport as HibernateSchemaExport
+import org.hibernate.tool.schema.TargetType
+
+import grails.dev.commands.ApplicationCommand
+import grails.dev.commands.ExecutionContext
+import grails.util.Environment
+
+import org.grails.build.parsing.CommandLine
+import org.grails.datastore.mapping.core.connections.ConnectionSource
+import org.grails.orm.hibernate.HibernateDatastore
+
+/**
+ * Adds a schema-export command
+ *
+ * @author Graeme Rocher
+ * @author Michael Yan
+ * @since 4.0
+ */
+@CompileStatic
+class SchemaExportCommand implements ApplicationCommand {
+
+    final String description = "Creates a DDL file of the database schema"
+    Boolean skipBootstrap = true
+
+    @Override
+    boolean handle(ExecutionContext executionContext) {
+        CommandLine commandLine = executionContext.commandLine
+
+        String filename = "${executionContext.baseDir.canonicalPath}/db/schema.sql"
+        boolean export = false
+        boolean stdout = false
+
+        for (arg in commandLine.remainingArgs) {
+            switch (arg) {
+                case 'export': export = true; break
+                case 'generate': export = false; break
+                case 'stdout': stdout = true; break
+                default: filename = arg
+            }
+        }
+
+        def argsMap = commandLine.undeclaredOptions
+        String dataSourceName = argsMap.datasource ? argsMap.datasource : ConnectionSource.DEFAULT
+
+        def file = new File(filename)
+        file.parentFile.mkdirs()
+
+        HibernateDatastore hibernateDatastore = applicationContext.getBean("hibernateDatastore", HibernateDatastore)
+        hibernateDatastore = hibernateDatastore.getDatastoreForConnection(dataSourceName)
+
+        def serviceRegistry = ((SessionFactoryImplementor) hibernateDatastore.sessionFactory).getServiceRegistry()
+                .getParentServiceRegistry()
+        def metadata = hibernateDatastore.metadata
+
+        def schemaExport = new HibernateSchemaExport()
+                .setHaltOnError(true)
+                .setOutputFile(file.path)
+                .setDelimiter(';')
+
+
+        String action = export ? "Exporting" : "Generating script to ${file.absolutePath}"
+        String ds = argsMap.datasource ? "for DataSource '$argsMap.datasource'" : "for the default DataSource"
+        println "$action in environment '${Environment.current.name}' $ds"
+
+        EnumSet<TargetType> targetTypes
+        if (stdout) {
+            targetTypes = EnumSet.of(TargetType.SCRIPT, TargetType.STDOUT)
+        }
+        else {
+            targetTypes = EnumSet.of(TargetType.SCRIPT)
+        }
+
+        schemaExport.execute(targetTypes, HibernateSchemaExport.Action.CREATE, metadata, serviceRegistry)
+
+        if (schemaExport.exceptions) {
+            def e = (Exception) schemaExport.exceptions[0]
+            e.printStackTrace()
+            return false
+        }
+        return true
+    }
+
+}