build(meson): add additional warning flags for libgrovedb

Author: kwvg

src/ffi/grovedb/README.md

@@ -51,6 +51,7 @@ meson compile -C builddir
 - `-Dbuild_tests=[true|false]`: Build unit tests (default: `true`)
 - `-Dgrovedb_cxx_build_dir=<path>`: Path to `grovedb_cxx` build directory (auto-detected if empty, ignored if `use_rustdeps=true`)
 - `-Drustdeps_build_dir=<path>`: Path to `librustdeps` build directory (auto-detected if empty)
+- `-Dsuppress_external_warnings=[true|false]`: Suppress compiler warnings on external sources (default: `true`)
 - `-Duse_rustdeps=[true|false]`: Link against `librustdeps` instead of `libgrovedb_cxx` (default: `false`)
 
 ## License

src/ffi/grovedb/meson.build

@@ -26,6 +26,46 @@ rustdeps_build_dir = get_option('rustdeps_build_dir')
 
 # C++ compiler
 cxx = meson.get_compiler('cpp')
+cxx_core_flags_list = [
+  '-fno-extended-identifiers',
+  '-fstack-reuse=none', # https://gcc.gnu.org/bugzilla/show_bug.cgi?id=90348
+]
+cxx_warn_flags_list = [
+  '-Wconditional-uninitialized',
+  '-Wdate-time',
+  '-Wdocumentation',
+  '-Wduplicated-branches',
+  '-Wduplicated-cond',
+  '-Wgnu',
+  '-Wimplicit-fallthrough',
+  '-Wlogical-op',
+  '-Wloop-analysis',
+  '-Woverloaded-virtual',
+  '-Wredundant-decls',
+  '-Wreorder',
+  '-Wself-assign',
+  '-Wshadow-field',
+  '-Wsuggest-override',
+  '-Wthread-safety',
+  '-Wunreachable-code',
+  '-Wunused-member-function',
+  '-Wvla',
+]
+
+# Check compiler support for flags and apply them
+cxx_flags = []
+foreach flag : cxx_core_flags_list + cxx_warn_flags_list
+  if cxx.has_multi_arguments(['-Werror', flag])
+    cxx_flags += flag
+  endif
+endforeach
+
+# -Wformat and -Wformat-security must defined together
+if cxx.has_multi_arguments(['-Werror', '-Wformat', '-Wformat-security'])
+  cxx_flags += ['-Wformat', '-Wformat-security']
+endif
+
+add_project_arguments(cxx_flags, language: 'cpp')
 
 # Check for threading support
 thread_dep = dependency('threads', required: true)
@@ -193,32 +233,28 @@ pkg.generate(
   subdirs: 'grovedb',
 )
 
-# Tests
+# Unit tests
+suppress_external_warns = get_option('suppress_external_warnings')
+test_sources = files(
+  'src/test/main.cpp',
+  'src/test/misc_tests.cpp',
+)
 if build_tests
   boost_dep = dependency('boost',
     modules: ['unit_test_framework'],
     version: '>=1.73.0',
-    required: false,
+    required: true,
+    include_type: suppress_external_warns ? 'system' : 'preserve',
   )
 
-  if boost_dep.found()
-    test_sources = files(
-      'src/test/main.cpp',
-      'src/test/misc_tests.cpp',
-    )
-
-    # Build test executable
-    test_exe = executable('test_grovedb',
-      test_sources,
-      include_directories: libgrovedb_inc,
-      dependencies: [libgrovedb_dep, boost_dep],
-      build_by_default: true,
-    )
+  test_bin = executable('test_grovedb',
+    test_sources,
+    include_directories: libgrovedb_inc,
+    dependencies: [libgrovedb_dep, boost_dep],
+    build_by_default: true,
+  )
 
-    test('grovedb_tests', test_exe)
-  else
-    warning('Boost not found. Tests will not be built.')
-  endif
+  test('grovedb_tests', test_bin)
 endif
 
 # Summary
@@ -231,6 +267,7 @@ summary({
 
 summary({
   'C++ compiler': cxx.get_id(),
+  'C++ flags': ' '.join(cxx_flags),
   'C++ standard': get_option('cpp_std'),
 }, section: 'Compiler')
 

src/ffi/grovedb/meson_options.txt

@@ -16,6 +16,12 @@ option('rustdeps_build_dir',
   description: 'Path to rustdeps build directory (auto-detected if empty)'
 )
 
+option('suppress_external_warnings',
+  type: 'boolean',
+  value: true,
+  description: 'Suppress warnings from external headers'
+)
+
 option('use_rustdeps',
   type: 'boolean',
   value: false,