|
| 1 | +/**============================================================================= |
| 2 | +@file |
| 3 | + qhblas_f_vector_dot_af.S |
| 4 | +
|
| 5 | +@brief |
| 6 | + Calculates dot product of two input float vectors. |
| 7 | +
|
| 8 | + Function prototype |
| 9 | + |
| 10 | + int32_t qhblas_f_vector_dot_af(float_a8_t *input_1, float_a8_t *input_2, float *output, uint32_t size); |
| 11 | +
|
| 12 | + Reference C code |
| 13 | + |
| 14 | + int32_t qhblas_f_vector_dot_af(float_a8_t *input_1, float_a8_t *input_2, float *output, uint32_t size) |
| 15 | + { |
| 16 | + if ((input_1 == NULL) || (input_2 == NULL) || (output == NULL) || (size == 0)) |
| 17 | + { |
| 18 | + return -1; |
| 19 | + } |
| 20 | +
|
| 21 | + float dot = 0; |
| 22 | + for (uint32_t i = 0; i < size; ++i) |
| 23 | + { |
| 24 | + dot += input_1[i] * input_2[i]; |
| 25 | + } |
| 26 | +
|
| 27 | + *output = dot; |
| 28 | + return 0; |
| 29 | + } |
| 30 | +
|
| 31 | +Copyright (c) 2019 Qualcomm Technologies Incorporated. |
| 32 | +All Rights Reserved. Qualcomm Proprietary and Confidential. |
| 33 | +=============================================================================**/ |
| 34 | + |
| 35 | +/*============================================================================*/ |
| 36 | + |
| 37 | + .p2align 2 |
| 38 | + .p2align 4,,15 |
| 39 | + .global qhblas_f_vector_dot_af |
| 40 | + .type qhblas_f_vector_dot_af, @function |
| 41 | + |
| 42 | +/*============================================================================*/ |
| 43 | + |
| 44 | +#define DC_PREFETCH_AHEAD 64 // number of bytes for DCFETCH |
| 45 | +#define L2_PREFETCH_AHEAD 256 // number of bytes for L2FETCH |
| 46 | +#define L2FETCH_CONFIG 0x0100FF00+(L2_PREFETCH_AHEAD/256) // [stride = 256 : width = 255 : height = bytes/256] |
| 47 | +#define L2_PREFETCH_ELEMS L2_PREFETCH_AHEAD/8 // number of elements to prefetch with L2FETCH |
| 48 | + |
| 49 | +/*============================================================================*/ |
| 50 | + |
| 51 | +qhblas_f_vector_dot_af: |
| 52 | +{ |
| 53 | + p0 = !cmp.eq(r0,#0) // input_1 != NULL |
| 54 | + p0 = !cmp.eq(r1,#0) // input_2 != NULL |
| 55 | + p0 = !cmp.eq(r2,#0) // output != NULL |
| 56 | + p0 = cmp.gtu(r3,#0) // size > 0 |
| 57 | + if (!p0.new) jump:nt .L_ret |
| 58 | +} |
| 59 | +{ |
| 60 | + r10 = #0 |
| 61 | + r3 = lsr(r3,#1) // size / 2 |
| 62 | + p1 = tstbit(r3,#0) // check for odd size |
| 63 | + if(cmp.eq(r3.new,#0)) jump:nt .L_do_one |
| 64 | +} |
| 65 | +{ |
| 66 | + r7:6 = #0 |
| 67 | + r9:8 = #0 |
| 68 | + r5 = add(r3,#7) // (size / 2) + 7 |
| 69 | + p2 = cmp.gtu(r3,#L2_PREFETCH_ELEMS) // check whether we can do l2fetch |
| 70 | +} |
| 71 | +{ |
| 72 | + r5 = lsr(r5,#3) // ceil(size / 2) |
| 73 | + r14 = mux(p2,r3,#0) // set l2fetch counter |
| 74 | +} |
| 75 | +{ |
| 76 | + r13:12 = combine(##L2FETCH_CONFIG,#8) // set l2fetch config and max number of iterations for .L_loop_do_two |
| 77 | + loop1(.L_prefetch_loop_do_two,r5) |
| 78 | +} |
| 79 | + .falign |
| 80 | +.L_prefetch_loop_do_two: |
| 81 | +{ |
| 82 | + dcfetch(r0+#DC_PREFETCH_AHEAD) // prefetch ahead for input_1 |
| 83 | + r5 = min(r12,r3) // min(8, size / 2) |
| 84 | +} |
| 85 | +{ |
| 86 | + dcfetch(r1+#DC_PREFETCH_AHEAD) // prefetch ahead for input_2 |
| 87 | + loop0(.L_loop_do_two,r5) |
| 88 | + p2 = cmp.eq(r3,r14) // check whether to do l2fetch |
| 89 | + if (!p2.new) jump:t .L_loop_do_two |
| 90 | +} |
| 91 | +{ |
| 92 | + r5 = add(r3,#-L2_PREFETCH_ELEMS) // number of elements left to prefetch ahead |
| 93 | + r15 = add(r0,#L2_PREFETCH_AHEAD) // input_1 addr for l2fetch |
| 94 | +} |
| 95 | +{ |
| 96 | + p2 = cmp.gtu(r5,#L2_PREFETCH_ELEMS) // check whether we can continue to do l2fetch |
| 97 | + r15 = add(r1,#L2_PREFETCH_AHEAD) // input_2 addr for l2fetch |
| 98 | + l2fetch(r15,r13) |
| 99 | +} |
| 100 | +{ |
| 101 | + if (p2) r14 = add(r14,#-L2_PREFETCH_ELEMS) // adjust l2fetch counter |
| 102 | + if (!p2) r14 = #0 // there are no more bytes left to prefetch ahead |
| 103 | + l2fetch(r15,r13) |
| 104 | +} |
| 105 | + .falign |
| 106 | +.L_loop_do_two: |
| 107 | +{ |
| 108 | + r7:6 = memd(r0++#8) |
| 109 | + r9:8 = memd(r1++#8) |
| 110 | + r10 += sfmpy(r7,r9) |
| 111 | +} |
| 112 | +{ |
| 113 | + r10 += sfmpy(r6,r8) |
| 114 | + r3 = add(r3,#-1) // adjust (size / 2) |
| 115 | +}:endloop0:endloop1 |
| 116 | +{ |
| 117 | + r10 += sfmpy(r7,r9) |
| 118 | + if (!p1) jump:nt .L_ret |
| 119 | +} |
| 120 | + .falign |
| 121 | +.L_do_one: |
| 122 | +{ |
| 123 | + r4 = memw(r0) |
| 124 | + r5 = memw(r1) |
| 125 | +} |
| 126 | +{ |
| 127 | + r10 += sfmpy(r4,r5) |
| 128 | +} |
| 129 | + .falign |
| 130 | +.L_ret: |
| 131 | +{ |
| 132 | + if (p0) memw(r2) = r10 |
| 133 | + r0 = mux(p0,#0,#-1) |
| 134 | + jumpr r31 |
| 135 | +} |
| 136 | + .size qhblas_f_vector_dot_af, .-qhblas_f_vector_dot_af |
0 commit comments