Examples? Help needed

[clivemist]

Please excuse me, it has been a while since I last delved in to newer libraries, but I am struggling to work out how I initiate and use this library to use it correctly.

I am using a WROOM module with the APS6404L.

Would it be possible to put up an example so that I may test, read and write, and otherwise access the package?

I am using the current pinout defines also:

#define HSPI_SCLK 18
#define HSPI_MOSI 23
#define HSPI_MISO 19
#define HSPI_SS 5

Thanks!

[grandaspanna]

I'm travelling at the moment. I think I have a WROOM module at home, but won't be able to test it for at least a week and a bit.

The library in its current form uses the default SPI interface, which quite likely maps to the pins you've identified above. VSPI is likely the default SPI, depending on the Arduino core you're using.

Assuming that's the case, the general approach to using the module via the library would be something like this:

#include <SPI.h>
#include <APS6404L.h>

#define RAM_CSPIN  5 // Chip select pin for the SPI RAM chip
APS6404L_Ram ram(RAM_CSPIN);

// Data record definition
struct DataRecordT {
  uint32_t  recordNo;
  uint32_t  timeStamp;
  uint16_t  data_1, data_2;
  uint16_t  moreData1, moreData2, moreData3;
  uint16_t  OneMoreData;
  boolean endRecord;  
};

struct DataRecordT logRecord;

// Keep record position
uint32_t currentRecord;
uint32_t  currentAddress;

// Number of records to write
#define TESTRECS 1000

#define LED1 17

void setup() {
  // Configure the LED pins
  pinMode(LED1,OUTPUT);
    
  // Setup the RAM chip
  ram.begin();
  
  // Populate ID info
  if(ram.readChipID()){
    // Was successful, blink once
    digitalWrite(LED1,HIGH); 
    delay(400);
    digitalWrite(LED1,LOW);
  }
  else{
    // Was not successful, blink 5 times
    for(int i=0;i<5;i++){
      digitalWrite(LED1,HIGH);
      delay(400);
      digitalWrite(LED1,LOW);
      delay(400);
    }
  }
}
void loop(){
  // Do a test
  currentAddress = 0;
  uint32_t currentRecord = 0;
  int addressIncrement = sizeof(logRecord);
  uint32_t startTime = millis();
  for(int i = 0 ; i < TESTRECS ; i++){
    logRecord.recordNo = currentRecord;
    logRecord.timeStamp = millis();
    logRecord.data_1 = random(1000);
    logRecord.moreData1 = 512;
    logRecord.moreData2 = 384;
    logRecord.moreData3 = 519;
    logRecord.endRecord = false;
    ram.writeData(currentAddress,(uint8_t*)&logRecord,sizeof(logRecord));
    currentAddress+=addressIncrement;
    currentRecord+=1;
  }

  // Grab a record at random. First pic a random record number
  uint32_t recordToGet = random(TESTRECS);
  // Convert to an address
  currentAddress = recordToGet * sizeof(logRecord);
  // Retrieve the record
  ram.readData(currentAddress,(uint8_t*)&logRecord,sizeof(logRecord));

  // Do something with data
  Serial.print("Record no = ");
  Serial.print(logRecord.recordNo);
  Serial.print(", timestamp = ");
  Serial.print(logRecord.timeStamp);
  Serial.print(", data_1 = ");
  Serial.println(logRecord.data_1);

  delay(2000);
}

[clivemist]

Hi Grandaspanna

I have the following serial output:

Record no = 557, timestamp = 80940, data_1 = 493
Record no = 268, timestamp = 83248, data_1 = 801
Record no = 182, timestamp = 85643, data_1 = 829
Record no = 179, timestamp = 88075, data_1 = 512
Record no = 38, timestamp = 90447, data_1 = 460
Record no = 418, timestamp = 93044, data_1 = 138
Record no = 75, timestamp = 95329, data_1 = 118
Record no = 365, timestamp = 97888, data_1 = 931
Record no = 348, timestamp = 100313, data_1 = 85
Record no = 866, timestamp = 102970, data_1 = 819
Record no = 65, timestamp = 105057, data_1 = 762
Record no = 888, timestamp = 107846, data_1 = 57
Record no = 877, timestamp = 110274, data_1 = 848
Record no = 672, timestamp = 112618, data_1 = 622
Record no = 61, timestamp = 114787, data_1 = 452
Record no = 657, timestamp = 117478, data_1 = 275

Does this mean that the APS6404L is working as expected?!

Thanks!

[grandaspanna]

Did you have an LED connected to a corresponding pin? That's the main diagnostic element of the code. The rest of the code is meant to show how package data and do read/writes. You could also try doing something like this, after the "readChipID" call:

Serial.print("EID = ");
Serial.println(ram.EID);

It's a couple of bytes long, so not sure how the standard print function will deal with it. The EID contains information on the chip

[clivemist]

"Did you have an LED connected to a corresponding pin?"

Yes! I changed this in the code to pin 4 as this was what I have hooked up.
It flashes on then off for boot, so assume that is working correctly!

I made some minor corrections to the code as you had missed things like "Serial.begin" ect. I also corrected some pins and other things.

I currently have the addition you posted in the main loop just for now as I'm having difficulty with the serial at the moment (it just seems to be on this specific board)

Serial.print("EID = ");
Serial.println(ram.EID);

Current code:

#include <SPI.h>
#include <APS6404L.h>

#define RAM_CSPIN 5  // Chip select pin for the SPI RAM chip
APS6404L_Ram ram(RAM_CSPIN);

// Data record definition
struct DataRecordT {
  uint32_t recordNo;
  uint32_t timeStamp;
  uint16_t data_1, data_2;
  uint16_t moreData1, moreData2, moreData3;
  uint16_t OneMoreData;
  boolean endRecord;
};

struct DataRecordT logRecord;

// Keep record position
uint32_t currentRecord;
uint32_t currentAddress;

// Number of records to write
#define TESTRECS 1000

#define LED1 4

void setup() {

  Serial.begin(115200);
  // Configure the LED pins
  pinMode(LED1, OUTPUT);

  // Setup the RAM chip
  ram.begin();  // (CLK_PIN,SO_PIN,SI_PIN,m_csPin)

  // Populate ID info
  if (ram.readChipID()) {
    // Was successful, blink once
    digitalWrite(LED1, HIGH);
    delay(400);
    digitalWrite(LED1, LOW);
  } else {
    // Was not successful, blink 5 times
    for (int i = 0; i < 5; i++) {
      digitalWrite(LED1, HIGH);
      delay(400);
      digitalWrite(LED1, LOW);
      delay(400);
    }
  }
}
void loop() {
  // Do a test
  currentAddress = 0;
  uint32_t currentRecord = 0;
  int addressIncrement = sizeof(logRecord);
  uint32_t startTime = millis();
  for (int i = 0; i < TESTRECS; i++) {
    logRecord.recordNo = currentRecord;
    logRecord.timeStamp = millis();
    logRecord.data_1 = random(1000);
    logRecord.moreData1 = 512;
    logRecord.moreData2 = 384;
    logRecord.moreData3 = 519;
    logRecord.endRecord = false;
    ram.writeData(currentAddress, (uint8_t*)&logRecord, sizeof(logRecord));  // ADDR. DATA. SIZE
    currentAddress += addressIncrement;
    currentRecord += 1;
  }

  // Grab a record at random. First pic a random record number
  uint32_t recordToGet = random(TESTRECS);
  // Convert to an address
  currentAddress = recordToGet * sizeof(logRecord);
  // Retrieve the record
  ram.readData(currentAddress, (uint8_t*)&logRecord, sizeof(logRecord));

  // Do something with data
  Serial.print("EID = ");
  Serial.println(ram.EID);
  Serial.print("Record no = ");
  Serial.print(logRecord.recordNo);
  Serial.print(", timestamp = ");
  Serial.print(logRecord.timeStamp);
  Serial.print(", data_1 = ");
  Serial.println(logRecord.data_1);



  delay(2000);
}

I am now getting a printout of:

EID = 82628591063489

Thank you for your help so far, it's been awesome!

I am now wondering, how do I read and write to specific addresses?

I am a little lost on how to format this correctly?

ram.writeData(ADDRESS, DATA, ????);
ram.readData(ADDRESS, DATA, ????);

Assuming I wish to define pins when initializing..

Is this the correct order in which to format the init?

ram.begin(CLK, MOSI, MISO, CS);

[grandaspanna]

The first parameter to read & write is the byte address of where you want to start the operation. The second value is a pointer to the data. The last parameter is the number of bytes to read/write. You need to calculate the byte address of what you want to access. If you're writing a data type of 4 bytes, then the address of a given object will be n*4 (where first object is number 0). In the example code, an arbitrary structure is written/read, so the sizeof() function is used to work out the object size and calculate addresses.

The current version only accepts a single parameter which is the pin to be used for chip select. I see a benefit in making the SPI object a parameter too, allowing flexibility on architectures with multiple SPI ports. I'll have a look at this when I get back from this trip.