Fixes composite identifier not visible to JPA

I am not sure if this fix is correct.

The hibernate documentation [1] says that there are the following ways to define a composite identity:

- @EmbeddedId
- @IdClass
- Composite identifiers with associations => Use @id multiple times

I am not sure what the binding by `bindCompositeId` corresponds to.

I just know that in the 3rd case hibernate does set the `identifierMapper`. I am not sure if there is valid in the other cases.

[1]: https://docs.jboss.org/hibernate/orm/5.2/userguide/html_single/Hibernate_User_Guide.html#identifiers-composite

Author: felixscheinost

grails-datastore-gorm-hibernate5/src/main/groovy/org/grails/orm/hibernate/cfg/GrailsDomainBinder.java

@@ -1828,6 +1828,7 @@ protected void bindCompositeId(PersistentEntity domainClass, RootClass root,
         Component id = new Component(metadataBuildingContext, root);
         id.setNullValue("undefined");
         root.setIdentifier(id);
+        root.setIdentifierMapper(id);
         root.setEmbeddedIdentifier(true);
         id.setComponentClassName(domainClass.getName());
         id.setKey(true);

grails-datastore-gorm-hibernate5/src/test/groovy/grails/gorm/tests/compositeid/CompositeIdCriteria.groovy

@@ -0,0 +1,95 @@
+package grails.gorm.tests.compositeid
+
+import grails.gorm.annotation.Entity
+import grails.gorm.hibernate.mapping.MappingBuilder
+import grails.gorm.transactions.Rollback
+import org.grails.orm.hibernate.HibernateDatastore
+import spock.lang.AutoCleanup
+import spock.lang.Issue
+import spock.lang.Shared
+import spock.lang.Specification
+
+@Rollback
+class CompositeIdCriteria extends Specification {
+
+  @Shared
+  @AutoCleanup
+  HibernateDatastore datastore = new HibernateDatastore(CompositeIdToMany, CompositeIdSimple, Author, Book)
+
+  @Issue("https://github.com/grails/gorm-hibernate5/issues/234")
+  def "test that composite to-many properties can be queried using JPA"() {
+    Author _author = new Author(name:"Author").save()
+    Book _book = new Book(title:"Book").save()
+    CompositeIdToMany compositeIdToMany = new CompositeIdToMany(author:_author, book:_book).save(failOnError:true, flush:true)
+
+    def criteriaBuilder = datastore.sessionFactory.criteriaBuilder
+    def criteriaQuery = criteriaBuilder.createQuery()
+    def root = criteriaQuery.from(CompositeIdToMany)
+    criteriaQuery.select(root)
+    criteriaQuery.where(criteriaBuilder.equal(root.get("author"), _author))
+    def query = datastore.sessionFactory.currentSession.createQuery(criteriaQuery)
+
+    expect:
+    query.list() == [compositeIdToMany]
+  }
+
+  def "test that composite can be queried using JPA"() {
+    CompositeIdSimple compositeIdSimple = new CompositeIdSimple(name:"name", age:2l).save(failOnError:true, flush:true)
+
+    def criteriaBuilder = datastore.sessionFactory.criteriaBuilder
+    def criteriaQuery = criteriaBuilder.createQuery()
+    def root = criteriaQuery.from(CompositeIdSimple)
+    criteriaQuery.select(root)
+    criteriaQuery.where(criteriaBuilder.equal(root.get("name"), "name"))
+    def query = datastore.sessionFactory.currentSession.createQuery(criteriaQuery)
+
+    expect:
+    query.list() == [compositeIdSimple]
+  }
+
+  @Issue("https://github.com/grails/grails-data-mapping/issues/1351")
+  def "test that composite to-many can be used in criteria"() {
+    Author _author = new Author(name:"Author").save()
+    Book _book = new Book(title:"Book").save()
+    CompositeIdToMany compositeIdToMany = new CompositeIdToMany(author:_author, book:_book).save(failOnError:true, flush:true)
+
+    expect:
+    CompositeIdToMany.createCriteria().list {
+      author {
+        eq('id', _author.id)
+      }
+    } == [compositeIdToMany]
+  }
+}
+
+@Entity
+class Author {
+  String name
+}
+
+@Entity
+class Book {
+  String title
+}
+
+@Entity
+class CompositeIdToMany implements Serializable {
+  Author author
+  Book book
+
+  static mapping = MappingBuilder.define {
+    composite("author", "book")
+  }
+}
+
+@Entity
+class CompositeIdSimple implements Serializable {
+  String name
+  Long age
+
+  static mapping = MappingBuilder.define {
+    composite("name", "age")
+  }
+}
+
+