|
| 1 | +#include "..\script_component.hpp" |
| 2 | +/* |
| 3 | + * Author: johnb43 |
| 4 | + * Makes all interaction menus for all explosive types for a unit. |
| 5 | + * |
| 6 | + * Arguments: |
| 7 | + * 0: Unit <OBJECT> |
| 8 | + * |
| 9 | + * Return Value: |
| 10 | + * Modified interaction menu <ARRAY> |
| 11 | + * |
| 12 | + * Example: |
| 13 | + * player call AIMEE_inventory_fnc_explosiveMenus |
| 14 | + * |
| 15 | + * Public: No |
| 16 | + */ |
| 17 | + |
| 18 | + |
| 19 | +// Returns case correct magazines |
| 20 | +private _magazines = (magazines [_this, false]) call CBA_fnc_getArrayElements; |
| 21 | + |
| 22 | +if (_magazines isEqualTo []) exitWith {[]}; |
| 23 | + |
| 24 | +private _explosives = uiNamespace getVariable ["ace_arsenal_putCache", createHashMap]; |
| 25 | +private _class = ""; |
| 26 | +private _config = configNull; |
| 27 | +private _cfgMagazines = configFile >> "CfgMagazines"; |
| 28 | +private _menus = []; |
| 29 | + |
| 30 | +for "_i" from 0 to (count _magazines) - 2 step 2 do { |
| 31 | + _class = _magazines select _i; |
| 32 | + |
| 33 | + // Find compatible magazines |
| 34 | + if (_class in _explosives) then { |
| 35 | + _config = _cfgMagazines >> _class; |
| 36 | + |
| 37 | + _menus pushBack [ |
| 38 | + [ |
| 39 | + format [QGVAR(explosive_%1), _class], // Action name |
| 40 | + format [LQSTRING(str_action_putbomb), getText (_config >> "displayName"), _magazines select (_i + 1)], // Name of action shown in menu |
| 41 | + getText (_config >> "picture"), // Icon |
| 42 | + { |
| 43 | + _player playAction "PutDown"; |
| 44 | + |
| 45 | + [{ |
| 46 | + params ["_unit", "_mineData"]; |
| 47 | + |
| 48 | + // If magazine couldn't be removed, it means it was deleted before; Don't continue |
| 49 | + if !([_unit, _mineData select 0] call CBA_fnc_removeMagazine) exitWith {}; |
| 50 | + |
| 51 | + private _mine = createVehicle [_mineData select 1, _unit, [], 0]; |
| 52 | + _mine setDir (getDir _unit); |
| 53 | + _mine setPosWorld getPosWorld _mine; // mine direction needs to be synchronised |
| 54 | + |
| 55 | + _unit addOwnedMine _mine; |
| 56 | + (side group _unit) revealMine _mine; |
| 57 | + }, [_player, _this select 2], 1] call CBA_fnc_waitAndExecute; |
| 58 | + }, // Statement |
| 59 | + {true}, // Condition |
| 60 | + nil, |
| 61 | + [_class, getText (_config >> "ammo")] // Action parameters |
| 62 | + ] call ace_interact_menu_fnc_createAction, |
| 63 | + [], |
| 64 | + _this |
| 65 | + ]; |
| 66 | + }; |
| 67 | +}; |
| 68 | + |
| 69 | +_menus |
0 commit comments