Add BLE examples.

Author: h2zero

libraries/n-able/examples/BLE_Advertiser/BLE_Advertiser.ino

@@ -0,0 +1,43 @@
+/**
+ * Example of advertising service data.
+ *
+ * This example will start advertising service data for a custom UUID, the data value of which
+ * will increment by one every 5 seconds.
+ *
+ * Note the configuration options in the build_opt.h file.
+ * More BLE examples can be found in the NimBLE-Arduino examples: https://github.com/h2zero/NimBLE-Arduino.
+ *
+ * For further BLE documentation see: https://h2zero.github.io/NimBLE-Arduino
+ */
+
+#include <Arduino.h>
+#include <NimBLEDevice.h>
+
+#define SERVICE_UUID "4fafc201-1fb5-459e-8fcc-c5c9c331914b"
+
+static NimBLEUUID dataUuid(SERVICE_UUID);
+static NimBLEAdvertising *pAdvertising = NimBLEDevice::getAdvertising();
+static uint32_t count = 0;
+
+void setup() {
+  Serial.begin(115200);
+  Serial.println("Starting Advertising!");
+
+  // Initialize the stack
+  NimBLEDevice::init("NimBLE");
+}
+
+void loop() {
+  if (!pAdvertising->isAdvertising()) {
+    // Update the advertised data
+    pAdvertising->setServiceData(dataUuid, std::string((char*)&count, sizeof(count)));
+
+    // Start advertising the data
+    pAdvertising->start(5);
+    Serial.printf("Advertising count = %d\n", count);
+    count++;
+  }
+
+  // Short delay to allow the stack to reset states.
+  delay(100);
+}

libraries/n-able/examples/BLE_Advertiser/build_opt.h

@@ -0,0 +1,5 @@
+'-DCONFIG_MAIN_TASK_STACK_SIZE=512'
+'-DCONFIG_BT_NIMBLE_HOST_TASK_STACK_SIZE=1024'
+'-DCONFIG_BT_NIMBLE_ROLE_CENTRAL_DISABLED'
+'-DCONFIG_BT_NIMBLE_ROLE_OBSERVER_DISABLED'
+'-DCONFIG_BT_NIMBLE_ROLE_PERIPHERAL_DISABLED'

libraries/n-able/examples/BLE_Scan/BLE_Scan.ino

@@ -0,0 +1,59 @@
+/**
+ * Example of continuous scanning for BLE advertisements.
+ * This example will scan for scanTime (seconds) and report all advertisements on the serial monitor.
+ *
+ * Note the configuration options in the build_opt.h file.
+ * More BLE examples can be found in the NimBLE-Arduino examples: https://github.com/h2zero/NimBLE-Arduino.
+ *
+ * For further BLE documentation see: https://h2zero.github.io/NimBLE-Arduino
+ */
+
+#include <Arduino.h>
+#include "NimBLEDevice.h"
+
+NimBLEScan* pBLEScan;
+uint32_t scanTime = 30; // Scan duration in seconds (0 = forever)
+
+// Callback class for received advertisements
+class MyAdvertisedDeviceCallbacks: public NimBLEAdvertisedDeviceCallbacks {
+    void onResult(NimBLEAdvertisedDevice* advertisedDevice) {
+      Serial.printf("Advertised Device: %s \n", advertisedDevice->toString().c_str());
+    }
+};
+
+void setup() {
+  Serial.begin(115200);
+  Serial.println("Scanning...");
+
+  // Initialize the BLE stack
+  NimBLEDevice::init("");
+
+  // Create new scan instance
+  pBLEScan = NimBLEDevice::getScan();
+
+  // Set the callback for when devices are discovered, no duplicates.
+  pBLEScan->setAdvertisedDeviceCallbacks(new MyAdvertisedDeviceCallbacks(), false);
+
+  // Set active scanning, this will get scan response data from the advertiser.
+  pBLEScan->setActiveScan(true);
+
+  // Set how often the scan occurs/switches channels; in milliseconds,
+  pBLEScan->setInterval(97);
+
+  // How long to scan during the interval; in milliseconds.
+  pBLEScan->setWindow(37);
+
+  // Do not store the scan results, use callback only.
+  pBLEScan->setMaxResults(0);
+}
+
+void loop() {
+  // When the scan stops, restart it. This will cause duplicate devices to be reported again.
+  if(pBLEScan->isScanning() == false) {
+      // Start scan with: duration = scanTime (seconds), no scan ended callback, not a continuation of a previous scan.
+      pBLEScan->start(scanTime, nullptr, false);
+  }
+
+  // Short delay to allow the stack to reset states.
+  delay(100);
+}

libraries/n-able/examples/BLE_Scan/build_opt.h

@@ -0,0 +1,4 @@
+'-DCONFIG_MAIN_TASK_STACK_SIZE=512'
+'-DCONFIG_BT_NIMBLE_HOST_TASK_STACK_SIZE=1024'
+'-DCONFIG_BT_NIMBLE_ROLE_PERIPHERAL_DISABLED'
+'-DCONFIG_BT_NIMBLE_ROLE_BROADCASTER_DISABLED'