QZXingBinaries/QZXing.pri at master · graft-project/QZXingBinaries · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
QT += multimedia

DEFINES += QZXING_QML QZXING_MULTIMEDIA DISABLE_LIBRARY_FEATURES

INCLUDEPATH  += $$PWD/include

windows {
    win32-msvc* {
        contains(QMAKE_TARGET.arch, x86) {
            PLATFORM_PATH = msvc2015_x86
        } else {
            PLATFORM_PATH = msvc2017_x64
        }
    }

    win32-g++ {
        PLATFORM_PATH = mingw_x86
    }
}

ios {
    PLATFORM_PATH = ios
} else {
    mac {
        PLATFORM_PATH = mac
    }
}

android {
    equals(ANDROID_TARGET_ARCH, armeabi-v7a) {
        PLATFORM_PATH = android/armeabi-v7a
    }

    equals(ANDROID_TARGET_ARCH, arm64-v8a) {
        PLATFORM_PATH = android/arm64-v8a
    }

    equals(ANDROID_TARGET_ARCH, x86) {
        PLATFORM_PATH = android/x86
    }
} else {
    linux {
        PLATFORM_PATH = linux
    }
}

LIBS_PATH = $$PWD/libs/$$PLATFORM_PATH
CONFIG(release, debug|release) {
    LIBS += -L$$LIBS_PATH/release -lQZXing
}
CONFIG(debug, debug|release) {
    LIBS += -L$$LIBS_PATH/debug -lQZXing
}