Implement --matrix-extra for more matrix dimensions

Sometimes you need to test your project along more dimensions than
just GHC version.  This is particularly important for
programs/libraries that use FFI to bind to libraries - they might
need to be tested against a range of library versions.

In general, you want to test all the combinations of GHC versions
and other properties, i.e. the cartesian product.  It is burdensome
for maintainers that need such a strategy to manually adjust the
matrix after every (re)generation of the CI script/spec.  Better
tool support for this scenario is warranted.

This commit implements a new --matrix-extra option, which adds
additional matrix dimensions.  The option value format is:

  --matrix-extra libfoo:2.6,3.0;libbar:0.1,0.2

haskell-ci adds all the combinations of GHC version and the
--matrix-extra fields to the matrix.  Corresponding build/test steps
can be introduced via --github-patches (or --travis-patches).

This commit implements this feature for GitHub actions only.  It can
be implemented for Travis in a subsequent commit, if desired.

Author: frasertweedale

src/HaskellCI/Config.hs

@@ -83,6 +83,7 @@ data Config = Config
     , cfgPostgres            :: !Bool
     , cfgGoogleChrome        :: !Bool
     , cfgEnv                 :: M.Map Version String
+    , cfgMatrixExtra         :: M.Map String (S.Set String)
     , cfgAllowFailures       :: !VersionRange
     , cfgLastInSeries        :: !Bool
     , cfgLinuxJobs           :: !VersionRange
@@ -132,7 +133,7 @@ configGrammar
        , c (Identity Version)
        , c (Identity Natural)
        , c (Identity Components)
-       , c Env, c Folds, c CopyFields, c HeadVersion
+       , c Env, c MatrixExtra, c Folds, c CopyFields, c HeadVersion
        , c (C.List C.FSep (Identity Installed) Installed)
        , Applicative (g DoctestConfig)
        , Applicative (g DocspecConfig)
@@ -215,6 +216,8 @@ configGrammar = Config
         ^^^ help "Add google-chrome service"
     <*> C.monoidalFieldAla    "env"                       Env                                 (field @"cfgEnv")
         ^^^ metahelp "ENV" "Environment variables per job (e.g. `8.0.2:HADDOCK=false`)"
+    <*> C.monoidalFieldAla    "matrix-extra"              MatrixExtra                         (field @"cfgMatrixExtra")
+        ^^^ metahelp "MATRIX" "Extra matrix dimensions (e.g. `libfoo:2.6,3.0,git`)"
     <*> C.optionalFieldDefAla "allow-failures"            Range                               (field @"cfgAllowFailures") noVersion
         ^^^ metahelp "JOB" "Allow failures of particular GHC version"
     <*> C.booleanFieldDef     "last-in-series"                                                (field @"cfgLastInSeries") False
@@ -305,6 +308,28 @@ instance C.Pretty Env where
     pretty (Env m) = PP.fsep . PP.punctuate PP.comma . map p . M.toList $ m where
         p (v, s) = C.pretty v PP.<> PP.colon PP.<> PP.text s
 
+
+-------------------------------------------------------------------------------
+-- MatrixExtra
+-------------------------------------------------------------------------------
+
+newtype MatrixExtra = MatrixExtra (M.Map String (S.Set String))
+  deriving anyclass (C.Newtype (M.Map String (S.Set String)))
+
+instance C.Parsec MatrixExtra where
+  parsec = MatrixExtra . M.fromList . toList <$> C.sepByNonEmpty p (C.char ';')
+    where
+    p = do
+      k <- C.munch1 (/= ':')
+      _ <- C.char ':'
+      v <- foldMap S.singleton <$> C.sepByNonEmpty (C.munch1 (`notElem` [',', ';'])) (C.char ',')
+      pure (k, v)
+
+instance C.Pretty MatrixExtra where
+  pretty (MatrixExtra m) = PP.fsep . PP.punctuate PP.semi . map p . M.toList $ m where
+    p (k, v) = PP.text k PP.<> PP.colon PP.<> PP.fsep (PP.punctuate PP.comma (map PP.text (toList v)))
+
+
 -------------------------------------------------------------------------------
 -- From Cabal
 -------------------------------------------------------------------------------

src/HaskellCI/GitHub.hs

@@ -618,18 +618,7 @@ makeGitHub _argv config@Config {..} gitconfig prj jobs@JobVersions {..} = do
                 , ghjServices        = mconcat
                     [ Map.singleton "postgres" postgresService | cfgPostgres ]
                 , ghjTimeout         = max 10 cfgTimeoutMinutes
-                , ghjMatrix          =
-                    [ GitHubMatrixEntry
-                        { ghmeCompiler     = translateCompilerVersion $ compiler
-                        , ghmeAllowFailure =
-                               previewGHC cfgHeadHackage compiler
-                            || maybeGHC False (`C.withinRange` cfgAllowFailures) compiler
-                        , ghmeSetupMethod = if isGHCUP compiler then GHCUP else HVRPPA
-                        }
-                    | compiler <- reverse $ toList linuxVersions
-                    , compiler /= GHCHead -- TODO: Make this work
-                                          -- https://github.com/haskell-CI/haskell-ci/issues/458
-                    ]
+                , ghjMatrix          = matrix
                 })
             unless (null cfgIrcChannels) $
                 ircJob actionName mainJobName projectName config gitconfig
@@ -678,6 +667,33 @@ makeGitHub _argv config@Config {..} gitconfig prj jobs@JobVersions {..} = do
     isGHCUP :: CompilerVersion -> Bool
     isGHCUP v = compilerWithinRange v (RangeGHC /\ Range cfgGhcupJobs)
 
+    -- extra matrix fields
+    matrixExtra :: [[(String, String)]]
+    matrixExtra =
+      sequence
+      $ (\(k, vs) -> fmap (\v -> (k, v)) (toList vs))
+      <$> Map.toList cfgMatrixExtra
+
+    mkMatrixEntries :: [(String, String)] -> [GitHubMatrixEntry]
+    mkMatrixEntries extra =
+      [ GitHubMatrixEntry
+          { ghmeCompiler     = translateCompilerVersion $ compiler
+          , ghmeAllowFailure =
+                 previewGHC cfgHeadHackage compiler
+              || maybeGHC False (`C.withinRange` cfgAllowFailures) compiler
+          , ghmeSetupMethod = if isGHCUP compiler then GHCUP else HVRPPA
+          , ghmeMatrixExtra = extra
+          }
+      | compiler <- reverse $ toList linuxVersions
+      , compiler /= GHCHead -- TODO: Make this work
+                            -- https://github.com/haskell-CI/haskell-ci/issues/458
+      ]
+
+    matrix :: [GitHubMatrixEntry]
+    matrix = case matrixExtra of
+      [] -> mkMatrixEntries []
+      xs -> xs >>= mkMatrixEntries
+
     -- step primitives
     githubRun' :: String -> Map.Map String String ->  ShM () -> ListBuilder (Either HsCiError GitHubStep) ()
     githubRun' name env shm = item $ do

src/HaskellCI/GitHub/Yaml.hs

@@ -48,6 +48,7 @@ data SetupMethod = HVRPPA | GHCUP
 data GitHubMatrixEntry = GitHubMatrixEntry
     { ghmeCompiler     :: CompilerVersion
     , ghmeAllowFailure :: Bool
+    , ghmeMatrixExtra  :: [(String, String)]
     , ghmeSetupMethod  :: SetupMethod
     }
   deriving (Show)
@@ -134,13 +135,13 @@ instance ToYaml SetupMethod where
     toYaml GHCUP  = "ghcup"
 
 instance ToYaml GitHubMatrixEntry where
-    toYaml GitHubMatrixEntry {..} = ykeyValuesFilt []
+    toYaml GitHubMatrixEntry {..} = ykeyValuesFilt [] $
         [ "compiler"        ~> fromString (dispGhcVersion ghmeCompiler)
         , "compilerKind"    ~> fromString (compilerKind ghmeCompiler)
         , "compilerVersion" ~> fromString (compilerVersion ghmeCompiler)
         , "setup-method"    ~> toYaml ghmeSetupMethod
         , "allow-failure"   ~> toYaml ghmeAllowFailure
-        ]
+        ] ++ fmap (\(k, v) -> k ~> fromString v) ghmeMatrixExtra
 
 instance ToYaml GitHubStep where
     toYaml GitHubStep {..} = ykeyValuesFilt [] $