Merge pull request #3 from MillerTechnologyPeru/trunk

Updated to Swift 5.7

Author: jeremy-prater

.gitignore

@@ -0,0 +1 @@
+*.swp

README.md

@@ -1,5 +1,5 @@
 # meta-swift
-Yocto meta-layer for swift-on-arm (Swift 5.1.2)
+Yocto meta-layer for swift-on-arm (Swift 5.7)
 
 # Usage
 
@@ -8,7 +8,7 @@ Add this meta layer to your project (refer to yocto user manual)
 Create a new swift application and include it in your yocto build as follows...
 
 ```
-DESCRIPTION = "My swift 5.1.3 app"
+DESCRIPTION = "My swift 5.7 app"
 LICENSE = "CLOSED"
 
 SRC_URI = "file://Sources/hello-world/main.swift \
@@ -20,8 +20,8 @@ inherit swift
 
 This does a few things, when you `inherit swift` meta-layer class, it will does the following...
 
-- Automatically download the x86_64 and ARMv7 swift 5.1.2 binaries and create a cross-compiling sys-root
-- Add an RDEPENDS_${PN} for `swift` which is the arm v7 runtime
+- Automatically download the x86_64 and ARMv7 swift 5.7 binaries and create a cross-compiling sys-root
+- Add an RDEPENDS_${PN} for `swift` which is the Armv7 runtime
 - Performs the required build steps
 
 # Deployment

classes/swift-cmake-base.bbclass

@@ -0,0 +1,107 @@
+inherit cmake
+
+DEPENDS_append += " swift-native libgcc gcc glibc "
+
+SWIFT_TARGET_ARCH = "${@oe.utils.conditional('TARGET_ARCH', 'arm', 'armv7', 'aarch64', d)}"
+SWIFT_TARGET_NAME = "${@oe.utils.conditional('TARGET_ARCH', 'arm', 'armv7-unknown-linux-gnueabihf', 'aarch64-unknown-linux-gnueabi', d)}"
+TARGET_CPU_NAME = "${@oe.utils.conditional('TARGET_ARCH', 'arm', 'armv7-a', 'aarch64', d)}"
+
+HOST_CC_ARCH_prepend = "-target ${SWIFT_TARGET_NAME}"
+
+################################################################################
+# NOTE: The host running bitbake must have lld available and the following     #
+# must be added to the local.conf file:                                        #
+#                                                                              #
+# HOSTTOOLS += "ld.lld"                                                        #
+#                                                                              #
+################################################################################
+
+# Use lld (see note above)
+TARGET_LDFLAGS += "-fuse-ld=lld"
+
+# Add build-id to generated binaries
+TARGET_LDFLAGS += "-Xlinker --build-id=sha1"
+
+# Use Apple's provided clang (it understands Apple's custom compiler flags)
+# Made available via swift-native package.
+OECMAKE_C_COMPILER = "clang"
+OECMAKE_CXX_COMPILER = "clang++"
+
+# Point clang to where the C++ runtime is for our target arch
+RUNTIME_FLAGS = "-w -fuse-ld=lld -B${STAGING_DIR_TARGET}/usr/lib/${TARGET_SYS}/current"
+TARGET_LDFLAGS += "-w -fuse-ld=lld -L${STAGING_DIR_TARGET}/usr/lib/${TARGET_SYS}/current"
+
+EXTRA_INCLUDE_FLAGS ?= ""
+OECMAKE_C_FLAGS += "${RUNTIME_FLAGS} ${EXTRA_INCLUDE_FLAGS}"
+OECMAKE_CXX_FLAGS += "${RUNTIME_FLAGS} ${EXTRA_INCLUDE_FLAGS}"
+OECMAKE_ASM_FLAGS += "${RUNTIME_FLAGS} ${EXTRA_INCLUDE_FLAGS}"
+
+BUILD_MODE = "${@['release', 'debug'][d.getVar('DEBUG_BUILD') == '1']}"
+
+# Additional parameters to pass to swiftc
+EXTRA_SWIFTC_FLAGS ??= ""
+
+SWIFT_FLAGS = "-target ${SWIFT_TARGET_NAME} -use-ld=lld \
+-resource-dir ${STAGING_DIR_TARGET}/usr/lib/swift \
+-module-cache-path ${B}/${BUILD_MODE}/ModuleCache \
+-Xclang-linker -B${STAGING_DIR_TARGET}/usr/lib/${TARGET_SYS}/current \
+-Xclang-linker -B${STAGING_DIR_TARGET}/usr/lib \
+-Xcc -I${STAGING_DIR_NATIVE}/usr/lib/${TARGET_SYS}/gcc/${TARGET_SYS}/current/include \
+-Xcc -I${STAGING_DIR_NATIVE}/usr/lib/${TARGET_SYS}/gcc/${TARGET_SYS}/current/include-fixed \
+-L${STAGING_DIR_TARGET} \
+-L${STAGING_DIR_TARGET}/lib \
+-L${STAGING_DIR_TARGET}/usr/lib \
+-L${STAGING_DIR_TARGET}/usr/lib/swift \
+-L${STAGING_DIR_TARGET}/usr/lib/swift/linux \
+-L${STAGING_DIR_TARGET}/usr/lib/${TARGET_SYS}/current \
+-sdk ${STAGING_DIR_TARGET} \
+${EXTRA_SWIFTC_FLAGS} \
+"
+
+HOST_LLVM_PATH = "${STAGING_DIR_NATIVE}/opt/usr/lib/llvm-swift"
+EXTRA_OECMAKE += '-DCMAKE_Swift_FLAGS="${SWIFT_FLAGS}"'
+EXTRA_OECMAKE += " -DSWIFT_USE_LINKER=lld"
+EXTRA_OECMAKE += " -DLLVM_USE_LINKER=lld"
+EXTRA_OECMAKE += " -DLLVM_DIR=${HOST_LLVM_PATH}/lib/cmake/llvm"
+EXTRA_OECMAKE += " -DLLVM_BUILD_LIBRARY_DIR=${HOST_LLVM_PATH}"
+
+EXTRANATIVEPATH += "swift-tools"
+
+################################################################################
+# Create symlinks to the directories containing the gcc version specific       #
+# headers, objects and libraries we need.                                      #
+#                                                                              #
+# We can't just use ${GCC_VERSION} in the path variables in the recipe         #
+# because bitbake parses and expands variables before GCC_VERSION is           #
+# defined. GCC_VERSION cannot be defined until the sysroot is populated        #
+# because we inspect the sysroot to determine the GCC version number string.   #
+# If there was an env or bitbake var with the GCC version, we could use that   #
+# and avoid all of this but the closest thing we have access to is             #
+# ${GCCVERSION} which yields and incomplete version number (ex: "9.%").        #
+#                                                                              #
+# Also there is some suspicion that these path variables and these symlinks    #
+# may not be necessary if the --gcc-toolchain clang flag was used. But that    #
+# is an unproven theory.                                                       #
+################################################################################
+
+do_create_gcc_version_symlinks() {
+    GCC_VERSION=`basename ${STAGING_DIR_TARGET}/usr/include/c++/*`
+
+    if [ ! -L "${STAGING_DIR_TARGET}/usr/lib/${TARGET_SYS}/current" ]; then
+        cd ${STAGING_DIR_TARGET}/usr/lib/${TARGET_SYS}
+        ln -s -r ${GCC_VERSION} current
+    fi
+
+    if [ ! -L "${STAGING_DIR_TARGET}/usr/include/c++/current" ]; then
+        cd ${STAGING_DIR_TARGET}/usr/include/c++
+        ln -s -r ${GCC_VERSION} current
+    fi
+
+    if [ ! -L "${STAGING_DIR_NATIVE}/usr/lib/${TARGET_SYS}/gcc/${TARGET_SYS}/current" ]; then
+        cd ${STAGING_DIR_NATIVE}/usr/lib/${TARGET_SYS}/gcc/${TARGET_SYS}
+        ln -s -r ${GCC_VERSION} current
+    fi
+}
+
+addtask do_create_gcc_version_symlinks after do_prepare_recipe_sysroot before do_configure
+

classes/swift-cmake.bbclass

@@ -0,0 +1,5 @@
+inherit swift-cmake-base
+
+DEPENDS_append += " swift-stdlib libdispatch libfoundation "
+
+TARGET_LDFLAGS += "-L${STAGING_DIR_TARGET}/usr/lib/swift/linux"

classes/swift.bbclass

@@ -1,61 +1,95 @@
 
-DEPENDS_prepend += "swift-native swift glibc gcc libgcc "
-RDEPENDS_${PN} += " swift "
+DEPENDS += "swift-native glibc gcc libgcc swift-stdlib libdispatch libfoundation"
+
+# Default build directory for SPM is "./.build"
+# (see 'swift [build|package|run|test] --help')
+#
+# We can allow for this to be changed by changing ${B} but one must be careful to also set
+# "--build-path ${B}" for _ALL_ invocations of SPM within a recipe.
+B ?= "${S}/.build"
+EXTERNALSRC_BUILD ?= "${EXTERNALSRC}/.build"
+
+BUILD_MODE = "${@['release', 'debug'][d.getVar('DEBUG_BUILD') == '1']}"
 
 # Additional parameters to pass to SPM
 EXTRA_OESWIFT ?= ""
 
+SWIFT_TARGET_NAME = "${@oe.utils.conditional('TARGET_ARCH', 'arm', 'armv7-unknown-linux-gnueabihf', 'aarch64-unknown-linux-gnueabi', d)}"
+
+# Workaround complex macros that cannot be automatically imported by Swift.
+# https://developer.apple.com/documentation/swift/imported_c_and_objective-c_apis/using_imported_c_macros_in_swift
+#
+# Seems that SO_RCVTIMEO and SO_SNDTIMEO definitions aren't working because they are expressions
+# and not simple constants.
+#
+# This could be improved to replace just the specific lines that need fixing rather than rewriting
+# the entire file.
 def fix_socket_header(filename):
-    with open(filename, 'r') as f:
-        lines = f.readlines() 
+  with open(filename, 'r') as f:
+    lines = f.readlines()
 
-    os.remove(filename)
+  os.remove(filename)
+
+  with open(filename, 'w') as f:
+    for line in lines:
+      if line.startswith('#define SO_RCVTIMEO ') and ("SO_RCVTIMEO_OLD" in line) and ("?" in line):
+        f.write('#define SO_RCVTIMEO    SO_RCVTIMEO_OLD\n')
+      elif line.startswith('#define SO_SNDTIMEO ') and ("SO_SNDTIMEO_OLD" in line) and ("?" in line):
+        f.write('#define SO_SNDTIMEO    SO_SNDTIMEO_OLD\n')
+      else:
+        f.write(line)
 
-    with open(filename, 'w') as f:
-        for line in lines:
-            if line.startswith('#define SO_RCVTIMEO ') and ("SO_RCVTIMEO_OLD" in line) and ("?" in line):
-                f.write('#define SO_RCVTIMEO		SO_RCVTIMEO_OLD\n')
-            elif line.startswith('#define SO_SNDTIMEO ') and ("SO_SNDTIMEO_OLD" in line) and ("?" in line):
-                f.write('#define SO_SNDTIMEO		SO_SNDTIMEO_OLD\n')
-            else:
-                f.write(line)
 
 python swift_do_configure() {
     import os
     import os.path
     import shutil
+
     workdir = d.getVar("WORKDIR", True)
     recipe_sysroot = d.getVar("STAGING_DIR_TARGET", True)
-    
-    #socket.h workaround. Seems that SO_RCVTIMEO and SO_SNDTIMEO definitions using ? aren't working
+
+    # Workaround complex macros that cannot be automatically imported by Swift.
+    # https://developer.apple.com/documentation/swift/imported_c_and_objective-c_apis/using_imported_c_macros_in_swift
+    #
+    # Seems that SO_RCVTIMEO and SO_SNDTIMEO definitions aren't working because they are expressions
+    # and not simple constants.
     socket_header = recipe_sysroot + "/usr/include/asm-generic/socket.h"
     fix_socket_header(socket_header)
 
+    # Detect the version of the C++ runtime
+    # This is used to determine necessary include paths
     cxx_include_base = recipe_sysroot + "/usr/include/c++"
     cxx_include_list = os.listdir(cxx_include_base)
     if len(cxx_include_list) != 1:
         bb.fatal("swift bbclass detected more than one c++ runtime, unable to determine which one to use")
     cxx_version = cxx_include_list[0]
-    
+
     d.setVar('SWIFT_CXX_VERSION', cxx_version)
 
     swift_destination_template = """{
         "version":1,
         "sdk":"${STAGING_DIR_TARGET}/",
-        "toolchain-bin-dir":"${STAGING_DIR_NATIVE}/opt/swift-arm/usr/bin",
-        "target":"armv7-unknown-linux-gnueabihf",
+        "toolchain-bin-dir":"${STAGING_DIR_NATIVE}/opt/usr/bin",
+        "target":"${SWIFT_TARGET_NAME}",
         "dynamic-library-extension":"so",
-        "extra-cc-flags":[ 
+        "extra-cc-flags":[
             "-fPIC",
             "-I${STAGING_DIR_TARGET}/usr/include/c++/${SWIFT_CXX_VERSION}",
             "-I${STAGING_DIR_TARGET}/usr/include/c++/${SWIFT_CXX_VERSION}/${TARGET_SYS}",
+            "-I${STAGING_DIR_NATIVE}/opt/usr/lib/clang/13.0.0/include",
+            "-I${STAGING_DIR_NATIVE}/opt/usr/lib/clang/13.0.0/include-fixed"
         ],
-        "extra-swiftc-flags":[ 
+        "extra-swiftc-flags":[
             "-target",
-            "armv7-unknown-linux-gnueabihf",
+            "${SWIFT_TARGET_NAME}",
             "-use-ld=lld",
             "-tools-directory",
-            "/usr/bin",
+            "${STAGING_DIR_NATIVE}/opt/usr/bin",
+
+            "-Xlinker", "-rpath", "-Xlinker", "/usr/lib/swift/linux",
+
+            "-Xlinker",
+            "-L${STAGING_DIR_TARGET}",
 
             "-Xlinker",
             "-L${STAGING_DIR_TARGET}/lib",
@@ -68,29 +102,41 @@ python swift_do_configure() {
 
             "-Xlinker",
             "-L${STAGING_DIR_TARGET}/usr/lib/${TARGET_SYS}/${SWIFT_CXX_VERSION}",
-            
+
+            "-Xlinker",
+            "--build-id=sha1",
+
+            "-I${STAGING_INCDIR}",
             "-I${STAGING_DIR_TARGET}/usr/include/c++/${SWIFT_CXX_VERSION}",
-            "-I${STAGING_DIR_TARGET}/usr/include/c++/${SWIFT_CXX_VERSION}/${TARGET_SYS}"
+            "-I${STAGING_DIR_TARGET}/usr/include/c++/${SWIFT_CXX_VERSION}/${TARGET_SYS}",
+            "-I${STAGING_DIR_NATIVE}/opt/usr/lib/clang/13.0.0/include",
+            "-I${STAGING_DIR_NATIVE}/opt/usr/lib/clang/13.0.0/include-fixed",
+
+            "-resource-dir", "${STAGING_DIR_TARGET}/usr/lib/swift",
+            "-module-cache-path", "${B}/${BUILD_MODE}/ModuleCache",
+            "-Xclang-linker", "-B${STAGING_DIR_TARGET}/usr/lib/${TARGET_SYS}/${SWIFT_CXX_VERSION}",
+            "-Xclang-linker", "-B${STAGING_DIR_TARGET}/usr/lib",
+
+            "-sdk", "${STAGING_DIR_TARGET}"
         ],
-        "extra-cpp-flags":[ 
+        "extra-cpp-flags":[
             "-lstdc++"
         ]
     }"""
 
     swift_destination =  d.expand(swift_destination_template)
 
     d.delVar("SWIFT_CXX_VERSION")
-    
+
     configJSON = open(workdir + "/destination.json", "w")
     configJSON.write(swift_destination)
     configJSON.close()
 }
 
 swift_do_compile()  {
-    #Linker isn't finding crtbeginS.o and crtendS.o under ${TARGET_SYS} path
-    cp -r ${WORKDIR}/recipe-sysroot/usr/lib/${TARGET_SYS}/*/* ${WORKDIR}/recipe-sysroot/usr/lib
-	cd ${S}
-    ${WORKDIR}/recipe-sysroot-native/usr/bin/swift build -v -c release --destination ${WORKDIR}/destination.json ${EXTRA_OESWIFT}
+    swift build --package-path ${S} --build-path ${B} --skip-update -c ${BUILD_MODE} --destination ${WORKDIR}/destination.json ${EXTRA_OESWIFT}
 }
 
 EXPORT_FUNCTIONS do_configure do_compile
+
+EXTRANATIVEPATH += "swift-tools"

conf/layer.conf

@@ -8,3 +8,5 @@ BBFILES += "${LAYERDIR}/recipes*/*/*.bb \
 BBFILE_COLLECTIONS += "swift-layer"
 BBFILE_PATTERN_swift-layer := "^${LAYERDIR}/"
 BBFILE_PRIORITY_swift-layer = "7"
+
+LAYERSERIES_COMPAT_swift-layer = "dunfell"

recipes-devtools/swift/libdispatch.bb

@@ -0,0 +1,36 @@
+
+SUMMARY = "Libdispatch"
+HOMEPAGE = "https://github.com/apple/swift-corelibs-libdispatch"
+
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=1cd73afe3fb82e8d5c899b9d926451d0"
+
+require swift-version.inc
+PV = "${SWIFT_VERSION}"
+
+SRC_URI = "git://github.com/apple/swift-corelibs-libdispatch.git;protocol=https;tag=swift-${PV}-RELEASE;nobranch=1"
+
+DEPENDS = "swift-stdlib ncurses"
+
+S = "${WORKDIR}/git"
+
+inherit swift-cmake-base
+
+TARGET_LDFLAGS += "-L${STAGING_DIR_TARGET}/usr/lib/swift/linux"
+
+# Enable Swift parts
+EXTRA_OECMAKE += "-DENABLE_SWIFT=YES"
+
+# Ensure the right CPU is targeted
+cmake_do_generate_toolchain_file_append() {
+    sed -i 's/set([ ]*CMAKE_SYSTEM_PROCESSOR .*[ ]*)/set(CMAKE_SYSTEM_PROCESSOR ${TARGET_CPU_NAME})/' ${WORKDIR}/toolchain.cmake
+}
+
+do_install_append() {
+    # Copy cmake build modules
+    mkdir -p ${D}${libdir}/swift/dispatch/cmake
+    cp -rf ${WORKDIR}/build/cmake/modules/* ${D}${libdir}/swift/dispatch/cmake/
+}
+
+FILES_${PN} = "${libdir}/swift/*"
+INSANE_SKIP_${PN} = "file-rdeps"