diff --git a/src/data/mult.asm b/src/data/mult.asm
deleted file mode 100644
index 82e4f9b6..00000000
--- a/src/data/mult.asm
+++ /dev/null
@@ -1,9 +0,0 @@
-multBy10Table:
-        .byte   $00,$0A,$14,$1E,$28,$32,$3C,$46
-        .byte   $50,$5A,$64,$6E,$78,$82,$8C,$96
-        .byte   $A0,$AA,$B4,$BE
-multBy32Table:
-        .byte 0,32,64,96,128,160,192,224
-multBy100Table:
-        .byte $0, $64, $c8, $2c, $90
-        .byte $f4, $58, $bc, $20, $84
diff --git a/src/data/mult_orient.asm b/src/data/mult_orient.asm
new file mode 100644
index 00000000..a1bcd73f
--- /dev/null
+++ b/src/data/mult_orient.asm
@@ -0,0 +1,105 @@
+; multiplication and orientation tables
+; Combined to share a common page.  Crossing page boundaries in table lookups
+; costs an extra cycle and causes timing variance that can add up.  One advantage
+; of these tables taking nearly a full page is being able to use the end of the
+; page for lookups to the multBy10Table.  The game logic multiplies tetriminoY (or
+; offsets determined by the orientation table) by 10 frequently. During these
+; calculations, this value is never less than -2 and never greater than 20.  A 256
+; byte lookup table would be mostly wasteful except the first 20 and last 2 bytes.
+; The repeated calls to isPositionValid used for harddrop and 0 arr see a massive
+; impact from these optimisations.
+
+; mult10Tail at end of this page allows table lookup for all possible values of tetriminoY (-2..=20)
+multOrientBegin:
+.assert <multOrientBegin = 0, warning, "multOrientBegin not aligned to page boundary"
+
+
+; multyBy10Table needs to be first in this page with mult10Tail last
+multBy10Table:                                                  ; 20
+        .byte   $00,$0A,$14,$1E,$28,$32,$3C,$46
+        .byte   $50,$5A,$64,$6E,$78,$82,$8C,$96
+        .byte   $A0,$AA,$B4,$BE
+
+multBy32Table:                                                  ; 8
+        .byte   0,32,64,96,128,160,192,224
+
+multBy100Table:                                                 ; 10
+        .byte   $00,$64,$C8,$2C,$90
+        .byte   $F4,$58,$BC,$20,$84
+
+spawnTable:                                                     ; 7
+        .byte   $02,$07,$08,$0A,$0B,$0E,$12
+
+tetriminoTypeFromOrientation:                                   ; 19
+        .byte   $00,$00,$00,$00 ; t
+        .byte   $01,$01,$01,$01 ; j
+        .byte   $02,$02         ; z
+        .byte   $03             ; o
+        .byte   $04,$04         ; s
+        .byte   $05,$05,$05,$05 ; l
+        .byte   $06,$06         ; i
+
+tetriminoTileFromOrientation:                                   ; 20
+        .byte   $7B,$7B,$7B,$7B ; t
+        .byte   $7D,$7D,$7D,$7D ; j
+        .byte   $7C,$7C         ; z
+        .byte   $7B             ; o
+        .byte   $7D,$7D         ; s
+        .byte   $7C,$7C,$7C,$7C ; l
+        .byte   $7B,$7B         ; i
+        .byte   $FF             ; hidden
+
+orientationTableY:                                              ; 80
+        .byte   $00,$00,$00,$FF ; $00 t up
+        .byte   $FF,$00,$00,$01 ; $01 t right
+        .byte   $00,$00,$00,$01 ; $02 t down
+        .byte   $FF,$00,$00,$01 ; $03 t left
+        .byte   $FF,$00,$01,$01 ; $04 j left
+        .byte   $FF,$00,$00,$00 ; $05 j up
+        .byte   $FF,$FF,$00,$01 ; $06 j right
+        .byte   $00,$00,$00,$01 ; $07 j down
+        .byte   $00,$00,$01,$01 ; $08 z horizontal
+        .byte   $FF,$00,$00,$01 ; $09 z vertical
+        .byte   $00,$00,$01,$01 ; $0a o
+        .byte   $00,$00,$01,$01 ; $0b s horizontal
+        .byte   $FF,$00,$00,$01 ; $0c s vertical
+        .byte   $FF,$00,$01,$01 ; $0d l right
+        .byte   $00,$00,$00,$01 ; $0e l down
+        .byte   $FF,$FF,$00,$01 ; $0f l left
+        .byte   $FF,$00,$00,$00 ; $10 l up
+        .byte   $FE,$FF,$00,$01 ; $11 i vertical
+        .byte   $00,$00,$00,$00 ; $12 i horizontal
+        .byte   $00,$00,$00,$00 ; $13 hidden
+
+orientationTableX:                                              ; 80
+        .byte   $FF,$00,$01,$00 ; $00 t up
+        .byte   $00,$00,$01,$00 ; $01 t right
+        .byte   $FF,$00,$01,$00 ; $02 t down
+        .byte   $00,$FF,$00,$00 ; $03 t left
+        .byte   $00,$00,$FF,$00 ; $04 j left
+        .byte   $FF,$FF,$00,$01 ; $05 j up
+        .byte   $00,$01,$00,$00 ; $06 j right
+        .byte   $FF,$00,$01,$01 ; $07 j down
+        .byte   $FF,$00,$00,$01 ; $08 z horizontal
+        .byte   $01,$00,$01,$00 ; $09 z vertical
+        .byte   $FF,$00,$FF,$00 ; $0a o
+        .byte   $00,$01,$FF,$00 ; $0b s horizontal
+        .byte   $00,$00,$01,$01 ; $0c s vertical
+        .byte   $00,$00,$00,$01 ; $0d l right
+        .byte   $FF,$00,$01,$FF ; $0e l down
+        .byte   $FF,$00,$00,$00 ; $0f l left
+        .byte   $01,$FF,$00,$01 ; $10 l up
+        .byte   $00,$00,$00,$00 ; $11 i vertical
+        .byte   $FE,$FF,$00,$01 ; $12 i horizontal
+        .byte   $00,$00,$00,$00 ; $13 hidden
+
+; unused.  padding required for mult10Tail
+.repeat 10
+    .byte $00
+.endrepeat
+
+; needs to be last table in this page
+mult10Tail:                                                     ; 2
+    .byte $EC,$F6 ; -20,-10
+
+.assert multBy10Table + $fe = mult10Tail, error, "mult10Tail is not multBy10Table + $FE"
diff --git a/src/data/orientation.asm b/src/data/orientation.asm
deleted file mode 100644
index 7952ef31..00000000
--- a/src/data/orientation.asm
+++ /dev/null
@@ -1,39 +0,0 @@
-orientationTable:
-        .byte   $00,$7B,$FF,$00,$7B,$00,$00,$7B
-        .byte   $01,$FF,$7B,$00,$FF,$7B,$00,$00
-        .byte   $7B,$00,$00,$7B,$01,$01,$7B,$00
-        .byte   $00,$7B,$FF,$00,$7B,$00,$00,$7B
-        .byte   $01,$01,$7B,$00,$FF,$7B,$00,$00
-        .byte   $7B,$FF,$00,$7B,$00,$01,$7B,$00
-        .byte   $FF,$7D,$00,$00,$7D,$00,$01,$7D
-        .byte   $FF,$01,$7D,$00,$FF,$7D,$FF,$00
-        .byte   $7D,$FF,$00,$7D,$00,$00,$7D,$01
-        .byte   $FF,$7D,$00,$FF,$7D,$01,$00,$7D
-        .byte   $00,$01,$7D,$00,$00,$7D,$FF,$00
-        .byte   $7D,$00,$00,$7D,$01,$01,$7D,$01
-        .byte   $00,$7C,$FF,$00,$7C,$00,$01,$7C
-        .byte   $00,$01,$7C,$01,$FF,$7C,$01,$00
-        .byte   $7C,$00,$00,$7C,$01,$01,$7C,$00
-        .byte   $00,$7B,$FF,$00,$7B,$00,$01,$7B
-        .byte   $FF,$01,$7B,$00,$00,$7D,$00,$00
-        .byte   $7D,$01,$01,$7D,$FF,$01,$7D,$00
-        .byte   $FF,$7D,$00,$00,$7D,$00,$00,$7D
-        .byte   $01,$01,$7D,$01,$FF,$7C,$00,$00
-        .byte   $7C,$00,$01,$7C,$00,$01,$7C,$01
-        .byte   $00,$7C,$FF,$00,$7C,$00,$00,$7C
-        .byte   $01,$01,$7C,$FF,$FF,$7C,$FF,$FF
-        .byte   $7C,$00,$00,$7C,$00,$01,$7C,$00
-        .byte   $FF,$7C,$01,$00,$7C,$FF,$00,$7C
-        .byte   $00,$00,$7C,$01,$FE,$7B,$00,$FF
-        .byte   $7B,$00,$00,$7B,$00,$01,$7B,$00
-        .byte   $00,$7B,$FE,$00,$7B,$FF,$00,$7B
-        .byte   $00,$00,$7B,$01,$00,$FF,$00,$00
-        .byte   $FF,$00,$00,$FF,$00,$00,$FF,$00
-
-tetriminoTypeFromOrientation:
-        .byte   $00,$00,$00,$00,$01,$01,$01,$01
-        .byte   $02,$02,$03,$04,$04,$05,$05,$05
-        .byte   $05,$06,$06
-spawnTable:
-        .byte   $02,$07,$08,$0A,$0B,$0E,$12
-        .byte   $02
diff --git a/src/main.asm b/src/main.asm
index 1bebb3e3..2ad1db24 100644
--- a/src/main.asm
+++ b/src/main.asm
@@ -66,8 +66,6 @@ mainLoop:
 .include "sprites/piece.asm"
 
 .include "data/bytebcd.asm"
-.include "data/orientation.asm"
-.include "data/mult.asm"
 
 .include "palettes.asm"
 .include "nametables.asm"
@@ -93,7 +91,9 @@ mainLoop:
 .include "modes/qtap.asm"
 .include "modes/garbage.asm"
 
-.code
+.align $100
+; these tables benefit from page alignment
+.include "data/mult_orient.asm"
 
 .segment    "PRG_chunk3": absolute
 
diff --git a/src/playstate/active.asm b/src/playstate/active.asm
index e60cb685..2299ded3 100644
--- a/src/playstate/active.asm
+++ b/src/playstate/active.asm
@@ -23,11 +23,8 @@ harddrop_tetrimino:
         beq playState_playerControlsActiveTetrimino_return
         lda tetriminoY
         sta tmpY
-@loop:
-        inc tetriminoY
-        jsr isPositionValid
-        beq @loop
-        dec tetriminoY
+        lda hardDropGhostY ; value set by previous frame's sprite staging
+        sta tetriminoY
 
         ; sonic drop
         lda newlyPressedButtons
@@ -119,16 +116,13 @@ harddropMarkCleared:
         sta harddropAddr
 
         ; check for empty row
-        ldy #$0
+        ldy #$9
 @minoLoop:
         lda (harddropAddr), y
-        cmp #EMPTY_TILE
-        beq @noLineClear
+        bmi @noLineClear ; EMPTY_TILE sets negative flag, normal tiles do not
 
-        iny
-        cpy #$A
-        beq @lineClear
-        jmp @minoLoop
+        dey
+        bpl @minoLoop
 
 @lineClear:
         lda #1
@@ -196,14 +190,13 @@ harddropShift:
         sbc lineOffset
         sta harddropAddr+2
 
-        ldy #0
+        ldy #9
 @shiftLineLoop:
         lda (harddropAddr+2), y
         sta (harddropAddr), y
 
-        iny
-        cpy #$A
-        bne @shiftLineLoop
+        dey
+        bpl @shiftLineLoop
 
 @nextLine:
         dec tmpY
@@ -222,12 +215,11 @@ harddropShift:
         sta completedLines
         ; emty top row
         lda #EMPTY_TILE
-        ldx #0
+        ldx #9
 @topRowLoop:
         sta playfield, x
-        inx
-        cpx #$A
-        bne @topRowLoop
+        dex
+        bpl @topRowLoop
         ; lda #TETRIMINO_X_HIDE
         ; sta tetriminoX
 
diff --git a/src/playstate/lock.asm b/src/playstate/lock.asm
index f91de399..258f692b 100644
--- a/src/playstate/lock.asm
+++ b/src/playstate/lock.asm
@@ -1,4 +1,5 @@
 playState_lockTetrimino:
+@currentTile = generalCounter5
         jsr isPositionValid
         beq @notGameOver
 @gameOver:
@@ -32,49 +33,35 @@ playState_lockTetrimino:
         lda vramRow
         cmp #$20
         bmi @ret
-        lda tetriminoY
-        asl a
-        sta generalCounter
-        asl a
-        asl a
+        ldy tetriminoY
+        lda multBy10Table,y
         clc
-        adc generalCounter
         adc tetriminoX
         sta generalCounter
-        lda currentPiece
-        asl a
+        ldx currentPiece
+        lda tetriminoTileFromOrientation,x
+        sta @currentTile
+        txa
         asl a
-        sta generalCounter2
         asl a
-        clc
-        adc generalCounter2
         tax
         ldy #$00
         lda #$04
         sta generalCounter3
 ; Copies a single square of the tetrimino to the playfield
 @lockSquare:
-        lda orientationTable,x
-        asl a
-        sta generalCounter4
-        asl a
-        asl a
-        clc
-        adc generalCounter4
+        ldy orientationTableY,x
+        lda multBy10Table,y
         clc
         adc generalCounter
         sta positionValidTmp
-        inx
-        lda orientationTable,x
-        sta generalCounter5
-        inx
-        lda orientationTable,x
+        lda orientationTableX,x
         clc
         adc positionValidTmp
         tay
-        lda generalCounter5
+        lda @currentTile
         ; BLOCK_TILES
-        sta (playfieldAddr),y
+        sta playfield,y
         inx
         dec generalCounter3
         bne @lockSquare
diff --git a/src/playstate/util.asm b/src/playstate/util.asm
index a09c2dcb..7f7a8311 100644
--- a/src/playstate/util.asm
+++ b/src/playstate/util.asm
@@ -1,53 +1,38 @@
 isPositionValid:
-        lda tetriminoY
-        asl a
-        sta generalCounter
-        asl a
-        asl a
+        ldy tetriminoY
+        lda multBy10Table,y
         clc
-        adc generalCounter
         adc tetriminoX
         sta generalCounter
         lda currentPiece
         asl a
         asl a
-        sta generalCounter2
-        asl a
-        clc
-        adc generalCounter2
         tax
         ldy #$00
         lda #$04
         sta generalCounter3
 ; Checks one square within the tetrimino
 @checkSquare:
-        lda orientationTable,x
+        lda orientationTableY,x
         clc
         adc tetriminoY
-        adc #$02
+        adc #$02 ; carry may be set for this add but doesn't have any noticeable impact
 
         cmp #$16
         bcs @invalid
-        lda orientationTable,x
-        asl a
-        sta generalCounter4
-        asl a
-        asl a
-        clc
-        adc generalCounter4
-        clc
+
+        ldy orientationTableY,x
+        lda multBy10Table,y
+        ; clc omitted, carry is clear from cmp instruction above that branches away on carry set
         adc generalCounter
         sta positionValidTmp
-        inx
-        inx
-        lda orientationTable,x
+        lda orientationTableX,x
         clc
         adc positionValidTmp
         tay
-        lda (playfieldAddr),y
-        cmp #EMPTY_TILE
-        bcc @invalid
-        lda orientationTable,x
+        lda playfield,y
+        bpl @invalid ; tiles do not set negative flag
+        lda orientationTableX,x
         clc
         adc tetriminoX
         cmp #$0A
diff --git a/src/ram.asm b/src/ram.asm
index f021f206..e6fb6c11 100755
--- a/src/ram.asm
+++ b/src/ram.asm
@@ -220,8 +220,9 @@ dasOnlyShiftDisabled: .res 1 ; $63A
 invisibleFlag: .res 1 ; $63B  ; 0 for normal mode, non-zero for Invisible playfield rendering.  Reset on game init and game over.
 currentFloor: .res 1 ; $63C floorModifier is copied here at game init.  Set to 0 otherwise and incremented when linecap floor.
 mapperId: .res 1 ; $63D ; For INES_MAPPER 1000 (autodetect).  0 = CNROM.  1 = MMC1.
+hardDropGhostY: .res 1 ; ghost Y used as a shortcut for hard/sonic drop
 
-    .res $37
+    .res $36
 
 .if KEYBOARD
 newlyPressedKeys: .res 1 ; $0675
diff --git a/src/sprites/piece.asm b/src/sprites/piece.asm
index c15efdfb..05e84a90 100644
--- a/src/sprites/piece.asm
+++ b/src/sprites/piece.asm
@@ -19,9 +19,10 @@ ghostPiece:
         jsr isPositionValid
         beq @loop
         dec tetriminoY
-
-        ; check if equal to current position
         lda tetriminoY
+        ; save value for use by hard/sonic drop in next frame
+        sta hardDropGhostY
+        ; check if equal to current position
         cmp tmp3
         beq @noGhost
 
@@ -38,12 +39,13 @@ ghostPiece:
         rts
 
 tileModifierForCurrentPiece:
+@currentTile = generalCounter5
         lda pieceTileModifier
         beq @tileNormal
         and #$80
         bne @tileSingle
 ; @tileMultiple:
-        lda orientationTable,x
+        lda @currentTile
         clc
         adc pieceTileModifier
         rts
@@ -51,10 +53,11 @@ tileModifierForCurrentPiece:
         lda pieceTileModifier
         rts
 @tileNormal:
-        lda orientationTable,x
+        lda @currentTile
         rts
 
 stageSpriteForCurrentPiece_actual:
+@currentTile = generalCounter5
         lda tetriminoX
         cmp #TETRIMINO_X_HIDE
         beq stageSpriteForCurrentPiece_return
@@ -70,21 +73,18 @@ stageSpriteForCurrentPiece_actual:
         rol a
         adc #$2F
         sta generalCounter4
-        lda currentPiece
-        sta generalCounter5
-        clc
-        lda generalCounter5
-        rol a
-        rol a
-        sta generalCounter
-        rol a
-        adc generalCounter
+        ldx currentPiece
+        lda tetriminoTileFromOrientation,x
+        sta @currentTile
+        txa
+        asl a
+        asl a
         tax
         ldy oamStagingLength
         lda #$04
         sta generalCounter2
 @stageMino:
-        lda orientationTable,x
+        lda orientationTableY,x
         asl a
         asl a
         asl a
@@ -94,13 +94,11 @@ stageSpriteForCurrentPiece_actual:
         sta originalY
         inc oamStagingLength
         iny
-        inx
         jsr tileModifierForCurrentPiece ; used to just load from orientationTable
         ; lda orientationTable, x
         sta oamStaging,y
         inc oamStagingLength
         iny
-        inx
         lda #$02
         sta oamStaging,y
         lda originalY
@@ -119,7 +117,7 @@ stageSpriteForCurrentPiece_actual:
 @validYCoordinate:
         inc oamStagingLength
         iny
-        lda orientationTable,x
+        lda orientationTableX,x
         asl a
         asl a
         asl a
diff --git a/tests/src/harddrop.rs b/tests/src/harddrop.rs
index 7e3b85bc..80a4dff5 100644
--- a/tests/src/harddrop.rs
+++ b/tests/src/harddrop.rs
@@ -1,4 +1,3 @@
-
 use rusticnes_core::nes::NesState;
 
 use crate::{ util, labels, playfield};