[FREELDR] Add/change necessary code for the initial position relative code (reactos#7530)

CORE-19882

Author: iLauncherDev

boot/freeldr/freeldr/arch/amd64/entry.S

@@ -214,7 +214,7 @@ SwitchToRealCompSegment:
     .byte HEX(0EA) // 32bit long jmp
 AddressOfRealModeEntryPoint:
     .long 0 // receives address of RealModeEntryPoint
-    .word HEX(20)//RMODE_CS
+    .word L_RMODE_CS
     nop
 
 CallRealMode_return:

boot/freeldr/freeldr/arch/realmode/amd64.S

@@ -367,6 +367,7 @@ stack16:
 
 
 #include "int386.inc"
+#include "helpers_all.inc"
 #include "helpers.inc"
 #include "pxe.inc"
 #include "pnp.inc"

boot/freeldr/freeldr/arch/realmode/helpers_all.inc

@@ -0,0 +1,155 @@
+/*
+ * PROJECT:     FreeLoader
+ * LICENSE:     GPL-2.0-or-later (https://spdx.org/licenses/GPL-2.0-or-later)
+ * PURPOSE:     Real mode helper code for all architectures
+ * COPYRIGHT:   Copyright 2024-2025 Daniel Victor <[email protected]>
+ */
+
+Relocator16SS:
+    .word 0
+Relocator16EAX:
+    .long 0
+Relocator16ESP:
+    .long 0
+
+cs_writestr:
+    /* Save necessary registers */
+    push ax
+    push ds
+
+    /* Prepare ds before writestr call */
+    mov ax, cs
+    mov ds, ax
+
+    /* Display the message */
+    call writestr
+
+    /* Restore necessary registers and return */
+    pop ds
+    pop ax
+    ret
+
+/* This function will Update BSS_CurrentBaseAddress, instruction pointer, code segment and relocate if necessary */
+RelocateFreeLdr:
+    /* Clear necessary registers */
+    xor eax, eax
+    xor ebx, ebx
+    xor ecx, ecx
+
+    /* Call the sub function to get the base address */
+    call .SubCall
+.SubCall:
+    /* Pop the return address into bx. Since the return address is consumed,
+     * this function does not return to UpdateCurrentCodeSegment */
+    pop bx
+
+    /* Calculate the base address by adjusting the offset */
+    sub bx, offset .SubCall
+
+    /* Load the current code segment into eax */
+    mov ax, cs
+
+    /* Shift the segment address to get its physical address (real mode calculation) */
+    shl eax, 4
+
+    /* Add the physical segment base to the relative base address */
+    add eax, ebx
+
+    /* Store the calculated base address (low 32 bits) */
+    mov dword ptr ds:[BSS_CurrentBaseAddress], eax
+
+.FixBaseAddress:
+    /* Don't relocate if it's not necessary */
+    cmp eax, FREELDR_BASE
+    jz .NotNecessaryRelocation
+
+    /* Setup source segment */
+    shr eax, 4
+    mov ds, ax
+
+    /* Move the realmode FREELDR code to TEMPCODE16_BASE */
+    mov di, TEMPCODE16_BASE
+    xor si, si
+    mov cx, FREELDR_PE_BASE - FREELDR_BASE
+    rep movsb
+
+    ljmp16 TEMPCODE16_BASE / 16, .FixBaseAddress2
+.FixBaseAddress2:
+    /* Prepare the registers for relocation */
+    mov cx, (MEMORY_MARGIN - FREELDR_BASE) / 16
+    mov eax, dword ptr es:[BSS_CurrentBaseAddress]
+    shr eax, 4
+    mov ds, ax
+    mov ax, FREELDR_BASE / 16
+    mov es, ax
+
+    /* If current base address is lower than the final one then just copy it backwards */
+    cmp dword ptr fs:[BSS_CurrentBaseAddress], FREELDR_BASE
+    jb .PreFixLoopInverted
+.FixLoop:
+    /* Save CX */
+    push cx
+
+    /* Copy 16 bytes from source to destination */
+    xor di, di
+    xor si, si
+    mov cx, HEX(10)
+    rep movsb
+
+    /* Restore CX */
+    pop cx
+
+    /* Increment DS */
+    mov ax, ds
+    inc ax
+    mov ds, ax
+
+    /* Increment ES */
+    mov ax, es
+    inc ax
+    mov es, ax
+
+    /* Repeat the loop while decrementing cx */
+    loop .FixLoop
+    jmp .FinishedRelocation
+.PreFixLoopInverted:
+    /* Move DS to the end */
+    mov ax, ds
+    add ax, cx
+    mov ds, ax
+
+    /* Move ES to the end */
+    mov ax, es
+    add ax, cx
+    mov es, ax
+.FixLoopInverted:
+    /* Decrement DS */
+    mov ax, ds
+    dec ax
+    mov ds, ax
+
+    /* Decrement ES */
+    mov ax, es
+    dec ax
+    mov es, ax
+
+    /* Save CX */
+    push cx
+
+    /* Copy 16 bytes from source to destination */
+    xor di, di
+    xor si, si
+    mov cx, HEX(10)
+    rep movsb
+
+    /* Restore CX */
+    pop cx
+
+    /* Repeat the loop while decrementing cx */
+    loop .FixLoopInverted
+
+.FinishedRelocation:
+    ljmp16 FREELDR_BASE / 16, 0
+
+.NotNecessaryRelocation:
+    ret

boot/freeldr/freeldr/arch/realmode/i386.S

@@ -199,6 +199,7 @@ rmode_idtptr:
     .long 0             /* Base Address */
 
 #include "int386.inc"
+#include "helpers_all.inc"
 #if defined(SARCH_PC98)
 #include "helpers_pc98.inc"
 #else

boot/freeldr/freeldr/include/arch/pc/x86common.h

@@ -12,11 +12,14 @@
 #define BIOSCALLBUFFER      HEX(4000) /* Buffer to store temporary data for any Int386() call */
 #define STACK16ADDR         HEX(6F00) /* The 16-bit stack top will be at 0000:6F00 */
 #define BSS_START           HEX(6F00)
-#define STACKLOW            HEX(7000)
+#define STACKLOW            HEX(8000)
 #define STACKADDR           HEX(F000) /* The 32/64-bit stack top will be at 0000:F000, or 0xF000 */
-#define FREELDR_BASE        HEX(F800)
-#define FREELDR_PE_BASE    HEX(10000)
-#define MEMORY_MARGIN      HEX(88000) /* We need this much memory */
+#define FREELDR_BASE        HEX(F600)
+#define FREELDR_PE_BASE     HEX(10000)
+#define TEMPDATA16_BASE     HEX(7000)
+#define TEMPCODE16_BASE     HEX(7400)
+#define TEMPCODE_BASE       HEX(200000)
+#define MEMORY_MARGIN       HEX(88000) /* We need this much memory */
 
 #define BIOSCALLBUFSEGMENT (BIOSCALLBUFFER/16) /* Buffer to store temporary data for any Int386() call */
 #define BIOSCALLBUFOFFSET   HEX(0000) /* Buffer to store temporary data for any Int386() call */
@@ -49,6 +52,7 @@
 #define BSS_PnpResult            (BSS_START + 104)
 #define BSS_BootDrive            (BSS_START + 108) // 1 byte
 #define BSS_BootPartition        (BSS_START + 109) // 1 byte
+#define BSS_CurrentBaseAddress   (BSS_START + 110) // 4 bytes
 
 
 /* Realmode function IDs */
@@ -73,7 +77,9 @@
 #define RMODE_DS    HEX(20)    /* RMode data selector, base 0 limit 64k */
 //#else
 /* Long mode selectors */
-#define LMODE_CS HEX(10)
-#define LMODE_DS HEX(18)
-#define CMODE_CS HEX(30)
+#define LMODE_CS    HEX(10)
+#define LMODE_DS    HEX(18)
+#define L_RMODE_CS  HEX(20)
+#define L_RMODE_DS  HEX(28)
+#define CMODE_CS    HEX(30)
 //#endif