Find list of places where Location or Address or Maps Link is missing

[adarshmadrecha]

This is to identify bad data

[adarshmadrecha]

A Simple Query

PREFIX yq: <https://data.jain.wiki/entity/>
PREFIX yp: <https://data.jain.wiki/prop/direct/>

SELECT DISTINCT ?item ?itemLabel ?itemDescription WHERE {
  ?item yp:P1 ?p1Value .
  ?p1Value yp:P1 yq:Q8238 .
  
  # Where location (i.e. Lattitude and Longitude) not added.
  FILTER NOT EXISTS { ?item yp:P2 ?loc . }

  SERVICE wikibase:label { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
    ?item rdfs:label ?itemLabel .
    ?item schema:description ?itemDescription .
  }
}

[adarshmadrecha]

Complex Query with all the fields identified.

PREFIX yq: <https://data.jain.wiki/entity/>
PREFIX yp: <https://data.jain.wiki/prop/direct/>

SELECT DISTINCT ?item ?itemLabel ?itemDescription
       (IF(BOUND(?loc), "No", "Yes") AS ?missingLocation)
       (IF(BOUND(?address), "No", "Yes") AS ?missingAddress)
       (IF(BOUND(?gmapPlaceId), "No", "Yes") AS ?missingPlaceId)
       (IF(BOUND(?gmapLink), "No", "Yes") AS ?missingMapURL)
WHERE {
  ?item yp:P1 ?p1Value .
  ?p1Value yp:P1 yq:Q8238 .

  OPTIONAL { ?item yp:P2 ?loc . }       # Location
  OPTIONAL { ?item yp:P14 ?address . }  # Address
  OPTIONAL { ?item yp:P25 ?gmapPlaceId . }  # Google Maps Place ID
  OPTIONAL { ?item yp:P5 ?gmapLink . }  # Google Maps Link
  
  # Only include items where at least one property is missing
  FILTER(
    !BOUND(?loc) || !BOUND(?address) || !BOUND(?gmapPlaceId) || !BOUND(?gmapLink)
  )

  SERVICE wikibase:label { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
    ?item rdfs:label ?itemLabel .
    ?item schema:description ?itemDescription .
  }
}