using @ConfigurationProperties for configuration access

Author: davidkron

grails-app/services/grails/plugins/mail/MailService.groovy

@@ -16,38 +16,47 @@
 package grails.plugins.mail
 
 import grails.config.Config
-import grails.core.support.GrailsConfigurationAware
 import groovy.transform.CompileStatic
 import groovy.util.logging.Slf4j
 import org.springframework.beans.factory.DisposableBean
 import org.springframework.beans.factory.InitializingBean
+import org.springframework.boot.context.properties.ConfigurationProperties
+import org.springframework.boot.context.properties.bind.Bindable
+import org.springframework.boot.context.properties.bind.Binder
+import org.springframework.boot.context.properties.source.ConfigurationPropertySource
+import org.springframework.boot.context.properties.source.ConfigurationPropertySources
+import org.springframework.core.env.PropertiesPropertySource
+import org.springframework.core.env.PropertySource
 import org.springframework.mail.MailMessage
 
 import java.util.concurrent.LinkedBlockingQueue
 import java.util.concurrent.ThreadPoolExecutor
 import java.util.concurrent.TimeUnit
+
 /**
  * Provides the entry point to the mail sending API.
  */
 @Slf4j
 @CompileStatic
-class MailService implements InitializingBean, DisposableBean, GrailsConfigurationAware {
+class MailService implements InitializingBean, DisposableBean {
 
     static transactional = false
 
-    MailConfig configuration
+	MailConfigurationProperties mailConfigurationProperties
     MailMessageBuilderFactory mailMessageBuilderFactory
 	ThreadPoolExecutor mailExecutorService
 
 	private static final Integer DEFAULT_POOL_SIZE = 5
 
-    MailMessage sendMail(MailConfig config, @DelegatesTo(strategy = Closure.DELEGATE_FIRST, value = MailMessageBuilder) Closure callable) {
+	private static final Bindable<MailConfigurationProperties> CONFIG_BINDABLE = Bindable.of(MailConfigurationProperties)
+
+    MailMessage sendMail(MailConfigurationProperties properties, @DelegatesTo(strategy = Closure.DELEGATE_FIRST, value = MailMessageBuilder) Closure callable) {
         if (isDisabled()) {
             log.warn("Sending emails disabled by configuration option")
             return
         }
 
-        MailMessageBuilder messageBuilder = mailMessageBuilderFactory.createBuilder(config)
+        MailMessageBuilder messageBuilder = mailMessageBuilderFactory.createBuilder(properties)
         callable.delegate = messageBuilder
         callable.resolveStrategy = Closure.DELEGATE_FIRST
         callable.call(messageBuilder)
@@ -56,28 +65,29 @@ class MailService implements InitializingBean, DisposableBean, GrailsConfigurati
     }
 
 	MailMessage sendMail(Config config, @DelegatesTo(strategy = Closure.DELEGATE_FIRST, value = MailMessageBuilder) Closure callable) {
-		return sendMail(new MailConfig(config), callable)
+		return sendMail(toMailProperties(config), callable)
 	}
 
     MailMessage sendMail(@DelegatesTo(strategy = Closure.DELEGATE_FIRST, value = MailMessageBuilder) Closure callable) {
-        return sendMail(configuration, callable)
+        return sendMail(mailConfigurationProperties, callable)
     }
 
+	private static MailConfigurationProperties toMailProperties(Config config) {
+		PropertySource propertySource = new PropertiesPropertySource('mailProperties', config.toProperties())
+		Iterable<ConfigurationPropertySource> configurationPropertySources = ConfigurationPropertySources.from(propertySource)
+		Binder binder = new Binder(configurationPropertySources)
+		return binder.bind(MailConfigurationProperties.PREFIX, CONFIG_BINDABLE).get()
+	}
 
     boolean isDisabled() {
-        configuration.disabled
+        mailConfigurationProperties.disabled
     }
 
 	void setPoolSize(Integer poolSize){
 		mailExecutorService.setMaximumPoolSize(poolSize ?: DEFAULT_POOL_SIZE)
 		mailExecutorService.setCorePoolSize(poolSize ?: DEFAULT_POOL_SIZE)
 	}
 
-	@Override
-	void setConfiguration(Config config) {
-		configuration = new MailConfig(config)
-	}
-
 	@Override
 	public void destroy() throws Exception {
 		mailExecutorService.shutdown()
@@ -88,7 +98,7 @@ class MailService implements InitializingBean, DisposableBean, GrailsConfigurati
 	public void afterPropertiesSet() throws Exception {
 		mailExecutorService = new ThreadPoolExecutor(1, 1, 60, TimeUnit.SECONDS, new LinkedBlockingQueue<Runnable>())
 
-		Integer poolSize = configuration.poolSize
+		Integer poolSize = mailConfigurationProperties.poolSize
 		try{
 			((ThreadPoolExecutor)mailExecutorService).allowCoreThreadTimeOut(true)
 		}catch(MissingMethodException e){

src/integration-test/groovy/grails/plugins/mail/MailServiceSpec.groovy

@@ -69,7 +69,7 @@ class MailServiceSpec extends Specification  {
         )
         mimeCapableMailService = new MailService(
             mailMessageBuilderFactory: mimeMessageBuilderFactor,
-            configuration: grailsApplication.config)
+                mailConfigurationProperties: new MailConfigurationProperties())
         mimeCapableMailService.afterPropertiesSet()
 
         MailSender simpleMailSender = new SimpleMailSender()
@@ -79,7 +79,7 @@ class MailServiceSpec extends Specification  {
         )
         nonMimeCapableMailService = new MailService(
             mailMessageBuilderFactory: simpleMessageBuilderFactory,
-            configuration: grailsApplication.config)
+                mailConfigurationProperties: new MailConfigurationProperties())
         nonMimeCapableMailService.afterPropertiesSet()
     }
 

src/main/groovy/grails/plugins/mail/MailConfig.groovy

@@ -0,0 +1,103 @@
+package grails.plugins.mail
+
+import grails.core.GrailsApplication
+import grails.plugins.GrailsPluginManager
+import grails.web.pages.GroovyPagesUriService
+import groovy.transform.CompileStatic
+import org.grails.gsp.GroovyPagesTemplateEngine
+import org.springframework.beans.factory.annotation.Autowired
+import org.springframework.beans.factory.annotation.Qualifier
+import org.springframework.boot.autoconfigure.condition.ConditionalOnMissingBean
+import org.springframework.boot.autoconfigure.condition.ConditionalOnProperty
+import org.springframework.context.annotation.Bean
+import org.springframework.context.annotation.Configuration
+import org.springframework.jndi.JndiObjectFactoryBean
+import org.springframework.mail.MailSender
+import org.springframework.mail.javamail.JavaMailSenderImpl
+
+import javax.mail.Session
+
+@Configuration
+@CompileStatic
+class MailConfiguration {
+
+    @Bean
+    MailConfigurationProperties mailConfigurationProperties() {
+        return new MailConfigurationProperties()
+    }
+
+    @Bean
+    @ConditionalOnMissingBean(name = 'mailSession')
+    @ConditionalOnProperty(prefix = 'grails.mail', name = 'jndiName')
+    JndiObjectFactoryBean mailSession(MailConfigurationProperties mailProperties) {
+        JndiObjectFactoryBean factory = new JndiObjectFactoryBean()
+        factory.jndiName = mailProperties.jndiName
+        return factory
+    }
+
+    @Bean
+    JavaMailSenderImpl mailSender(
+            @Autowired(required = false) @Qualifier('mailSession') Session mailSession,
+            MailConfigurationProperties mailProperties) {
+
+        JavaMailSenderImpl mailSender = new JavaMailSenderImpl()
+        if (mailProperties.host) {
+            mailSender.host = mailProperties.host
+        } else if (!mailProperties.jndiName) {
+            def envHost = System.getenv()['SMTP_HOST']
+            if (envHost) {
+                mailSender.host = envHost
+            } else {
+                mailSender.host = 'localhost'
+            }
+        }
+        if (mailProperties.encoding) {
+            mailSender.defaultEncoding = mailProperties.encoding
+        } else if (!mailProperties.jndiName) {
+            mailSender.defaultEncoding = 'utf-8'
+        }
+        if (mailSession != null) {
+            mailSender.session = mailSession
+        }
+        if (mailProperties.port) {
+            mailSender.port = mailProperties.port
+        }
+        if (mailProperties.username) {
+            mailSender.username = mailProperties.username
+        }
+        if (mailProperties.password) {
+            mailSender.password = mailProperties.password
+        }
+        if (mailProperties.protocol) {
+            mailSender.protocol = mailProperties.protocol
+        }
+        if (mailProperties.props) {
+            mailSender.javaMailProperties = mailProperties.props
+        }
+        return mailSender
+    }
+
+    @Bean
+    MailMessageBuilderFactory mailMessageBuilderFactory(
+            MailSender mailSender,
+            MailMessageContentRenderer mailMessageContentRenderer) {
+        MailMessageBuilderFactory factory = new MailMessageBuilderFactory()
+        factory.mailSender = mailSender
+        factory.mailMessageContentRenderer = mailMessageContentRenderer
+        return factory
+    }
+
+    @Bean
+    MailMessageContentRenderer mailMessageContentRenderer(
+            GroovyPagesTemplateEngine groovyPagesTemplateEngine,
+            GroovyPagesUriService groovyPagesUriService,
+            GrailsApplication grailsApplication,
+            GrailsPluginManager pluginManager) {
+        MailMessageContentRenderer renderer = new MailMessageContentRenderer()
+        renderer.groovyPagesTemplateEngine = groovyPagesTemplateEngine
+        renderer.groovyPagesUriService = groovyPagesUriService
+        renderer.grailsApplication = grailsApplication
+        renderer.pluginManager = pluginManager
+        return renderer
+    }
+}

src/main/groovy/grails/plugins/mail/MailConfiguration.groovy

@@ -0,0 +1,36 @@
+package grails.plugins.mail
+
+import org.springframework.boot.context.properties.ConfigurationProperties
+
+@ConfigurationProperties(MailConfigurationProperties.PREFIX)
+class MailConfigurationProperties {
+
+    public static final String PREFIX = 'grails.mail'
+
+    boolean disabled
+    String overrideAddress
+    Defaults defaults = new Defaults()
+
+    Integer poolSize
+    String encoding
+    String jndiName
+    String protocol
+    String host
+    Integer port
+    String username
+    String password
+    Properties props
+
+    /**
+     * We can't use 'default' as a groovy property name as it is a reserved keyword.
+     * But it is possible to define a getter for it to make it compatible.
+     */
+    Defaults getDefault() {
+        return defaults
+    }
+
+    static class Defaults {
+        String from
+        String to
+    }
+}