toml2json/BUILD.bazel at master · hermeticbuild/toml2json · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
load("@bazel_lib//lib:transitions.bzl", "platform_transition_filegroup")
load("@rules_rs//rs:rust_binary.bzl", "rust_binary")

rust_binary(
    name = "toml2json",
    srcs = ["src/main.rs"],
    crate_root = "src/main.rs",
    deps = [
        "@crates//:serde_json",
        "@crates//:serde-transcode",
        "@crates//:toml",
    ],
)

[
    platform_transition_filegroup(
        name = "for_" + triple,
        srcs = [":toml2json"],
        target_platform = "@rules_rs//rs/experimental/platforms:" + triple,
    )
    for triple in [
        "aarch64-apple-darwin",
        "x86_64-apple-darwin",
        "aarch64-unknown-linux-musl",
        "x86_64-unknown-linux-musl",
        "aarch64-pc-windows-msvc",
        "x86_64-pc-windows-msvc",
    ]
]

filegroup(
    name = "for_non_windows_platforms",
    srcs = [
        "for_aarch64-apple-darwin",
        "for_x86_64-apple-darwin",
        "for_aarch64-unknown-linux-musl",
        "for_x86_64-unknown-linux-musl",
    ],
)

platform(
    name = "local_linux_platform",
    parents = ["@platforms//host"],
    constraint_values = [
        "@llvm//constraints/libc:gnu.2.28",
    ],
)

platform(
    name = "local_windows_platform",
    parents = ["@platforms//host"],
    constraint_values = [
        "@rules_rs//rs/experimental/platforms/constraints:windows_msvc",
    ],
)