Custom command with preselected tools

[witek]

I would like to create a custom command which does not pop up the transient menu. Instead it uses a preselected system prompt and uses preselected tools.

On the wiki page about custom commands there is no hint how to select tools. Is this even supported in gptel-request?

Or is there a way to invoke gptel-send with predefined parameters?

[witek]

I came up with this "solution":

(defun my/ai-emacs-do ()
    "Execute the users request in emacs"
    (interactive)

    ;; tool
    (let ((emacs-eval-tool
           (gptel-make-tool
            :name "emacs_eval"
            :function (lambda (code)
                        (condition-case err
                            (let ((result (eval (read code))))
                              (format "Evaluation result: %S" result))
                          (error (format "Error: %s" (error-message-string err)))))
            :description "Evaluate Emacs Lisp code and return the result"
            :args '((:name "code"
                           :type "string"
                           :description "Emacs Lisp code to evaluate")))))
        
      (setq-local gptel-tools (list emacs-eval-tool))
      (setq-local gptel-use-tools t)
      )

    ;; system prompt
    (setq-local gptel--system-message "You are a helpful assistant living inside Emacs.
  Use the emacs_eval tool to fullfill the request of the user.")

    (gptel--suffix-send '("m" "e"))
    )

Feels not right to use the internal function gptel--suffix-send. Would be nicer if I could pass tools, system prompt, input source, output source directly to a public function which then runs the fsm.

[karthink]

The wiki needs to be updated.

Method 1: let-bind around gptel-send:

(let ((gptel-tools (list (gptel-get-tool "emacs-eval")))
      (gptel--system-message "You are a helpful assistant living inside Emacs.
  Use the emacs_eval tool to fullfill the request of the user."))
  (gptel-send))

Method 2: use a preset

(gptel-make-preset 'eval
  :tools '("emacs-eval")
  :system "You are a helpful assistant living inside Emacs.
  Use the emacs_eval tool to fullfill the request of the user.")

(gptel-with-preset 'eval (gptel-send))

Afterwards, you can also switch to this preset from the menu or send a prompt with this preset by including @eval.

You can also use the lower level gptel-request.

[witek]

Thank you for this enlightening response.

But I don't see options for input and output. Is there a reason why these are missing?

[karthink]

But I don't see options for input and output. Is there a reason why these
are missing?

You have to use gptel--suffix-send instead of gptel-send if you want to redirect the prompt and response.