isIriDeleted check does not consider boolean value of the checked triple

[GGoetzelmann]

Check for deleted flag only checks if there is a triple with the "deleted"-predicate, but it does not care if the value of the triple is set to true or false.

wap-server/src/main/java/edu/kit/scc/dem/wapsrv/service/AbstractWapService.java

Line 454 in 0a9e4fd

result[0] = graph.contains(node, WapVocab.deleted, null);

Might be quite safe at the moment because the value is only set to true, but would not work properly if at some point some 'undelete' operation takes place (via code, via sparql), setting the value to false.

[ThomasJejkal]

...unless the idea was that 'deleted' is only checked to be present and is removed to 'undelete' a certain IRI.

[GGoetzelmann]

I think that was the initial idea. Seems a little dangerous and like an idea that might not be shared by all future developers.

Moreover, as stated above, you can 'undelete' the annotation via SPARQL update on the (admin) user side.
Haven't checked it yet, but I, therefore, expect that removing the triple with <http://dem.scc.kit.edu/wapserv/ns#deleted> "true"^^xsd:boolean would undo the deletion, but changing the value to "false"^^xsd:boolean would not.

[GGoetzelmann]

welp, that issue turned out to be a can of worms ... 🥫🪱🪱🪱

#41 fixes check against the deleted flag - an explicit false here is now treated the same way the absence of the flag would be.

However, currently the only way of an 'undelete' operation is a SPARQL update that either removes the flag triple or sets it to false. In doing so the annotation (or container, but undeleting a container does not make much sense, its content would not be restored, and you should be able to recreate it via API on default configuration anyway) is retrievable via API again, but it is still removed from its container and basically orphaned - the state is then not really WAP compliant anymore.

WADM/WAP does not provide any functionality to UNDELETE (since soft delete is an implementation choice, not a specification necessity). REST in general does not really seem to provide standard concepts for UNDELETE.

The only reasonable way imho to allow for such an operation from the API side would be a PATCH with a payload that indicates restore/undelete. It still does not really feel like it fits well with the overall API concept.

The SPARQL update route on the other hand cannot be controlled at all, so the change of the deleted flag via SPARQL will always easily lead to orphaned annotations, so this is overall quite the weak point of a soft deletion concept without a controlled way to revert.

For documentation reason for now I'll provide a SPARQL request that should properly restore an annotation. Please consider the operation to be potentially dangerous to the integrity of your data, use responsibly and backup your data.

PREFIX wap: <http://dem.scc.kit.edu/wapserv/ns#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

DELETE {
  GRAPH ?annotationGraph {
    ?annotation wap:deleted true .
  }
}
INSERT {
  GRAPH ?containerGraph {
    ?seqIRI a rdf:Seq .
    ?seqIRI ?insertPredicate ?annotation .
  }
}
WHERE {
  # Define the annotation IRI
  BIND(<http://localhost:8081/wap/empty/18a85400-ef4e-4bc3-91c1-d538f48484dd> AS ?annotation) #SET YOUR ANNOTATION ID HERE
  # Derive container and graph IRIs
  BIND(IRI(REPLACE(STR(?annotation), "[^/]+$", "")) AS ?container)
  BIND(?container AS ?containerGraph)
  BIND(?annotation AS ?annotationGraph)
  BIND(IRI(CONCAT(STR(?container), "#annotations")) AS ?seqIRI)

  # Confirm the annotation is marked as deleted
  GRAPH ?annotationGraph {
    ?annotation wap:deleted true .
  }

  # Optional block to get the max index if the sequence exists
  OPTIONAL {
    {
      SELECT ?seqIRI (MAX(xsd:integer(STRAFTER(STR(?p), STR(rdf:_)))) AS ?maxIndex)
      WHERE {
        GRAPH ?containerGraph {
          ?seqIRI ?p ?o .
          FILTER(STRSTARTS(STR(?p), STR(rdf:_)))
        }
      }
      GROUP BY ?seqIRI
    }
  }

  # Compute the next index or default to 1
  BIND(
    IF(BOUND(?maxIndex),
      IRI(CONCAT(STR(rdf:), "_", STR(?maxIndex + 1))),
      rdf:_1
    ) AS ?insertPredicate
  )
}

Perform the request on the SPARQL write port as POST to http://<hostname>:<sparqlWritePort>/wap/update with header 'Content-Type': "application/sparql-update"