Fixed a bug in wrap_json_get_path (wrapper to json_get_path). Fixes #333

Added a unit test for this routine for all the options.

Author: jacobwilliams

src/json_value_module.F90

@@ -7176,19 +7176,20 @@ subroutine wrap_json_get_path(json, p, path, found, use_alt_array_tokens, path_s
     type(json_value),pointer,intent(in)               :: p     !! a JSON linked list object
     character(kind=CDK,len=:),allocatable,intent(out) :: path  !! path to the variable
     logical(LK),intent(out),optional                  :: found !! true if there were no problems
-    logical(LK),intent(in),optional :: use_alt_array_tokens    !! if true, then '()' are used for array elements
-                                                               !! otherwise, '[]' are used [default]
-    character(kind=CDK,len=1),intent(in),optional :: path_sep  !! character to use for path separator
-                                                               !! (default is '.')
+    logical(LK),intent(in),optional :: use_alt_array_tokens    !! if true, then '()' are used
+                                                               !! for array elements otherwise,
+                                                               !! '[]' are used [default]
+    character(kind=CDK,len=1),intent(in),optional :: path_sep  !! character to use for path
+                                                               !! separator (default is '.')
 
     character(kind=CK,len=:),allocatable :: ck_path  !! path to the variable
-    character(kind=CK,len=1) :: sep
-
-    ! from unicode:
-    sep = path_sep
 
     ! call the main routine:
-    call json_get_path(json,p,ck_path,found,use_alt_array_tokens,sep)
+    if (present(path_sep)) then
+        call json%get_path(p,ck_path,found,use_alt_array_tokens,to_unicode(path_sep))
+    else
+        call json%get_path(p,ck_path,found,use_alt_array_tokens)
+    end if
 
     ! from unicode:
     path = ck_path
@@ -7210,7 +7211,7 @@ function string_to_int(json,str) result(ival)
     character(kind=CK,len=*),intent(in) :: str
     integer(IK)                         :: ival
 
-    logical(LK) :: status_ok !! error flag
+    logical(LK) :: status_ok !! error flag for [[string_to_integer]]
 
     if (.not. json%exception_thrown) then
 
@@ -7243,7 +7244,7 @@ function string_to_dble(json,str) result(rval)
     character(kind=CK,len=*),intent(in) :: str   !! a string
     real(RK)                            :: rval  !! `str` converted to a double
 
-    logical(LK) :: status_ok  !! error flag
+    logical(LK) :: status_ok  !! error flag for [[string_to_real]]
 
     if (.not. json%exception_thrown) then
 

src/tests/jf_test_32.F90

@@ -0,0 +1,125 @@
+!*****************************************************************************************
+!>
+!  Module for the 32nd unit test.
+
+module jf_test_32_mod
+
+    use json_module, rk => json_rk, lk => json_lk, ik => json_ik, ck => json_ck, cdk => json_cdk
+    use, intrinsic :: iso_fortran_env , only: error_unit, output_unit
+
+    implicit none
+
+contains
+
+    subroutine test_32(error_cnt)
+
+    !! Test all the options and wrappers for [[json_get_path]].
+
+    implicit none
+
+    integer,intent(out) :: error_cnt
+    integer :: i !! counter
+    integer :: j !! counter
+    integer :: k !! counter
+    type(json_core) :: json
+    type(json_value),pointer :: p, p_var
+    character(kind=CK,len=:),allocatable :: path_ck
+    character(kind=CDK,len=:),allocatable :: path_cdk
+    logical(LK) :: use_alt_array_tokens
+    logical(LK) :: found
+
+    character(kind=CK,len=1),parameter  :: path_sep_ck  = CK_'.'
+    character(kind=CDK,len=1),parameter :: path_sep_cdk = CDK_'.'
+    character(kind=CK,len=*),parameter  :: json_string  = CK_'{ "struct": {"a": [1,2]} }'
+
+    error_cnt = 0
+
+    write(error_unit,'(A)') ''
+    write(error_unit,'(A)') '================================='
+    write(error_unit,'(A)') '   TEST 32'
+    write(error_unit,'(A)') '================================='
+    write(error_unit,'(A)') ''
+
+    call json%initialize()
+
+    call json%parse(p,json_string)
+    if (json%failed()) then
+        call json%print_error_message(error_unit)
+        error_cnt = error_cnt + 1
+    else
+
+        call json%get(p,CK_'struct.a(1)',p_var)
+
+        if (json%failed()) then
+            call json%print_error_message(error_unit)
+            error_cnt = error_cnt + 1
+        else
+
+            ! CK version:
+            do i=1,2
+                use_alt_array_tokens = i==1
+                do j=1,2
+                    if (j==1) then
+                        call json%get_path(p_var, path_ck, found, use_alt_array_tokens, path_sep_ck)
+                    else
+                        call json%get_path(p_var, path_ck, found, use_alt_array_tokens)
+                    end if
+                    if (json%failed()) then
+                        call json%print_error_message(error_unit)
+                        error_cnt = error_cnt + 1
+                    else
+                        write(error_unit,'(A)') path_ck
+                    end if
+                end do
+            end do
+
+            ! CDK version:
+            do i=1,2
+                use_alt_array_tokens = i==1
+                do j=1,2
+                    if (j==1) then
+                        call json%get_path(p_var, path_cdk, found, use_alt_array_tokens, path_sep_cdk)
+                    else
+                        call json%get_path(p_var, path_cdk, found, use_alt_array_tokens)
+                    end if
+                    if (json%failed()) then
+                        call json%print_error_message(error_unit)
+                        error_cnt = error_cnt + 1
+                    else
+                        write(error_unit,'(A)') path_cdk
+                    end if
+                end do
+            end do
+
+        end if
+
+    end if
+
+    if (.not. json%failed()) then
+        write(error_unit,*) ''
+        write(error_unit,*) 'Success!'
+    end if
+
+    call json%destroy(p)    ! free memory
+
+    end subroutine test_32
+
+end module jf_test_32_mod
+!*****************************************************************************************
+
+#ifndef INTERGATED_TESTS
+!*****************************************************************************************
+program jf_test_32
+
+    !! 32nd unit test.
+
+    use jf_test_32_mod , only: test_32
+    implicit none
+    integer :: n_errors
+    n_errors = 0
+    call test_32(n_errors)
+    if (n_errors /= 0) stop 1
+
+end program jf_test_32
+!*****************************************************************************************
+#endif