implement (untested) negative delay in hz display

Writing a very long explanation here as I think these changes are
somewhat brittle.

The delay value is stored in hzSpawnDelay, which is thankfully detached
from basically all other hz computations. Thus, it's actually simplest
to keep all other functionality as it is, i.e. the taps/speed metrics
only act on inputs made while a piece is active.

Negative delay is currently limited to -3. This choice is somewhat
arbitrary and could reasonably be extended in the future, but I think
this is pretty realistic for most people who do care about timing. To
support other entry delay frames, add a call to checkNegativeDelay in
the relevant branch, making sure to set X to the correct value. Negative
values themselves are stored as the magnitude ORed with $80, so e.g. -2
is represented as $82.

One tricky part is that the entry delay pipeline techincally has
multiple paths. The normal path goes through playState_receiveGarbage
once and playState_spawnNextTetrimino twice as the last three frames,
but the game can spend many more frames in playState_spawnNextTetrimino
if the spawnDelay parameter is set, which is done in the tspin and debug
modes. There is extra logic to handle positive spawnDelay, but any other
changes to how entry delay works might require further refactoring.

Author: fractal161

src/gamemodestate/initstate.asm

@@ -149,6 +149,8 @@ gameModeState_initGameState:
 @noTypeBPlayfield:
 
         jsr hzStart
+        lda #0
+        sta hzSpawnDelay
         jsr practiseInitGameState
         jsr resetScroll
 

src/modes/hz.asm

@@ -9,7 +9,6 @@ hzDebounceThreshold := $10
 
 hzStart: ; called in playState_spawnNextTetrimino, gameModeState_initGameState, gameMode_gameTypeMenu
         lda #0
-        sta hzSpawnDelay
         sta hzTapCounter
         lda #hzDebounceThreshold
         sta hzDebounceCounter
@@ -50,7 +49,7 @@ hzControl: ; called in playState_playerControlsActiveTetrimino, gameTypeLoopCont
         bne @noDelayInc
         lda hzSpawnDelay
         cmp #$F
-        beq @noDelayInc
+        bcs @noDelayInc
         inc hzSpawnDelay
 @noDelayInc:
         rts
@@ -183,6 +182,33 @@ hzTap:
         sta renderFlags
         rts
 
+; X: value to store if left or right is newly pressed
+checkNegativeDelay:
+        ; the tail of entry delay has two paths: a normal path, and one where
+        ; spawn delay is added (currently, tspins and debug mode)
+        ; if the spawn delay is too large, we shouldn't update here
+        lda spawnDelay
+        cmp #3
+        bcs @ret
+        lda hzSpawnDelay
+        bne @ret
+        lda newlyPressedButtons_player1
+        and #BUTTON_DPAD
+        cmp #BUTTON_LEFT
+        beq @setDelay
+        lda newlyPressedButtons_player1
+        and #BUTTON_DPAD
+        cmp #BUTTON_RIGHT
+        beq @setDelay
+        rts
+@setDelay:
+        stx hzSpawnDelay
+        lda renderFlags
+        ora #$10
+        sta renderFlags
+@ret:
+        rts
+
 dasLimitLookup:
         .byte 0, 0, 4, 11, 18, 24, 30, 36, 42 , 48; , 54, 60
         .byte 0, 0, 3, 7, 12, 16, 20, 24, 28, 32 ; PAL

src/nmi/render_hz.asm

@@ -1,15 +1,23 @@
 renderHz:
         ; only set at game start and when player is controlling a piece
         ; during which, no other tile updates are happening
-        ; this is pretty expensive and uses up $7 PPU tile writes and 1 palette write
+        ; this is pretty expensive and uses up $8 PPU tile writes and 1 palette write
 
         ; delay
 
         lda #$22
         sta PPUADDR
-        lda #$68
+        lda #$67
         sta PPUADDR
+        ldx #$24 ; minus sign
         lda hzSpawnDelay
+        and #$80
+        bne @isNegative
+        ldx #$FF ; blank tile
+@isNegative:
+        stx PPUDATA
+        lda hzSpawnDelay
+        and #$7F ; clear sign flag
         sta PPUDATA
 
 renderHzSpeedTest:

src/playstate/garbage.asm

@@ -37,8 +37,12 @@ playState_receiveGarbage:
         lda #$00
         sta pendingGarbage
         sta vramRow
-@ret:  inc playState
-@delay:  rts
+@ret:   inc playState
+        lda #$00 ; earliest possible measured point
+        sta hzSpawnDelay
+        ldx #$83 ; -3 tap delay
+        jsr checkNegativeDelay
+        rts
 
 
 garbageLines:

src/playstate/spawnnext.asm

@@ -3,11 +3,24 @@ SPAWN_NEXT_ADDONS := 1
 playState_spawnNextTetrimino:
         lda vramRow
         cmp #$20
-        bmi @ret
+        bpl :+
+        ldx #$82 ; -2 tap delay
+        jsr checkNegativeDelay
+        rts
 
+:
 .if SPAWN_NEXT_ADDONS
         lda spawnDelay
         beq @notDelaying
+        ; here, spawnDelay=1 means hzSpawnDelay=-2, 2 implies -3, and etc.
+        cmp #3 ; if spawnDelay is >= 3, don't update
+        bcs @noCheck
+        clc
+        adc #1
+        ora #$80 ; mark delay as negative
+        tax
+        jsr checkNegativeDelay
+@noCheck:
         dec spawnDelay
         jmp @ret
 .endif
@@ -24,7 +37,8 @@ playState_spawnNextTetrimino:
         sta saveStateDirty
         rts
 @noSaveState:
-
+        ldx #$81 ; -1 tap delay
+        jsr checkNegativeDelay
         jsr hzStart
 .endif