IsEmptyArray to check an Object array fails

[josef-poetzl]

Test:

Dim S() As String
Dim O() As Object

Debug.Print "S: "; IsEmptyArray(S), "O: "; IsEmptyArray(O)

Result:
S: True O: False

Why: IsArray does something to the array so that LBound returns the value 0 and UBound returns the value -1.

Check (works only for arrays with references):

Dim O() As Object
IsArray O ' without call of IsArray => Error
Debug.Print "LBound(O)="; LBound(O), "UBound(O)="; UBound(O)

IsEmptyArray code from VCS:

'---------------------------------------------------------------------------------------
' Procedure : IsEmptyArray
' Author    : Adam Waller
' Date      : 5/13/2023
' Purpose   : Return true if the passed array is empty, meaning it does not have any
'           : indexes defined. (Unfortunately we have to use on error resume next to
'           : trap the error when accessing the index.)
'---------------------------------------------------------------------------------------
'
Public Function IsEmptyArray(varArray As Variant) As Boolean

    ' Use an arbitrary number extremly unlikely to collide with an existing index
    Const clngTest As Long = -2147483646

    Dim lngLowBound As Long

    ' Exit (returning False) if we are not dealing with an array variable
    If Not IsArray(varArray) Then Exit Function

    LogUnhandledErrors
    On Error Resume Next

    ' Attempt to read the lower bound of the array
    lngLowBound = clngTest
    lngLowBound = LBound(varArray)

    ' Clear any error thrown while attempting to read LBound()
    If Err Then Err.Clear

    ' If the above assignment fails, we have an empty array
    IsEmptyArray = (lngLowBound = clngTest)

End Function

Possible fIx:

Public Function IsEmptyArray(varArray As Variant) As Boolean

    Dim lngLowBound As Long
    Dim lngUpBound As Long

    ' Exit (returning False) if we are not dealing with an array variable
    If Not IsArray(varArray) Then Exit Function

    LogUnhandledErrors
    On Error Resume Next

    ' Attempt to read the lower bound of the array
    lngLowBound = 0
    lngUpBound = -1
    lngLowBound = LBound(varArray)
    lngUpBound = UBound(varArray)

    ' Clear any error thrown while attempting to read LBound()
    If Err Then Err.Clear

    ' If the above assignment fails, we have an empty array
    IsEmptyArray = (lngUpBound < lngLowBound)

End Function

[joyfullservice]

That is a very interesting side effect! I like your approach for resolving this, and have incorporated this change into the add-in.