Add highlights test and fix #431

Author: krassowski

atest/05_Features/Highlights.robot

@@ -0,0 +1,61 @@
+*** Settings ***
+Suite Setup       Setup Suite For Screenshots    highlights
+Test Setup        Setup Highlights Test
+Test Teardown     Clean Up After Working With File    Highlights.ipynb
+Force Tags        feature:highlights
+Resource          ../Keywords.robot
+
+*** Test Cases ***
+# cursor is symbolized by pipe (|), for example when
+# it is at the end of line, after `1` in `test = 1`
+# it is presented as: `test = 1|`
+Highlights work at the start of a token
+    Enter Cell Editor    1    line=1
+    Press Keys    None    END    # cursor to the end of first line (`test = 1|`)
+    Should Not Highlight Any Tokens
+    Press Keys    None    HOME    # cursor before the token (`|test = 1`)
+    Should Highlight Token    test
+    Should Not Highlight Token    gist
+
+Highlights work at the end of a token
+    Enter Cell Editor    1    line=1
+    Press Keys    None    END    # cursor to the end of first line (`test = 1|`)
+    Press Keys    None    DOWN    # cursor to the end of the token in second line (`test`)
+    Should Highlight Token    test
+    Should Not Highlight Token    gist
+
+Highlights are changed when moving cursor between cells
+    [Documentation]    GH431
+    Enter Cell Editor    1    line=2
+    Press Keys    None    END    # cursor after the token in second line (`test|`)
+    Should Highlight Token    test
+    Should Not Highlight Token    gist
+    Press Keys    None    DOWN    # cursor to next cell, which is empty
+    Should Not Highlight Any Tokens
+    Press Keys    None    DOWN    # cursor to third cell (`|gist = 1`)
+    Should Highlight Token    gist
+    Press Keys    None    DOWN    # cursor to third cell, second line (`|test `)
+    Should Highlight Token    test
+
+Highlights are added after typing
+    Enter Cell Editor    1    line=2
+    Should Highlight Token    test
+    Press Keys    None    a
+    Should Highlight Token    testa
+
+*** Keywords ***
+Should Not Highlight Any Tokens
+    Page Should Not Contain    css:.cm-lsp-highlight
+
+Should Highlight Token
+    [Arguments]    ${token}    ${timeout}=10s
+    ${token_element}    Set Variable    xpath://span[contains(@class, 'cm-lsp-highlight')][contains(text(), '${token}')]
+    Wait Until Page Contains Element    ${token_element}    timeout=${timeout}
+
+Should Not Highlight Token
+    [Arguments]    ${token}    ${timeout}=10s
+    ${token_element}    Set Variable    xpath://span[contains(@class, 'cm-lsp-highlight')][contains(text(), '${token}')]
+    Wait Until Page Does Not Contain Element    ${token_element}    timeout=${timeout}
+
+Setup Highlights Test
+    Setup Notebook    Python    Highlights.ipynb

atest/examples/Highlights.ipynb

@@ -0,0 +1,54 @@
+{
+ "cells": [
+  {
+   "cell_type": "code",
+   "execution_count": null,
+   "metadata": {},
+   "outputs": [],
+   "source": [
+    "test = 1\n",
+    "test"
+   ]
+  },
+  {
+   "cell_type": "code",
+   "execution_count": null,
+   "metadata": {},
+   "outputs": [],
+   "source": []
+  },
+  {
+   "cell_type": "code",
+   "execution_count": null,
+   "metadata": {},
+   "outputs": [],
+   "source": [
+    "gist = 1\n",
+    "test\n",
+    "gist\n",
+    "test"
+   ]
+  }
+ ],
+ "metadata": {
+  "kernelspec": {
+   "display_name": "Python 3",
+   "language": "python",
+   "name": "python3"
+  },
+  "language_info": {
+   "codemirror_mode": {
+    "name": "ipython",
+    "version": 3
+   },
+   "file_extension": ".py",
+   "mimetype": "text/x-python",
+   "name": "python",
+   "nbconvert_exporter": "python",
+   "pygments_lexer": "ipython3",
+   "version": "3.7.5"
+  }
+ },
+ "nbformat": 4,
+ "nbformat_minor": 4
+}

packages/jupyterlab-lsp/src/features/highlights.ts

@@ -65,6 +65,8 @@ export class HighlightsCM extends CodeMirrorIntegration {
       this.debounced_get_highlight = this.create_debouncer();
     });
     this.editor_handlers.set('cursorActivity', this.onCursorActivity);
+    this.editor_handlers.set('blur', this.onCursorActivity);
+    this.editor_handlers.set('focus', this.onCursorActivity);
     super.register();
   }
 
@@ -136,9 +138,17 @@ export class HighlightsCM extends CodeMirrorIntegration {
 
     const token = this.virtual_editor.get_token_at(root_position);
 
-    // if token has not changed, no need to update highlight
-    if (this.last_token && token.value === this.last_token.value) {
-      console.log('LSP: not requesting highlights (token did not change)');
+    // if token has not changed, no need to update highlight, unless it is an empty token
+    // which would indicate that the cursor is at the first character
+    if (
+      this.last_token &&
+      token.value === this.last_token.value &&
+      token.value !== ''
+    ) {
+      console.log(
+        'LSP: not requesting highlights (token did not change)',
+        token
+      );
       return;
     }