Merge pull request #10 from nwjsmith/tagged-literals

Print dates and UUIDs with tagged literals

Author: plexus

src/lambdaisland/deep_diff/printer.clj

@@ -5,7 +5,10 @@
             [puget.dispatch]
             [puget.printer :as puget]
             [arrangement.core]
-            [lambdaisland.deep-diff.diff :as diff]))
+            [lambdaisland.deep-diff.diff :as diff])
+  (:import (java.text SimpleDateFormat)
+           (java.util TimeZone)
+           (java.sql Timestamp)))
 
 (defn print-deletion [printer expr]
   (let [no-color (assoc printer :print-color false)]
@@ -34,6 +37,38 @@
      [:align (interpose [:span (:map-delimiter this) :line] entries)]
      (color/document this :delimiter "}")]))
 
+(def ^:private ^ThreadLocal thread-local-utc-date-format
+  (proxy [ThreadLocal] []
+    (initialValue []
+      (doto (SimpleDateFormat. "yyyy-MM-dd'T'HH:mm:ss.SSS-00:00")
+        (.setTimeZone (TimeZone/getTimeZone "GMT"))))))
+
+(def ^:private print-date
+  (puget/tagged-handler
+    'inst
+    #(.format ^SimpleDateFormat (.get thread-local-utc-date-format) %)))
+
+(def ^:private ^ThreadLocal thread-local-utc-timestamp-format
+  (proxy [ThreadLocal] []
+    (initialValue []
+      (doto (SimpleDateFormat. "yyyy-MM-dd'T'HH:mm:ss")
+        (.setTimeZone (TimeZone/getTimeZone "GMT"))))))
+
+(def ^:private print-timestamp
+  (puget/tagged-handler
+    'inst
+    #(str (.format ^SimpleDateFormat (.get thread-local-utc-timestamp-format) %)
+          (format ".%09d-00:00" (.getNanos ^Timestamp %)))))
+
+(def ^:private print-calendar
+  (puget/tagged-handler
+    'inst
+    #(let [formatted (format "%1$tFT%1$tT.%1$tL%1$tz" %)
+           offset-minutes (- (.length formatted) 2)]
+       (str (subs formatted 0 offset-minutes)
+            ":"
+            (subs formatted offset-minutes)))))
+
 (def ^:private print-handlers
   {'lambdaisland.deep_diff.diff.Deletion
    print-deletion
@@ -72,7 +107,19 @@
            [:span
             (puget/format-doc printer k)
             (if (coll? v) (:map-coll-separator printer) " ")
-            (puget/format-doc printer v)]))))})
+            (puget/format-doc printer v)]))))
+
+   'java.util.Date
+   print-date
+
+   'java.util.GregorianCalendar
+   print-calendar
+
+   'java.sql.Timestamp
+   print-timestamp
+
+   'java.util.UUID
+   (puget/tagged-handler 'uuid str)})
 
 (defn- print-handler-resolver [extra-handlers]
   (fn [^Class klz]

test/lambdaisland/deep_diff/printer_test.clj

@@ -0,0 +1,40 @@
+(ns lambdaisland.deep-diff.printer-test
+  (:require [clojure.test :refer :all]
+            [lambdaisland.deep-diff.diff :as diff]
+            [lambdaisland.deep-diff.printer :as printer])
+  (:import (java.sql Timestamp)
+           (java.util Date
+                      GregorianCalendar
+                      TimeZone)))
+
+(defn- printed
+  [diff]
+  (let [printer (printer/puget-printer {})]
+    (with-out-str (-> diff
+                      (printer/format-doc printer)
+                      (printer/print-doc printer)))))
+
+(defn- calendar
+  [date]
+  (doto (GregorianCalendar. (TimeZone/getTimeZone "GMT"))
+    (.setTime date)))
+
+(deftest print-doc-test
+  (testing "date"
+    (is (= "\u001B[31m-#inst \"2019-04-09T14:57:46.128-00:00\"\u001B[0m \u001B[32m+#inst \"2019-04-10T14:57:46.128-00:00\"\u001B[0m\n"
+           (printed (diff/diff #inst "2019-04-09T14:57:46.128-00:00"
+                               #inst "2019-04-10T14:57:46.128-00:00")))))
+
+  (testing "timestamp"
+    (is (= "\u001B[31m-#inst \"1970-01-01T00:00:00.000000000-00:00\"\u001B[0m \u001B[32m+#inst \"1970-01-01T00:00:01.000000101-00:00\"\u001B[0m\n"
+           (printed (diff/diff (Timestamp. 0)
+                               (doto (Timestamp. 1000) (.setNanos 101)))))))
+
+  (testing "calendar"
+    (is (= "\u001B[31m-#inst \"1970-01-01T00:00:00.000+00:00\"\u001B[0m \u001B[32m+#inst \"1970-01-01T00:00:01.001+00:00\"\u001B[0m\n"
+           (printed (diff/diff (calendar (Date. 0)) (calendar (Date. 1001)))))))
+
+  (testing "uuid"
+    (is (= "\u001B[31m-#uuid \"e41b325a-ce9d-4fdd-b51d-280d9c91314d\"\u001B[0m \u001B[32m+#uuid \"0400be9a-619f-4c6a-a735-6245e4955995\"\u001B[0m\n"
+           (printed (diff/diff #uuid "e41b325a-ce9d-4fdd-b51d-280d9c91314d"
+                               #uuid "0400be9a-619f-4c6a-a735-6245e4955995"))))))