|
| 1 | +/****************************************************************************************** |
| 2 | +* This file is part of the Apex UUID project, released under the MIT License. * |
| 3 | +* See LICENSE file or go to https://github.com/jongpie/ApexUuid for full license details. * |
| 4 | +******************************************************************************************/ |
| 5 | +public without sharing class Uuid { |
| 6 | + |
| 7 | + private static final Integer HEX_BASE = HEX_CHARACTERS.length(); |
| 8 | + private static final String HEX_CHARACTERS = '0123456789abcdef'; |
| 9 | + private static final String HEX_PREFIX = '0x'; |
| 10 | + private static final List<String> HEX_CHARACTER_LIST = HEX_CHARACTERS.split(''); |
| 11 | + private static final Integer UUID_V4_LENGTH = 36; |
| 12 | + private static final String UUID_V4_REGEX = '[0-9a-f]{8}-[0-9a-f]{4}-4[0-9a-f]{3}-[89ab][0-9a-f]{3}-[0-9a-f]{12}'; |
| 13 | + |
| 14 | + public static String formatValue(String unformattedValue) { |
| 15 | + final String invalidValueError = unformattedValue + ' is not a valid UUID value'; |
| 16 | + |
| 17 | + // Remove any non-alphanumeric characters |
| 18 | + unformattedValue = unformattedValue.replaceAll('[^a-zA-Z0-9]', ''); |
| 19 | + |
| 20 | + // If the unformatted value isn't even the right length to be valid, then throw an exception |
| 21 | + // Subtract 4 because the UUID_V4_LENGTH includes 4 '-' characters in the UUID pattern |
| 22 | + if(unformattedValue.length() != (UUID_V4_LENGTH - 4)) throw new UuidException(invalidValueError); |
| 23 | + |
| 24 | + // UUID Pattern: 8-4-4-4-12 |
| 25 | + String formattedValue = unformattedValue.substring(0, 8) |
| 26 | + + '-' + unformattedValue.substring(8, 12) |
| 27 | + + '-' + unformattedValue.substring(12, 16) |
| 28 | + + '-' + unformattedValue.substring(16, 20) |
| 29 | + + '-' + unformattedValue.substring(20); |
| 30 | + |
| 31 | + formattedValue = formattedValue.toLowerCase(); |
| 32 | + |
| 33 | + if(!Uuid.isValid(formattedValue)) throw new UuidException(invalidValueError); |
| 34 | + |
| 35 | + return formattedValue; |
| 36 | + } |
| 37 | + |
| 38 | + public static Boolean isValid(String uuidValue) { |
| 39 | + if(String.isBlank(uuidValue)) return false; |
| 40 | + if(uuidValue.length() != UUID_V4_LENGTH) return false; |
| 41 | + |
| 42 | + Pattern uuidPattern = Pattern.compile(UUID_V4_REGEX.toLowerCase()); |
| 43 | + Matcher uuidMatcher = uuidPattern.matcher(uuidValue.toLowerCase()); |
| 44 | + |
| 45 | + return uuidMatcher.matches(); |
| 46 | + } |
| 47 | + |
| 48 | + public static Uuid valueOf(String uuidValue) { |
| 49 | + return new Uuid(uuidValue); |
| 50 | + } |
| 51 | + |
| 52 | + private final String value; |
| 53 | + |
| 54 | + public Uuid() { |
| 55 | + this.value = this.generateValue(); |
| 56 | + } |
| 57 | + |
| 58 | + private Uuid(String uuidValue) { |
| 59 | + this.value = Uuid.formatValue(uuidValue); |
| 60 | + } |
| 61 | + |
| 62 | + public String getValue() { |
| 63 | + return this.value; |
| 64 | + } |
| 65 | + |
| 66 | + private String generateValue() { |
| 67 | + String hexValue = EncodingUtil.convertToHex(Crypto.generateAesKey(128)); |
| 68 | + |
| 69 | + // Version Calculation: (i & 0x0f) | 0x40 |
| 70 | + // Version Format: Always begins with 4 |
| 71 | + String versionShiftedHexBits = this.getShiftedHexBits(hexValue.substring(14, 16), this.convertHexToInteger('0x0f'), this.convertHexToInteger('0x40')); |
| 72 | + |
| 73 | + // Variant Calculation: (i & 0x3f) | 0x80 |
| 74 | + // Variant Format: Always begins with 8, 9, A or B |
| 75 | + String variantShiftedHexBits = this.getShiftedHexBits(hexValue.substring(18, 20), this.convertHexToInteger('0x3f'), this.convertHexToInteger('0x80')); |
| 76 | + |
| 77 | + String uuidValue = hexValue.substring(0, 8) // time-low |
| 78 | + + hexValue.substring(8, 12) // time-mid |
| 79 | + + versionShiftedHexBits + hexValue.substring(14, 16) // time-high-and-version |
| 80 | + + variantShiftedHexBits + hexValue.substring(18, 20) // clock-seq-and-reserved + clock-seq-low |
| 81 | + + hexValue.substring(20); // node |
| 82 | + |
| 83 | + return Uuid.formatValue(uuidValue); |
| 84 | + } |
| 85 | + |
| 86 | + private String getShiftedHexBits(String hexSubstring, Integer lowerThreshold, Integer upperThreshold) { |
| 87 | + Integer shiftedIntegerBits = (this.convertHexToInteger(hexSubstring) & lowerThreshold) | upperThreshold; |
| 88 | + return this.convertIntegerToHex(shiftedIntegerBits); |
| 89 | + } |
| 90 | + |
| 91 | + private Integer convertHexToInteger(String hexValue) { |
| 92 | + hexValue = hexValue.toLowerCase(); |
| 93 | + |
| 94 | + if(hexValue.startsWith(HEX_PREFIX)) hexValue = hexValue.substringAfter(HEX_PREFIX); |
| 95 | + |
| 96 | + Integer integerValue = 0; |
| 97 | + for(String hexCharacter : hexValue.split('')) { |
| 98 | + Integer hexCharacterIndex = HEX_CHARACTERS.indexOf(hexCharacter); |
| 99 | + |
| 100 | + integerValue = HEX_BASE * integerValue + hexCharacterIndex; |
| 101 | + } |
| 102 | + return integerValue; |
| 103 | + } |
| 104 | + |
| 105 | + private String convertIntegerToHex(Integer integerValue) { |
| 106 | + String hexValue = ''; |
| 107 | + while(integerValue > 0) { |
| 108 | + Integer hexCharacterIndex = Math.mod(integerValue, HEX_BASE); |
| 109 | + |
| 110 | + hexValue = HEX_CHARACTER_LIST[hexCharacterIndex] + hexValue; |
| 111 | + integerValue = integerValue / HEX_BASE; |
| 112 | + } |
| 113 | + return hexValue; |
| 114 | + } |
| 115 | + |
| 116 | + private class UuidException extends Exception {} |
| 117 | + |
| 118 | +} |
0 commit comments