Resyntax integration

[jackfirth]

In the long term, I would like to integrate Resyntax with this language server so that Racket users can get helpful suggestions for improving their code directly in the editor. I don't think Resyntax is stable enough for this yet, but it's a goal I'm working towards. Does this seem like a good idea to folks?

[jeapostrophe]

Absolutely. My hope is that the Racket LSP will provide all of the same kinds of things that other LSPs do and I think Resyntax is the thing in the Racket world that fits the mold.

[spdegabrielle]

@jackfirth I think resyntax might be stable enough 😁

[dannypsnl]

I make a small exploration

#lang racket/base
(require resyntax
         resyntax/default-recommendations
         resyntax/private/source
         rebellion/base/range
         rebellion/base/comparator
         rebellion/collection/range-set)

(define all-lines (range-set (unbounded-range #:comparator natural<=>)))

(resyntax-analyze
  (file-source "or.rkt")
  #:suite default-recommendations
  #:lines all-lines)

I think this is almost what LSP expecting, we only need to transform its output structures to LSP structures.

Update

refactoring result

The output of resyntax:

(refactoring-result #:line-replacement (line-replacement #:new-lines '#("(or 1 2 3)") #:original-lines '#("(or 1 (or 2 3))") #:start-line 3) #:message "Nested `or` expressions can be flattened into a single, equivalent `or` expression." #:rule-name 'nested-or-to-flat-or #:string-replacement (string-replacement #:contents (list (inserted-string "(or 1 2 3)")) #:new-end 24 #:new-span 10 #:original-end 29 #:original-span 15 #:required-length 29 #:start 14) #:syntax-replacement (syntax-replacement #:introduction-scope #<procedure:...and/syntax-local.rkt:148:2> #:new-syntax #<syntax:/Users/dannypsnl/Library/Racket/8.17/pkgs/resyntax/default-recommendations/boolean-shortcuts.rkt:31:2 (or 1 2 3)> #:original-syntax #<syntax:or.rkt:3:0 (or 1 (or 2 3))> #:source (file-source #<path:/Users/dannypsnl/repo/use-resyntax/or.rkt>)))

The structure of CodeAction

From current server source:

(CodeAction
            #:title "Add prefix `_` to ignore"
            #:kind "quickfix"
            #:diagnostics (list diag)
            #:isPreferred #f
            #:edit (WorkspaceEdit
                     #:changes
                     (hasheq (string->symbol (path->uri src-obj))
                             (list (TextEdit #:range (Range #:start (abs-pos->Pos doc-text start)
                                                            #:end (abs-pos->Pos doc-text start))
                                             #:newText "_")))))

cc @6cdh

[jackfirth]

I think you'll also have to output some Diagnostic messages too.

[6cdh]

Yes. We need to add a new function that process integration, send diagnostic and code action to diagnostic.rkt.

I also expanded @dannypsnl code a bit, it should print all information we need from Resyntax:

#lang racket/base

(require resyntax
         resyntax/default-recommendations
         resyntax/private/source
         resyntax/private/refactoring-result
         resyntax/private/string-replacement
         rebellion/base/range
         rebellion/base/comparator
         rebellion/collection/range-set
         racket/string)

(define all-lines (range-set (unbounded-range #:comparator natural<=>)))
(define file-src (file-source "or.rkt"))
(define result-set
  (resyntax-analyze
    file-src
    #:suite default-recommendations
    #:lines all-lines))

(define results (refactoring-result-set-results result-set))

(define (extract-result source result)
  (define sr (refactoring-result-string-replacement result))
  (define info
    (list
      (format "name: ~a" (refactoring-result-rule-name result))
      (format "kind: refactor")
      (format "message: ~a" (refactoring-result-message result))
      (let ([start (string-replacement-start sr)]
            [end (string-replacement-original-end sr)])
        (format "range: [~a, ~a)" start end))
      (format "newText: ~v" (string-replacement-render sr (source->string source)))))

  (displayln (string-join info "\n")))

(for ([result results])
  (extract-result file-src result)
  (newline))

updated: use string-replacement-render instead of string-replacement-contents.

I can implement it later.

Also, @jackfirth why (string-replacement-contents sr) returns a list of inserted string (not a single inserted string) and they all share the same start, original-span, original-end, ... properties. Is it safe to concat them?

[jackfirth]

@6cdh The string replacement doesn't return a single string because if one replacement wants to rewrite a b c to A b C, and another replacement wants to rewrite a b c to a B c, then by representing each replacement as a list of individual edits, it becomes possible to combine those two replacements into a single replacement that rewrites a b c into A B C. If the string replacements only contained a single new string inside them, it would be much more difficult to detect when two suggestions are non-overlapping and can be combined together.

This is mostly relevant to the Resyntax Autofixer, which wants to apply multiple suggestions at once to produce pull requests with commits that apply many suggestions together. For an editor, I assume we'd only be applying one fix at a time? Or at most, a handful of fixes of the same type in a single file?

[jackfirth]

If you want to get just the new text for a string replacement, use the string-replacement-render function. Given a string replacement and the full text of the file, that will return a single string representing everything the replacement will insert in its range. Here's some example code to work with:

(require resyntax/private/string-replacement)


; this replacement inserts "foo " and " bar" around the text in the range [6-10)
(define replacement
  (string-replacement #:start 6
                      #:end 10
                      #:contents
                      (list (inserted-string "foo ") (copied-string 6 10) (inserted-string " bar"))))

(string-replacement-render replacement "START blah END")
; returns "foo blah bar"

(string-apply-replacement "START blah END" replacement)
; returns "STRT foo blah bar END"

[6cdh]

Thank you. I've updated the code.

[jryans]

@6cdh Should this be closed now that #153 has merged, or is there more to do?

[dannypsnl]

I think this can be closed, the major target is complete and following issues are opened.

[jackfirth]

I agree. This is closed, in my view. Future improvements to the integration can be filed as separate feature requests.